git.rot13.org Git - pxelator/blob - lib/PXElator/daemons.pm

   1 package daemons;
   2
   3 use warnings;
   4 use strict;
   5
   6 use File::Slurp;
   7 use Data::Dump qw/dump/;
   8
   9 use x11;
  10 use CouchDB;
  11
  12 our $pids;
  13 $pids = { httpd => $$, kvm => 'not started' } unless defined $pids; # keep pids on refresh
  14
  15 sub DESTROY {
  16         warn "pids ",dump( $pids );
  17         foreach ( values %$pids ) {
  18                 warn "kill $_";
  19                 kill 1,$_ || kill 9, $_;
  20         }
  21 }
  22
  23 $SIG{CHLD} = 'IGNORE';
  24
  25 sub audit {
  26         my $msg = shift;
  27         my $daemon = shift;
  28         CouchDB::audit( $msg, $daemon, { daemon => $daemon, message => $msg, @_ } );
  29 }
  30
  31 sub start_stop {
  32         my $daemon = shift;
  33
  34         my $pid = $pids->{$daemon};
  35         my $pid_path = "$server::conf/$daemon.pid";
  36
  37         if ( ! $pid && -e $pid_path ) {
  38                 my $p = read_file $pid_path;
  39                 if ( kill 0, $p ) {
  40                         audit 'adopted', $daemon, pid => $p;
  41                         return $pids->{$daemon} = $p;
  42                 } else {
  43                         audit 'not running', $daemon, pid => $p;
  44                         unlink $pid_path;
  45                 }
  46         }
  47
  48         $pid ||= 'not started';
  49         warn "start_stop $daemon $pid\n";
  50
  51         if ( $pid =~ m{^\d+$} ) {
  52                 my $pstree = `pstree -p $pid`;
  53                 my @pids = $pstree =~ m{\((\d+)\)}g;
  54                 warn "pstree $pstree pids ",dump( @pids );
  55                 kill 1, $_ foreach reverse @pids;
  56                 $pids->{$daemon} = 'stopped';
  57                 audit 'stopped', $daemon, pid => $pid;
  58                 return qq|$daemon pid $pid stopped|;
  59         } else {
  60                 if ( $pid = fork ) {
  61                         # parent
  62                         $pids->{$daemon} = $pid;
  63                         write_file $pid_path, $pid;
  64                         audit 'forked', $daemon, pid => $pid;
  65                         return qq|$daemon pid $pid started|;
  66                 } elsif ( defined $pid ) {
  67                         # child
  68                         my $invoke = 'start';
  69                         $invoke = $1 if $daemon =~ s{/(.+)}{};
  70                         if ( $daemon =~ m{dhcpd|tftpd|dnsd} ) {
  71                                 my $exec = "perl -I$server::base_dir/lib -I$server::base_dir/lib/PXElator -M$daemon -e ${daemon}::${invoke}";
  72                                 audit 'exec', $daemon, 'exec' => $exec;
  73                                 x11::xterm( $daemon => $exec );
  74                         } else {
  75                                 my $eval = $daemon . '::' . $invoke . '(' . ( @_ ? dump(@_) : '' ) . ')';
  76                                 audit 'eval', $daemon, 'eval' => $eval;
  77                                 eval $eval;
  78                                 audit 'error', $daemon, error => $@  if $@;
  79                         }
  80                         exit;
  81                 } else {
  82                         audit 'error', $daemon, error => $!;
  83                         die "fork error $!";
  84                 }
  85         }
  86 }
  87