git.rot13.org Git - pxelator/blob - lib/PXElator/client.pm

   1 package client;
   2
   3 use warnings;
   4 use strict;
   5 use autodie;
   6
   7 use File::Slurp;
   8 use Net::Ping;
   9
  10 use server;
  11 use format;
  12 use ip;
  13
  14 our $debug = $server::debug;
  15
  16 sub mkbasedir {
  17         my $path = shift;
  18         $path =~ s{(^.*)/[^/]+$}{$1};
  19         mkdir $path unless -d $path;
  20         return $path;
  21 }
  22
  23 sub mac_path { $server::conf . '/mac/' . $_[0] }
  24 sub  ip_path { $server::conf . '/ip/'  . join('/', @_) }
  25 sub conf_value {
  26         my $path = shift;
  27         my $value;
  28         if ( -l $path ) {
  29                 $value = readlink $path;
  30                 $value =~ s{.*/([^/]+)$}{$1};
  31         } elsif ( -f $path ) {
  32                 $value = read_file $path;
  33         } else {
  34                 warn "W: $path not file or symlink\n";
  35         }
  36         return $value;
  37 }
  38
  39 sub conf {
  40         my $ip  = shift;
  41         my $name = shift;
  42         my ( $default, $value );
  43         if ( $#_ == 0 ) {
  44                 $value = shift;
  45         } elsif ( $#_ == 1 && $_[0] eq 'default' ) {
  46                 $default = $_[1]
  47         }
  48
  49         my $path = ip_path $ip;
  50         mkdir $path unless -d $path;
  51         $path .= '/' . $name;
  52
  53         if ( defined $value ) {
  54                 mkbasedir  $path;
  55                 write_file $path, $value;
  56                 warn "update $path = $value";
  57         } elsif ( ! -e $path && defined $default ) {
  58                 mkbasedir  $path;
  59                 write_file $path, $default;
  60                 warn "default $path = $default";
  61                 $value = $default;
  62         } elsif ( -f $path ) {
  63                 $value = read_file $path;
  64         } else {
  65                 warn "# $name missing $path\n" if $debug;
  66         }
  67         return $value;
  68 }
  69
  70 sub all_conf {
  71         my $ip = shift;
  72         my $path = ip_path $ip || return;
  73         my $conf;
  74         foreach my $file ( glob("$path/*") ) {
  75                 my $name = $file;
  76                 $name =~ s{^.+/([^/]+)$}{$1};
  77                 $conf->{ $name } = read_file $file;
  78         }
  79         return $conf;
  80 }
  81 sub next_ip($) {
  82         my $mac = shift;
  83         $mac = format::mac($mac);
  84
  85         my $p = Net::Ping->new;
  86
  87         my $prefix = $server::ip;
  88         $prefix =~ s{\.\d+$}{.};
  89         my $addr = $server::ip_from || die;
  90         my $ip = $prefix . $addr;
  91
  92         while ( -e ip_path($ip) || $p->ping( $ip, 0.7 ) ) {
  93                 $ip = $prefix . $addr++;
  94                 die "all addresses allocated!" if $addr == $server::ip_to;
  95                 warn "skip $ip\n";
  96         }
  97
  98         warn "next_ip $ip\n";
  99
 100         save_ip_mac( $ip, $mac );
 101
 102         return $ip;
 103 }
 104
 105 sub save_ip_mac {
 106         my ($ip,$mac) = @_;
 107         $mac = format::mac($mac);
 108
 109         mkdir ip_path($ip) unless -e ip_path($ip);
 110
 111         my $mac_path = mac_path($mac);
 112         unlink $mac_path if -l $mac_path;       # XXX audit?
 113         symlink ip_path($ip), $mac_path;
 114         write_file( ip_path($ip,'mac'), $mac );
 115 }
 116
 117 sub ip_from_mac($) {
 118         my $mac = shift;
 119         $mac = format::mac($mac);
 120
 121         my $mac_path = mac_path $mac;
 122         return unless -e $mac_path;
 123
 124         my $ip;
 125
 126         if ( -f $mac_path ) {
 127                 $ip = read_file $mac_path;
 128                 unlink $mac_path;
 129                 symlink ip_path($ip), $mac_path;
 130                 warn "I: upgrade to mac symlink $mac_path\n";
 131         } elsif ( -l $mac_path ) {
 132                 $ip = conf_value $mac_path;
 133         } else {
 134                 die "$mac_path not file or symlink";
 135         }
 136
 137         return $ip;
 138 }
 139
 140 sub mac_from_ip($) {
 141         my $ip = shift;
 142         conf_value ip_path($ip, 'mac');
 143 }
 144
 145 sub change_ip($$) {
 146         my ($old, $new) = @_;
 147         return if $old eq $new;
 148         my $mac = mac_from_ip($old) || die "no mac for $old";
 149         rename ip_path($old), ip_path($new);
 150         unlink mac_path($mac);
 151         symlink ip_path($new), mac_path($mac);
 152         return $new;
 153 }
 154
 155 sub all_ips {
 156         sort { ip::to_int($a) cmp ip::to_int($b) }
 157         map {
 158                 my $ip = $_;
 159                 $ip =~ s{^.+/ip/}{};
 160                 $ip;
 161         } glob("$server::conf/ip/*")
 162 }
 163
 164 sub remove {
 165         my $ip = shift;
 166         unlink $_ foreach grep { -e $_ } ( glob "$server::conf/ip/$ip/*" );
 167         if ( my $mac = mac_from_ip $ip ) {
 168                 unlink "$server::conf/mac/$mac";
 169         }
 170         rmdir "$server::conf/ip/$ip";
 171 }
 172
 173 1;