lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 create_dump
  11 session
  12
  13 sock
  14 state
  15 store
  16 / );
  17
  18 use Data::Dump qw/dump/;
  19 use Carp qw/carp confess cluck croak/;
  20
  21 use CWMP::Request;
  22 use CWMP::Methods;
  23 use CWMP::Store;
  24
  25 #use Devel::LeakTrace::Fast;
  26
  27 =head1 NAME
  28
  29 CWMP::Session - implement logic of CWMP protocol
  30
  31 =head1 METHODS
  32
  33 =head2 new
  34
  35   my $server = CWMP::Session->new({
  36         sock => $io_socket_object,
  37         store => { ... },
  38         debug => 1,
  39         create_dump => 1,
  40   });
  41
  42 =cut
  43
  44 sub new {
  45         my $class = shift;
  46         my $self = $class->SUPER::new( @_ );
  47
  48         confess "need store" unless $self->store;
  49
  50         $self->debug( 0 ) unless $self->debug;
  51
  52         my $store_obj = CWMP::Store->new({
  53                 debug => $self->debug,
  54                 %{ $self->store },
  55         });
  56
  57         croak "can't open ", dump( $self->store ), ": $!" unless $store_obj;
  58
  59         # FIXME looks ugly. Should we have separate accessor for this?
  60         $self->store( $store_obj );
  61
  62         $self->create_dump( 1 ) if $self->debug > 2;
  63
  64         return $self;
  65 }
  66
  67 =head2 process_request
  68
  69 One request from client/response from server cycle. Call multiple times to
  70 facilitate brain-dead concept of adding state to stateless protocol like
  71 HTTP.
  72
  73 If used with debugging level of 3 or more, it will also create dumps of
  74 requests named C<< dump/nr.request >> where C<nr> is number from 0 to total number
  75 of requests in single session.
  76
  77 =cut
  78
  79
  80 sub process_request {
  81         my ( $self, $ip, $xml ) = @_;
  82
  83         my $size = length( $xml );
  84
  85         my $state;
  86
  87         if ( $size > 0 ) {
  88
  89                 warn "## request payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
  90
  91                 $state = CWMP::Request->parse( $xml );
  92
  93                 warn "## acquired state = ", dump( $state ), "\n" if $self->debug;
  94
  95                 if ( ! defined( $state->{DeviceID} ) ) {
  96                         if ( $self->state ) {
  97                                 warn "## state without DeviceID, using old one...\n";
  98                                 $state->{DeviceID} = $self->state->{DeviceID};
  99                         } else {
 100                                 warn "WARNING: state without DeviceID, and I don't have old one!\n";
 101                                 warn "## state = ",dump( $state );
 102                         }
 103                 }
 104
 105                 $self->state( $state );
 106                 $self->store->update_state( $state );
 107
 108         } else {
 109
 110                 warn "## empty request, using last request state\n";
 111
 112                 $state = $self->state;
 113                 delete( $state->{_dispatch} );
 114                 #warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 115         }
 116
 117         my $out = join("\r\n",
 118                 'HTTP/1.1 200 OK',
 119                 'Content-Type: text/xml; charset="utf-8"',
 120                 'Server: Perl-CWMP/42',
 121                 'SOAPServer: Perl-CWMP/42'
 122         ) . "\r\n";
 123
 124         $out .= "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" if $state->{ID};
 125
 126         my $uid = $self->store->state_to_uid( $state );
 127
 128         my $to_uid = join(" ", grep { defined($_) } "to $uid",
 129                         # board
 130                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.HardwareVersion'},
 131                         # version
 132                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.SoftwareVersion'},
 133                         # summary
 134 #                       $state->{Parameter}->{'InternetGatewayDevice.DeviceSummary'},
 135         ) . "\n";
 136
 137         my $queue = CWMP::Queue->new({
 138                 id => $uid,
 139                 debug => $self->debug,
 140         });
 141         my $job;
 142         $xml = '';
 143
 144         if ( my $dispatch = $state->{_dispatch} ) {
 145                 $xml = $self->dispatch( $dispatch );
 146         } elsif ( $job = $queue->dequeue ) {
 147                 $xml = $self->dispatch( $job->dispatch );
 148         } else {
 149                 warn ">>> empty response $to_uid";
 150                 $state->{NoMoreRequests} = 1;
 151                 $xml = '';
 152         }
 153
 154         $out .= "Content-Length: " . length( $xml ) . "\r\n\r\n";
 155         $out .= $xml if length($xml);
 156
 157         $job->finish if $job;
 158         warn "### request over for $uid\n" if $self->debug;
 159
 160         return $out;    # next request
 161 };
 162
 163 =head2 dispatch
 164
 165   $xml = $self->dispatch('Inform', $response_arguments );
 166
 167 If debugging level of 3 or more, it will create dumps of responses named C<< dump/nr.response >>
 168
 169 =cut
 170
 171 sub dispatch {
 172         my $self = shift;
 173
 174         my $dispatch = shift || die "no dispatch?";
 175         my $args = shift;
 176
 177         my $response = CWMP::Methods->new({ debug => $self->debug });
 178
 179         if ( $response->can( $dispatch ) ) {
 180                 warn ">>> dispatching to $dispatch with args ",dump( $args ),"\n";
 181                 my $xml = $response->$dispatch( $self->state, $args );
 182                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 183                 return $xml;
 184         } else {
 185                 confess "can't dispatch to $dispatch";
 186         }
 187 };
 188
 189
 190 =head2 error
 191
 192   return $self->error( 501, 'System error' );
 193
 194 =cut
 195
 196 sub error {
 197   my ($self, $number, $msg) = @_;
 198   $msg ||= 'ERROR';
 199   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 200   warn "Error - $number - $msg\n";
 201   return 0;     # close connection
 202 }
 203
 204 1;