git.rot13.org Git - webpac/blob - all2xml.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Biblio::Isis;
   5 use Getopt::Std;
   6 use Data::Dumper;
   7 use XML::Simple;
   8 use Text::Iconv;
   9 use Config::IniFiles;
  10 use Encode;
  11 #use GDBM_File;
  12 use Fcntl;      # for O_RDWR
  13 use TDB_File;
  14
  15 $|=1;
  16
  17 my $config_file = $0;
  18 $config_file =~ s/\.pl$/.conf/;
  19 $config_file = $ARGV[0] if ($ARGV[0] && -f $ARGV[0]);
  20 die "FATAL: can't find configuration file '$config_file'" if (! -e $config_file);
  21
  22 my $config;
  23
  24 #use index_DBI;         # default DBI module for index
  25 #use index_DBI_cache;   # faster DBI module using memory cache
  26 use index_DBI_filter;   # filter support for indexes
  27 my $index;
  28
  29 my %opts;
  30
  31 # usage:
  32 #       -d directory name
  33 #       -m multiple directories
  34 #       -q quiet
  35 #       -s run swish
  36
  37 getopts('d:m:qs', \%opts);
  38
  39 my $path;       # this is name of database
  40
  41 Text::Iconv->raise_error(0);     # Conversion errors don't raise exceptions
  42
  43 # this is encoding of all files on disk, including import_xml/*.xml file and
  44 # filter/*.pm files! It will be used to store strings in perl internally!
  45 my $codepage = 'ISO-8859-2';
  46
  47 my $utf2cp = Text::Iconv->new('UTF-8',$codepage);
  48 # this function will convert data from XML files to local encoding
  49 sub x {
  50         return $utf2cp->convert($_[0]);
  51 }
  52
  53 # decode isis/excel or other import codepage
  54 my $import2cp;
  55
  56 # outgoing xml must be in UTF-8
  57 my $cp2utf = Text::Iconv->new($codepage,'UTF-8');
  58
  59 # mapping between data type and tag which specify
  60 # format in XML file
  61 my %type2tag = (
  62         'isis' => 'isis',
  63         'excel' => 'column',
  64         'marc' => 'marc',
  65         'feed' => 'feed'
  66 );
  67
  68 my $cache;      # for cacheing
  69
  70 # lookup hash (tied to file)
  71 my %lhash;
  72 # this option will cache all lookup entries in memory.
  73 # if you are tight on memory, turn this off
  74 my $use_lhash_cache = 1;
  75
  76 my $last_field_name;    # cache to prevent repeated fields
  77
  78 sub data2xml {
  79
  80         use xmlify;
  81
  82         my $type = shift @_;
  83         my $row = shift @_;
  84         my $add_xml = shift @_;
  85         # needed to read values from configuration file
  86         my $cfg = shift @_;
  87         my $database = shift @_;
  88
  89         my $xml;
  90
  91         use parse_format;
  92
  93         my $html = "";          # html formatted display output
  94
  95         my %field_usage;        # counter for usage of each field
  96
  97         # sort subrouting using order="" attribute
  98         sub by_order {
  99                 my $va = $config->{indexer}->{$a}->{order} ||
 100                         $config->{indexer}->{$a};
 101                 my $vb = $config->{indexer}->{$b}->{order} ||
 102                         $config->{indexer}->{$b};
 103
 104                 return $va <=> $vb;
 105         }
 106
 107         my @sorted_tags;
 108         if ($cache->{tags_by_order}) {
 109                 @sorted_tags = @{$cache->{tags_by_order}};
 110         } else {
 111                 @sorted_tags = sort by_order keys %{$config->{indexer}};
 112                 $cache->{tags_by_order} = \@sorted_tags;
 113         }
 114
 115         # lookup key
 116         my $lookup_key;
 117
 118         # cache for field in pages
 119         delete $cache->{display_data};
 120         delete $cache->{swish_data};
 121         delete $cache->{swish_exact_data};
 122         delete $cache->{index_data};
 123         delete $cache->{index_delimiter};
 124         my @page_fields;        # names of fields
 125
 126
 127         # subs used to produce output
 128
 129         sub get_field_name($$$) {
 130                 my ($config,$field,$field_usage) = @_;
 131
 132                 # find field name (signular, plural)
 133                 my $field_name = "";
 134                 if ($config->{indexer}->{$field}->{name_singular} && $field_usage == 1) {
 135                         $field_name = $config->{indexer}->{$field}->{name_singular};
 136                 } elsif ($config->{indexer}->{$field}->{name_plural}) {
 137                         $field_name = $config->{indexer}->{$field}->{name_plural};
 138                 } elsif ($config->{indexer}->{$field}->{name}) {
 139                         $field_name = $config->{indexer}->{$field}->{name};
 140                 } else {
 141                         print STDERR "WARNING: field '$field' doesn't have 'name' attribute!";
 142                 }
 143
 144                 if ($field_name) {
 145                         $field_name = x($field_name);
 146                         if (! $last_field_name) {
 147                                 $last_field_name = $field_name;
 148                                 return $last_field_name;
 149                         } elsif ($field_name ne $last_field_name) {
 150                                 $last_field_name = $field_name;
 151                                 return $last_field_name;
 152                         }
 153                 }
 154         }
 155
 156
 157         # init variables for different types
 158         sub init_visible_type($) {
 159                 my $type = shift;
 160
 161                 # swish, swish_exact, display, index, index_lookup
 162                 # swish and display defaults
 163                 my ($s,$se,$d,$i,$il) = (1,0,1,0,0);
 164                 if (lc($type) eq "display") {
 165                         $s = 0;
 166                 } elsif (lc($type) eq "swish") {
 167                         $d = 0;
 168                 } elsif (lc($type) eq "index") {
 169                         ($s,$se,$d,$i) = (0,1,0,1);
 170                 } elsif (lc($type) eq "swish_exact") {
 171                         ($s,$se,$d,$i) = (0,1,0,0);
 172                 } elsif (lc($type) =~ /^lookup/) {
 173                         ($s,$se,$d,$i,$il) = (0,1,0,0,1);
 174                 } elsif ($type) {
 175                         print STDERR "WARNING: unknown type: $type\n";
 176                 }
 177                 return ($s,$se,$d,$i,$il);
 178         }
 179
 180
 181         # convert
 182         #
 183         # <tag>
 184         #  <delimiter>, </delimiter>
 185         #  <value>200a</value>
 186         # </tag>
 187         #
 188         # to
 189         #
 190         # <tag delimiter=", ">200a</tag>
 191         #
 192         # but without loosing spaces in delimiter (becasue
 193         # new XML::Simple strips spaces in attribute values
 194         # as defined in XML specification)
 195         #
 196         sub unroll_x($) {
 197                 my $x = shift;
 198
 199                 if (defined $x->{value}) {
 200                         my ($v,$d) = ($x->{value}->{content}, $x->{delimiter}->{content});
 201                         delete $x->{value};
 202                         delete $x->{delimiter};
 203                         $x->{content} = $v;
 204                         $x->{delimiter} = $d;
 205                 }
 206                 return $x;
 207         }
 208
 209         # begin real work: go field by field
 210         foreach my $field (@sorted_tags) {
 211
 212                 $field=x($field);
 213                 $field_usage{$field}++;
 214
 215                 my $swish_data = "";
 216                 my $swish_exact_data = "";
 217                 my $display_data = "";
 218                 my @index_data;
 219                 my $line_delimiter;
 220
 221                 my ($swish,$display);
 222
 223                 my $tag = $type2tag{$type} || die "can't find which tag to use for type $type";
 224
 225                 # is this field page-by-page?
 226                 my $iterate_by_page = $config->{indexer}->{$field}->{iterate_by_page};
 227                 push @page_fields,$field if ($iterate_by_page);
 228                 my %page_max = ();
 229                 # default line_delimiter if using
 230                 my $page_line_delimiter = $config->{indexer}->{$field}->{page_line_delimiter} || '<br/>';
 231                 $cache->{index_delimiter}->{$field} = $config->{indexer}->{$field}->{index_delimiter};
 232
 233                 my $format_name = $config->{indexer}->{$field}->{format_name};
 234                 my $format_delimiter = $config->{indexer}->{$field}->{format_delimiter};
 235                 if ($format_name && $format_delimiter) {
 236                         $cache->{format}->{$field}->{format_name} = $format_name;
 237                         $cache->{format}->{$field}->{format_delimiter} = $format_delimiter;
 238                 }
 239
 240                 foreach my $x (@{$config->{indexer}->{$field}->{$tag}}) {
 241
 242                         $x = unroll_x($x);
 243
 244                         my $format = x($x->{content});
 245                         my $delimiter = x($x->{delimiter}) || ' ';
 246
 247                         my $repeat_off = 0;     # init repeatable offset
 248
 249                         my ($s,$se,$d,$i,$il) = init_visible_type($x->{type});
 250
 251                         # what will separate last line from this one?
 252                         if ($display_data && $x->{append}) {
 253                                 $line_delimiter = $delimiter;
 254                         } elsif ($display_data) {
 255                                 $line_delimiter = '<br/>';
 256                         }
 257
 258                         # init vars so that we go into while...
 259                         ($swish,$display) = (1,1);
 260
 261                         sub mkformat($$) {
 262                                 my $x = shift || die "mkformat needs tag reference";
 263                                 my $data = shift || return;
 264                                 my $format_name = x($x->{format_name}) || return $data;
 265                                 my $fmt = x($config->{format}->{$format_name}->{content}) || die "<format name=\"$format_name\"> is not defined!";
 266                                 my $format_delimiter = x($x->{format_delimiter});
 267                                 my @data;
 268                                 if ($format_delimiter) {
 269                                         @data = split(/$format_delimiter/,$data);
 270                                 } else {
 271                                         push @data,$data;
 272                                 }
 273
 274                                 if ($fmt) {
 275                                         my $nr = scalar $fmt =~ s/%s/%s/g;
 276                                         if (($#data+1) == $nr) {
 277                                                 return sprintf($fmt,@data);
 278                                         } else {
 279                                                 #print STDERR "mkformat: [$data] can't be split on [$format_delimiter] to $nr fields!\n";
 280                                                 return $data;
 281                                         }
 282                                 } else {
 283                                         print STDERR "usage of link '$format_name' without defined format (<link> tag)\n";
 284                                 }
 285                         }
 286
 287                         # while because of repeatable fields
 288                         while ($swish || $display) {
 289                                 my $page = $repeat_off;
 290                                 $page_max{$field} = $page if ($iterate_by_page && $page > ($page_max{$field} || 0));
 291                                 ($swish,$display) = parse_format($type, $format,$row,$repeat_off++,$import2cp);
 292                                 if ($repeat_off > 1000) {
 293                                         print STDERR "loop (more than 1000 repeatable fields) deteced in $row, $format\n";
 294                                         last;
 295                                 }
 296
 297                                 # is this field is lookup?
 298                                 if ($display && $x->{lookup}) {
 299                                         my $null = "<!-- null -->";
 300                                         if ($use_lhash_cache) {
 301                                                 if (!defined($cache->{lhash}->{$display})) {
 302                                                         my $new_display = $lhash{$display};
 303                                                         if (defined($new_display)) {
 304 #print STDERR "lookup cache store '$display' = '$new_display'\n";
 305                                                                 $display = $new_display;
 306                                                                 $cache->{lhash}->{$display} = $new_display;
 307                                                         } else {
 308 #                                                               print STDERR "WARNING: lookup for '$display' didn't find anything.\n";
 309                                                                 $display = "";
 310                                                                 $cache->{lhash}->{$display} = $null;
 311                                                         }
 312                                                 } else {
 313                                                         $display = $cache->{lhash}->{$display};
 314                                                 }
 315                                         } else {
 316                                                 $display = $lhash{$display} || $null;
 317                                         }
 318                                 }
 319
 320                                 # filter="name" ; filter this field through
 321                                 # filter/[name].pm
 322                                 my $filter = $x->{filter};
 323                                 if ($filter && !$cache->{filter_loaded}->{$filter}) {
 324                                         require "filter/".$filter.".pm";
 325                                         $cache->{filter_loaded}->{$filter}++;
 326                                 }
 327                                 # type="swish" ; field for swish
 328                                 if ($swish) {
 329                                         my $tmp = $swish;
 330                                         if ($filter && ($s || $se)) {
 331                                                 no strict 'refs';
 332                                                 $tmp = join(" ",&$filter($tmp)) if ($s || $se);
 333                                         }
 334
 335                                         $swish_data .= $tmp if ($s && $tmp);
 336                                         $swish_exact_data .= "xxbxx $tmp xxexx " if ($tmp && $tmp ne "" && $se);
 337                                 }
 338
 339                                 # type="display" ; field for display
 340                                 if ($d && $display) {
 341                                         my $ldel = $delimiter;
 342                                         if ($line_delimiter && $display_data) {
 343                                                 $ldel = $line_delimiter;
 344                                         }
 345                                         if ($filter) {
 346                                                 no strict 'refs';
 347                                                 my @arr;
 348                                                 foreach my $tmp (&$filter($display)) {
 349                                                         my $tmp2 = mkformat($x,$tmp);
 350                                                         push @arr,$tmp2 if ($tmp2);
 351                                                 }
 352                                                 $display_data .= $ldel if ($display_data && @arr);
 353                                                 $display_data .= join($delimiter,@arr);
 354                                         } else {
 355                                                 $display_data .= $ldel if ($display_data);
 356                                                 my $tmp = mkformat($x,$display);
 357                                                 $display_data .= $tmp if ($tmp);
 358                                         }
 359                                 }
 360
 361                                 # type="index" ; insert into index
 362                                 my $idisplay;
 363                                 if ($i && $display) {
 364                                         $idisplay = $display;
 365                                         if ($filter) {
 366                                                 no strict 'refs';
 367                                                 $idisplay = &$filter($idisplay);
 368                                         }
 369                                         push @index_data, $idisplay if ($idisplay && !$iterate_by_page);
 370                                 }
 371
 372                                 # store fields in lookup
 373                                 if ($il && $display) {
 374                                         if (lc($x->{type}) eq "lookup_key") {
 375                                                 if ($lookup_key) {
 376                                                         print STDERR "WARNING: try to redefine lookup_key (keys shouldn't be repeatable fields!)";
 377                                                 } else {
 378                                                         if ($filter) {
 379                                                                 no strict 'refs';
 380                                                                 $lookup_key = &$filter($display);
 381                                                         } else {
 382                                                                 $lookup_key = $display;
 383                                                         }
 384                                                 }
 385                                         } elsif (lc($x->{type}) eq "lookup_val") {
 386                                                 if ($lookup_key) {
 387                                                         if ($filter) {
 388                                                                 no strict 'refs';
 389                                                                 $lhash{$lookup_key} = &$filter($display);
 390                                                         } else {
 391                                                                 $lhash{$lookup_key} = $display;
 392                                                         }
 393                                                 } else {
 394                                                         print STDERR "WARNING: no lookup_key defined for  '$display'?";
 395                                                 }
 396                                         }
 397
 398                                 }
 399
 400                                 # store data for page-by-page repeatable fields
 401                                 if ($iterate_by_page) {
 402                                         sub iterate_fld($$$$$$) {
 403                                                 my ($cache,$what,$field,$page,$data,$append) = @_;
 404                                                 return if (!$data);
 405
 406                                                 my $ldel = $page_line_delimiter;
 407                                                 $ldel = " " if ($append);
 408 #print STDERR "line delimiter: ",Dumper($ldel) if ($ldel);
 409                                                 if (! $cache->{$what}->{$field}->[$page]) {
 410                                                         $cache->{$what}->{$field}->[$page] = $data;
 411                                                 } else {
 412                                                         $cache->{$what}->{$field}->[$page] .= $ldel.$data;
 413                                                 }
 414                                         }
 415
 416                                         if ($display_data) {
 417                                                 iterate_fld($cache,'display_data',$field,$page,$display_data,$x->{append});
 418                                         }
 419                                                 $display_data = "";
 420                                         if ($swish_data) {
 421                                                 iterate_fld($cache,'swish_data',$field,$page,$swish_data,$x->{append});
 422                                                 $swish_data = "";
 423                                         }
 424                                         if ($swish_exact_data) {
 425                                                 iterate_fld($cache,'swish_exact_data',$field,$page,$swish_exact_data,$x->{append});
 426                                                 $swish_exact_data = "";
 427                                         }
 428
 429                                         if ($idisplay) {
 430                                                 my $ldel=$page_line_delimiter;
 431                                                 my @index_data;
 432                                                 if ($cache->{index_data}->{$field}->[$page]) {
 433
 434                                                         @index_data = @{$cache->{index_data}->{$field}->[$page]};
 435                                                 }
 436                                                 if ($x->{append}) {
 437                                                         if (@index_data) {
 438                                                                 $index_data[$#index_data] .= $idisplay;
 439                                                         } else {
 440                                                                 push @index_data, $idisplay;
 441                                                         }
 442                                                 } else {
 443                                                         push @index_data, $idisplay;
 444                                                 }
 445                                                 $idisplay = "";
 446                                                 @{$cache->{index_data}->{$field}->[$page]} = @index_data;
 447                                         }
 448                                 }
 449                         }
 450
 451                         if (! $iterate_by_page) {
 452                                 my $idel = $x->{index_delimiter};
 453                                 # fill data in index
 454                                 foreach my $tmp (@index_data) {
 455                                         my $i = $d = $tmp;
 456                                         if ($idel && $tmp =~ m/$idel/) {
 457                                                 ($i,$d) = split(/$idel/,$tmp);
 458                                         }
 459                                         $index->insert($field, $i, $d, $path);
 460                                 }
 461                                 @index_data = ();
 462                         }
 463                 }
 464
 465                 # now try to parse variables from configuration file
 466                 foreach my $x (@{$config->{indexer}->{$field}->{'config'}}) {
 467
 468                         $x = unroll_x($x);
 469
 470                         my $delimiter = x($x->{delimiter}) || ' ';
 471                         my $val = $cfg->val($database, x($x->{content}));
 472
 473                         # FIXME index_lookup is not supported!
 474                         my ($s,$se,$d,$i,$il) = init_visible_type($x->{type});
 475
 476                         if ($val) {
 477                                 $display_data .= $delimiter.$val if ($d);
 478                                 $swish_data .= " ".$val if ($s);
 479                                 $index->insert($field, $val, $path) if ($i);
 480                         }
 481
 482                         if ($iterate_by_page) {
 483                                 # FIXME data from config tag will appear just
 484                                 # on first page!!!
 485                                 my $page = 0;
 486                                 if ($display_data) {
 487                                         $cache->{display_data}->{$field}->[$page] = $display_data;
 488                                         $display_data = "";
 489                                 }
 490                                 if ($swish_data) {
 491                                         $cache->{swish_data}->{$field}->[$page] = $swish_data;
 492                                         $swish_data = "";
 493                                 }
 494                                 if ($swish_exact_data) {
 495                                         $cache->{swish_exact_data}->{$field}->[$page] = $swish_exact_data;
 496                                         $swish_exact_data = "";
 497                                 }
 498                         }
 499                 }
 500
 501                 # save data page-by-page
 502                 foreach my $field (@page_fields) {
 503                         my $nr_pages = $page_max{$field} || next;
 504 #print STDERR "field '$field' iterate over ",($nr_pages || 0)," pages...\n";
 505 #print STDERR Dumper($cache->{display_data});
 506                         for (my $page=0; $page <= $nr_pages; $page++) {
 507                                 my $display_data;
 508                                 if ($cache->{format}->{$field}) {
 509                                         my $tmp = mkformat($cache->{format}->{$field},$cache->{display_data}->{$field}->[$page]);
 510                                         $display_data=$tmp if ($tmp);
 511                                 } else {
 512                                         $display_data = $cache->{display_data}->{$field}->[$page];
 513                                 }
 514                                 if ($display_data) { # default
 515                                         if ($field eq "headline") {
 516                                                 $xml .= xmlify("headline", $display_data);
 517                                         } else {
 518
 519                                                 # fallback to empty field name if needed
 520                                                 $html .= get_field_name($config,$field,$field_usage{$field}) || '';
 521                                                 $html .= "#-#".$display_data."###\n";
 522                                         }
 523                                 }
 524
 525                                 my $swish_data = $cache->{swish_data}->{$field}->[$page];
 526                                 if ($swish_data) {
 527                                         # remove extra spaces
 528                                         $swish_data =~ s/ +/ /g;
 529                                         $swish_data =~ s/ +$//g;
 530
 531                                         $xml .= xmlify($field."_swish", my_unac_string($codepage,$swish_data));
 532                                 }
 533
 534                                 my $swish_exact_data = $cache->{swish_exact_data}->{$field}->[$page];
 535                                 if ($swish_exact_data) {
 536                                         $swish_exact_data =~ s/ +/ /g;
 537                                         $swish_exact_data =~ s/ +$//g;
 538
 539                                         # add delimiters before and after word.
 540                                         # That is required to produce exact match
 541                                         $xml .= xmlify($field."_swish_exact", my_unac_string($codepage,$swish_exact_data));
 542                                 }
 543
 544                                 my $idel = $cache->{index_delimiter}->{$field};
 545                                 foreach my $tmp (@{$cache->{index_data}->{$field}->[$page]}) {
 546                                         my $i = $tmp;
 547                                         my $d = $tmp;
 548                                         if ($idel && $tmp =~ m/$idel/) {
 549                                                 ($i,$d) = split(/$idel/,$tmp);
 550                                         }
 551                                         $index->insert($field, $i, $d, $path);
 552 #print STDERR "index [$idel] $field: $i --> $d [$path]\n";
 553                                 }
 554                         }
 555
 556                 }
 557
 558                 if (! $iterate_by_page) {
 559                         if ($display_data) {
 560                                 if ($field eq "headline") {
 561                                         $xml .= xmlify("headline", $display_data);
 562                                 } else {
 563
 564                                         # fallback to empty field name if needed
 565                                         $html .= get_field_name($config,$field,$field_usage{$field}) || '';
 566                                         $html .= "#-#".$display_data."###\n";
 567                                 }
 568                         }
 569                         if ($swish_data) {
 570                                 # remove extra spaces
 571                                 $swish_data =~ s/ +/ /g;
 572                                 $swish_data =~ s/ +$//g;
 573
 574                                 $xml .= xmlify($field."_swish", my_unac_string($codepage,$swish_data));
 575                         }
 576
 577                         if ($swish_exact_data) {
 578                                 $swish_exact_data =~ s/ +/ /g;
 579                                 $swish_exact_data =~ s/ +$//g;
 580
 581                                 # add delimiters before and after word.
 582                                 # That is required to produce exact match
 583                                 $xml .= xmlify($field."_swish_exact", my_unac_string($codepage,$swish_exact_data));
 584                         }
 585                 }
 586         }
 587
 588         # dump formatted output in <html>
 589         if ($html) {
 590                 #$xml .= xmlify("html",$html);
 591                 $xml .= "<html><![CDATA[ $html ]]></html>";
 592         }
 593
 594         if ($xml) {
 595                 $xml .= $add_xml if ($add_xml);
 596                 return "<xml>\n$xml</xml>\n";
 597         } else {
 598                 return;
 599         }
 600 }
 601
 602 ##########################################################################
 603
 604 # read configuration for this script
 605 my $cfg = new Config::IniFiles( -file => $config_file );
 606
 607 # read global.conf configuration
 608 my $cfg_global = new Config::IniFiles( -file => 'global.conf' );
 609
 610 # open index
 611 $index = new index_DBI(
 612                 $cfg_global->val('global', 'dbi_dbd'),
 613                 $cfg_global->val('global', 'dbi_dsn'),
 614                 $cfg_global->val('global', 'dbi_user'),
 615                 $cfg_global->val('global', 'dbi_passwd') || '',
 616         );
 617
 618 my $show_progress = $cfg_global->val('global', 'show_progress');
 619
 620 my $my_unac_filter = $cfg_global->val('global', 'my_unac_filter');
 621 if ($my_unac_filter) {
 622         print STDERR "using $my_unac_filter to filter characters for search\n";
 623         require $my_unac_filter;
 624 } else {
 625         print STDERR "### fallback to default my_unac_string!\n";
 626         eval q{
 627         sub main::my_unac_string($$) {
 628                 my ($charset, $string) = (@_);
 629                 return $string;
 630         }
 631         };
 632 }
 633
 634 foreach my $database ($cfg->Sections) {
 635
 636         # save database name in global variable path for later
 637         # (need for index filter creation)
 638         $path = $database;
 639
 640         my $type = lc($cfg -> val($database, 'type')) || die "$database doesn't have 'type' defined";
 641         my $add_xml = $cfg -> val($database, 'xml');    # optional
 642
 643         # create new lookup file
 644         my $lookup_file = $cfg -> val($database, 'lookup_newfile'); # optional
 645         if ($lookup_file) {
 646                 #tie %lhash, 'GDBM_File', $lookup_file, &GDBM_NEWDB, 0644;
 647                 if (! -e $lookup_file) {
 648                         open(LOOKUP, "> $lookup_file") || die "can't create $lookup_file': $!";
 649                         close(LOOKUP);
 650                 }
 651                 tie %lhash, 'TDB_File', $lookup_file, TDB_CLEAR_IF_FIRST, O_RDWR, 0644;
 652                 print STDERR "creating lookup file '$lookup_file'\n";
 653                 # delete memory cache for lookup file
 654                 delete $cache->{lhash};
 655         }
 656
 657         # open existing lookup file
 658         $lookup_file = $cfg -> val($database, 'lookup_open'); # optional
 659         if ($lookup_file) {
 660                 #tie %lhash, 'GDBM_File', $lookup_file, &GDBM_READER, 0644;
 661                 tie %lhash, 'TDB_File', $lookup_file, TDB_DEFAULT, O_RDWR, 0644;
 662                 print STDERR "opening lookup file '$lookup_file'\n";
 663         }
 664
 665 print STDERR "reading ./import_xml/$type.xml\n";
 666
 667         # extract just type basic
 668         my $type_base = $type;
 669         $type_base =~ s/_.+$//g;
 670
 671         $config=XMLin("./import_xml/$type.xml", ForceArray => [ $type2tag{$type_base}, 'config', 'format' ], ForceContent => 1 );
 672
 673         # helper for progress bar
 674         sub fmt_time {
 675                 my $t = shift || 0;
 676                 my $out = "";
 677
 678                 my ($ss,$mm,$hh) = gmtime($t);
 679                 $out .= "${hh}h" if ($hh);
 680                 $out .= sprintf("%02d:%02d", $mm,$ss);
 681                 $out .= "  " if ($hh == 0);
 682                 return $out;
 683         }
 684
 685         # output current progress indicator
 686         my $last_p = 0;
 687         my $start_t = time();
 688         sub progress {
 689                 return if (! $show_progress);
 690                 my $current = shift;
 691                 my $total = shift || 1;
 692                 my $p = int($current * 100 / $total);
 693                 if ($p < $last_p || $current == 1) {
 694                         $start_t = time();
 695                         $last_p = 0;
 696                 } elsif ($p != $last_p) {
 697                         my $rate = ($current / (time() - $start_t || 1));
 698                         my $eta = ($total-$current) / ($rate || 1);
 699                         printf STDERR ("%5d [%-38s] %-5d %0.1f/s %s\r",$current,"=" x ($p/3)."$p%>", $total, $rate, fmt_time($eta));
 700                         $last_p = $p;
 701                 }
 702         }
 703
 704         my $fake_dir = 1;
 705         my $fake_pos = 0;
 706         my $last_fake_t = time();
 707         sub fakeprogress {
 708                 return if (! $show_progress);
 709                 my $current = shift @_;
 710
 711                 my @ind = ('-','\\','|','/','-','\\','|','/');
 712
 713                 if ($current < $fake_pos) {
 714                         $start_t = time();
 715                         $last_fake_t = 0;
 716                         $fake_dir = 1;
 717                         $fake_pos = 0;
 718                 }
 719
 720                 if (time()-$last_fake_t >= 1) {
 721                         $last_fake_t = time();
 722                         $fake_pos += $fake_dir;
 723                         $fake_dir = -$fake_dir if ($fake_pos > 38);
 724                 }
 725
 726                 if ($current % 10 == 0) {
 727                         my $rate = ($current / (time() - $start_t || 1));
 728                         printf STDERR ("%5d [%-38s] %0.1f/s\r",$current, " " x $fake_pos .$ind[($current / 10) % 8], $rate);
 729                 }
 730         }
 731
 732         # now read database
 733 print STDERR "using: $type...\n";
 734
 735         # erase cache for tags by order in this database
 736         delete $cache->{tags_by_order};
 737
 738         if ($type_base eq "isis") {
 739
 740                 my $isis_db = $cfg -> val($database, 'isis_db') || die "$database doesn't have 'isis_db' defined!";
 741
 742                 $import2cp = Text::Iconv->new($config->{isis_codepage},$codepage);
 743                 my $db = new Biblio::Isis( isisdb => $isis_db );
 744
 745                 if (! $db) {
 746                         print STDERR "FATAL: can't read ISIS database: $isis_db, skipping...\n";
 747                         next;
 748                 }
 749
 750                 my $max_rowid = $db->count if ($db);
 751
 752                 print STDERR "Reading database: $isis_db [$max_rowid rows]\n";
 753
 754                 for (my $row_id = 1; $row_id <= $max_rowid; $row_id++ ) {
 755                         my $row = $db->to_hash( $row_id );
 756                         if ($row) {
 757
 758                                 $row->{mfn} = $row_id;
 759                                 $row->{record} = $db->{record};
 760
 761                                 progress($row->{mfn}, $max_rowid);
 762
 763                                 my $swishpath = $path."#".int($row->{mfn});
 764
 765                                 if (my $xml = data2xml($type_base,$row,$add_xml,$cfg,$database)) {
 766                                         $xml = $cp2utf->convert($xml);
 767                                         use bytes;      # as opposed to chars
 768                                         print "Path-Name: $swishpath\n";
 769                                         print "Content-Length: ".(length($xml)+1)."\n";
 770                                         print "Document-Type: XML\n\n$xml\n";
 771                                 }
 772                         }
 773                 }
 774                 print STDERR "\n";
 775
 776         } elsif ($type_base eq "excel") {
 777                 require Spreadsheet::ParseExcel;
 778                 require Spreadsheet::ParseExcel::Utility;
 779                 import Spreadsheet::ParseExcel::Utility qw(int2col);
 780
 781                 $import2cp = Text::Iconv->new($config->{excel_codepage},$codepage);
 782                 my $excel_file = $cfg -> val($database, 'excel_file') || die "$database doesn't have 'excel_file' defined!";
 783
 784                 my $sheet = x($config->{sheet}) || die "no sheet in $type.xml";
 785                 my $start_row = x($config->{start_row}) - 1 || die "no start_row in $type.xml";
 786
 787                 my $oBook = Spreadsheet::ParseExcel::Workbook->Parse($excel_file) || die "can't open Excel file '$excel_file'";
 788
 789                 my $sheet_nr = 0;
 790                 foreach my $oWks (@{$oBook->{Worksheet}}) {
 791                         #print STDERR "-- SHEET $sheet_nr:", $oWks->{Name}, "\n";
 792                         last if ($oWks->{Name} eq $sheet);
 793                         $sheet_nr++;
 794                 }
 795
 796                 my $oWorksheet = $oBook->{Worksheet}[$sheet_nr];
 797
 798                 print STDERR "using sheet: ",$oWorksheet->{Name},"\n";
 799                 defined ($oWorksheet) || die "can't find sheet '$sheet' in $excel_file";
 800                 my $end_row = x($config->{end_row}) || $oWorksheet->{MaxRow};
 801
 802                 for(my $iR = $start_row ; defined $end_row && $iR <= $end_row ; $iR++) {
 803                         my $row;
 804                         for(my $iC = $oWorksheet->{MinCol} ; defined $oWorksheet->{MaxCol} && $iC <= $oWorksheet->{MaxCol} ; $iC++) {
 805                                 my $cell = $oWorksheet->{Cells}[$iR][$iC];
 806                                 if ($cell) {
 807                                         # this conversion is a cludge.
 808                                         # Files from Excell could have
 809                                         # characters which don't fit into
 810                                         # destination encoding.
 811                                         $row->{int2col($iC)} = $utf2cp->convert($cell->Value) || $cell->Value;
 812                                 }
 813                         }
 814
 815                         progress($iR, $end_row);
 816
 817 #                       print "row[$iR/$end_row] ";
 818 #                       foreach (keys %{$row}) {
 819 #                               print "$_: ",$row->{$_},"\t";
 820 #                       }
 821 #                       print "\n";
 822
 823                         my $swishpath = $database."#".$iR;
 824
 825                         next if (! $row);
 826
 827                         if (my $xml = data2xml($type_base,$row,$add_xml,$cfg,$database)) {
 828                                 $xml = $cp2utf->convert($xml);
 829                                 use bytes;      # as opposed to chars
 830                                 print "Path-Name: $swishpath\n";
 831                                 print "Content-Length: ".(length($xml)+1)."\n";
 832                                 print "Document-Type: XML\n\n$xml\n";
 833                         }
 834                 }
 835
 836                 print STDERR "\n";
 837
 838         } elsif ($type_base eq "marc") {
 839
 840                 require MARC::File::USMARC;
 841
 842                 $import2cp = Text::Iconv->new($config->{marc_codepage},$codepage);
 843                 my $marc_file = $cfg -> val($database, 'marc_file') || die "$database doesn't have 'marc_file' defined!";
 844
 845                 # optional argument is format
 846                 warn "marc_format is no longer used!" if ($config->{marc_format});
 847                 print STDERR "Reading MARC file '$marc_file'\n";
 848
 849                 my $marc = MARC::File::USMARC->in( $marc_file );
 850
 851                 if (! $marc) {
 852                         print STDERR "FATAL: can't read MARC file: $marc_file, skipping...\n";
 853                         next;
 854                 }
 855
 856                 # count records in MARC file
 857                 sub marc_count {
 858                         my $filename = shift || die;
 859                         my $file = MARC::File::USMARC->in($filename) || return;
 860                         my $count = 0;
 861                         while ($file->skip()) {
 862                                 $count++;
 863                         }
 864                         return $count;
 865                 }
 866
 867                 my $count = marc_count($marc_file) || warn "no records in '$marc_file'?";
 868
 869                 my $i = 1;
 870
 871                 while( my $rec = $marc->next() ) {
 872
 873                         progress($i,$count);
 874
 875                         my $swishpath = $database."#".$i;
 876
 877                         if (my $xml = data2xml($type_base,$rec,$add_xml,$cfg,$database)) {
 878                                 $xml = $cp2utf->convert($xml);
 879                                 use bytes;      # as opposed to chars
 880                                 print "Path-Name: $swishpath\n";
 881                                 print "Content-Length: ".(length($xml)+1)."\n";
 882                                 print "Document-Type: XML\n\n$xml\n";
 883                         }
 884
 885                         $i++;
 886                 }
 887
 888                 print STDERR "\n";
 889
 890         } elsif ($type_base eq "feed") {
 891
 892                 $import2cp = Text::Iconv->new($config->{feed_codepage},$codepage);
 893                 my $prog = x($config->{prog}) || die "$database doesn't have 'prog' defined!";
 894
 895                 print STDERR "Reading feed from program '$prog'\n";
 896
 897                 open(FEED,"feeds/$prog |") || die "can't start $prog: $!";
 898
 899                 my $i=1;        # record nr.
 900
 901                 my $data;
 902                 my $line=1;
 903
 904                 while (<FEED>) {
 905                         chomp;
 906
 907                         if (/^$/) {
 908                                 my $swishpath = $database."#".$i++;
 909
 910                                 if (my $xml = data2xml($type_base,$data,$add_xml,$cfg,$database)) {
 911                                         $xml = $cp2utf->convert($xml);
 912                                         use bytes;      # as opposed to chars
 913                                         print "Path-Name: $swishpath\n";
 914                                         print "Content-Length: ".(length($xml)+1)."\n";
 915                                         print "Document-Type: XML\n\n$xml\n";
 916                                 }
 917                                 $line = 1;
 918                                 $data = {};
 919                                 next;
 920                         }
 921
 922                         $line = $1 if (s/^(\d+):\s*//);
 923                         $data->{$line++} = $_;
 924
 925                         fakeprogress($i);
 926
 927                 }
 928                 # close lookup
 929                 untie %lhash if (%lhash);
 930         }
 931 }
 932
 933 # call this to commit index
 934 $index->close;
 935
 936 1;
 937 __END__
 938 ##########################################################################
 939
 940 =head1 NAME
 941
 942 all2xml.pl - read various file formats and dump XML for SWISH-E
 943
 944 =head1 SYNOPSYS
 945
 946  $ all2xml.pl [test.conf]
 947
 948 =head1 DESCRIPTION
 949
 950 This command will read ISIS data file using Biblio::Isis perl module, MARC
 951 records using MARC::File module and optionally Micro$oft Excel files to
 952 create one XML file for usage with I<SWISH-E> indexer. Dispite it's name,
 953 this script B<isn't general xml generator> from isis files (isis allready
 954 has something like that). Output of this script is tailor-made for SWISH-E.
 955
 956 If no configuration file is specified, it will use default one called
 957 C<all2xml.conf>.
 958
 959 =head1 BUGS
 960
 961 Documentation is really lacking. However, in true Open Source spirit, source
 962 is best documentation. I even made considerable effort to comment parts
 963 which are not intuitively clear, so...
 964
 965 =head1 AUTHOR
 966
 967 Dobrica Pavlinusic <dpavlin@rot13.org>
 968
 969 =head1 COPYRIGHT
 970
 971 GNU Public License (GPL) v2 or later
 972
 973 =head1 SEE ALSO
 974
 975 SWISH-E web site at http://www.swish-e.org
 976
 977 =cut