persistant_worker.pl

   1 #!/usr/bin/perl
   2
   3 BEGIN {
   4         $SIG{'__WARN__'} = sub { warn $_[0] if $_[0] =~ m/^(#+)/ && length($1) <= $ENV{DEBUG} }
   5 }
   6
   7 package Cog; # persistant Gearman Worker - see the pun?
   8
   9 use Moose;
  10 use JSON::XS qw();
  11 extends 'Gearman::Driver::Worker::Base';
  12
  13 use lib 'lib';
  14 with 'APKPM::Gearman';
  15 with 'APKPM::Gearman::Client';
  16
  17 sub prefix { '' }
  18
  19 package main;
  20
  21 use Gearman::Driver;
  22 use Data::Dump qw(dump);
  23
  24 use Regexp::Common qw(net);
  25 use Redis;
  26
  27 use lib 'lib';
  28 use H1::ZTEDSLAM;
  29 use H1::ZTEMSAN;
  30 use APKPM::Model;
  31
  32 my ($variant,$max_processes) = @ARGV;
  33 $variant ||= 'ZTEDSLAM';
  34 $max_processes ||= 1;
  35 warn "variant: $variant max_processes: $max_processes\n";
  36
  37 my $driver = Gearman::Driver->new(
  38         server   => 'localhost:4730',
  39         interval => 15,
  40         loglevel   => 'DEBUG',
  41         logfile    => "log/$variant.log",
  42 ) || die $!;
  43
  44 my $w1 = 'Cog';
  45 my $worker = $w1->new();
  46
  47
  48 my $crm = $worker->do( 'CRM_search' => "TIP_UREDJAJA:$variant" );
  49
  50
  51 my $poll;
  52
  53 foreach my $user ( @$crm ) {
  54         next unless $user->{IP_UREDAJA} =~ /$RE{net}{IPv4}/;
  55         $poll->{ $user->{IP_UREDAJA} }->{ $user->{SHELF_SLOT_PORT} }++;
  56 }
  57
  58 warn "# poll = ", dump($poll);
  59
  60 foreach my $ip ( keys %$poll ) {
  61
  62         my $method = $variant . '_' . $ip;
  63
  64         my $module = 'H1::' . $variant;
  65         my $zte = $module->new( ip => $ip );
  66
  67         my $ports = keys %{ $poll->{$ip} };
  68         my $max_procs = ( int($ports/50) ) + 1; # one process for 50 ports
  69         $max_procs = $max_processes if $max_processes < $max_procs; # hard-limit for maximum ports in parallel
  70
  71         $driver->add_job({
  72                 max_processes => $max_procs,
  73                 min_processes => 0,
  74                 name            => $method,
  75                 worker          => $worker,
  76                 methods    => [
  77                         {
  78                                 decode => 'd_json',
  79 #                               encode => 'e_json',
  80                                 name   => $method,
  81                                 body   => sub {
  82
  83 # XXX -- worker body
  84
  85                 my ( $self, $job, $crm ) = @_;
  86
  87                 my $redis = Redis->new;
  88
  89                 if ( exists $crm->{logout} ) {
  90                         $zte->logout;
  91                         $redis->sadd("$variant.$ip.logout", $self->datetime_now);
  92                         return "logout ok"; # XXX return scalar!
  93                 }
  94
  95                 my $port     = $crm->{SHELF_SLOT_PORT} || die "no SHELF_SLOT_PORT";
  96                 my $username = $crm->{USERNAME}        || die "no USERNAME";
  97
  98                 my $hash;
  99                 eval { $hash = $zte->hash( $port ) };
 100
 101                 if ( $@ ) {
 102                         $redis->sadd("$variant.$ip.error" => $@);
 103                         return "error: $@";
 104                 } elsif ( ! $hash ) {
 105                         $redis->sadd("$variant.$ip.empty" => $port);
 106                         return "empty";
 107                 } else {
 108                         $redis->sadd("$variant.$ip.ok" => $port);
 109                 }
 110
 111                 $self->do_background_json( 'Store_insert', {
 112                         _table => 'dslam_h',
 113                         ip => $crm->{IP_MANAGEMENT}, # FIXME IP_UREDAJA ?
 114                         username => $username,
 115                         timestamp => $self->datetime_now,
 116                         h => $self->to_hstore($hash),
 117                 });
 118
 119                 return "ok $username $ip $port"; # body end
 120
 121 # XXX -- worker body
 122                                 },
 123                         },
 124                 ]
 125         });
 126
 127         warn "$method for $ip with $ports ports using $max_procs processes\n";
 128
 129 }
 130
 131 $driver->add_job({
 132         max_processes => 1,
 133         min_processes => 0,
 134         worker          => $worker,
 135         name            => "poll_$variant",
 136         methods    => [ {
 137                 name            => "poll_$variant",
 138                 encode => 'e_json',
 139                 body   => sub {
 140
 141                 my ( $self, $job, $workload ) = @_;
 142
 143                 my $crm = $self->do( 'CRM_search' => "TIP_UREDJAJA:$variant" );
 144
 145                 warn "# crm $crm";
 146
 147                 my $gc = Gearman::Client->new;
 148                 $gc->job_servers( $self->server || 'localhost:4730' );
 149                 my $taskset = $gc->new_task_set;
 150                 my $seen;
 151
 152                 my $redis = Redis->new;
 153                 $redis->del( $_ ) foreach $redis->keys("$variant.*");
 154
 155                 $redis->set( "$variant.poll.start" => $self->datetime_now );
 156
 157                 foreach my $user ( @$crm ) {
 158                         # required CRM fields for worker
 159                         my $ip   = $user->{IP_UREDAJA}      || next;
 160                         my $port = $user->{SHELF_SLOT_PORT} || next;
 161                         my $username = $user->{USERNAME}    || next;
 162
 163                         if ( $ip !~ /$RE{net}{IPv4}/ ) {
 164                                 $redis->sadd("$variant.invalid.IP_UREDAJA" => $ip);
 165                                 next;
 166                         } elsif ( $port !~ m{\d+(/\d+)+} ) {
 167                                 $redis->sadd("$variant.$ip.invalid.SHELF_SLOT_PORT" => $port);
 168                                 next;
 169                         } elsif ( ! $username ) {
 170                                 $redis->sadd("$variant.$ip.invalid.USERNAME" => $port);
 171                                 next;
 172                         } elsif ( $seen->{ $ip }->{ $port }++ ) {
 173                                 $redis->sadd("$variant.$ip.invalid.duplicate" => $port);
 174                                 next;
 175                         }
 176
 177                         $redis->incr("$variant.poll.queued");
 178                         $redis->sadd("$variant.$ip.queued" => $port);
 179
 180                         my $name = $variant . '_' . $ip;
 181                         $taskset->add_task( $name, $self->e_json( $user ), {
 182                                 on_complete => sub { $redis->sadd("$variant.$ip.complete" => $port) },
 183                                 on_fail     => sub { $redis->sadd("$variant.$ip.failed" => $port) },
 184                         } )
 185                 }
 186
 187                 warn "# queue logouts";
 188                 foreach my $ip ( keys %$seen ) {
 189                         $taskset->add_task( $variant . '_' . $ip, $self->e_json( { logout => 1 } ) );
 190                 }
 191
 192                 warn "# wait";
 193                 $taskset->wait;
 194
 195                 $redis->set( "$variant.poll.finish" => $self->datetime_now );
 196
 197                 my $status = APKPM::Model->redis_status;
 198                 my $row = $status->{poll}->{$variant};
 199                 $row->{$_} = $status->{"$variant.poll.$_"} foreach ( 'start', 'finish' );
 200                 $row->{variant} = $variant;
 201                 $self->do_background_json('Store_insert', { _table => 'zte_poll', %$row });
 202                 warn "# zte_poll ",dump($row);
 203
 204                 my $ips = scalar keys %$seen;
 205                 my $ports = 0;
 206                 $ports += scalar keys %{ $seen->{$_} } foreach keys %$seen;
 207                 warn "# finish $ips ips with $ports ports\n";
 208                 return { ips => $ips, ports => $ports, zte_poll => $row }  ; # body end
 209                 }
 210         } ],
 211 });
 212
 213 open(my $pid, '>', "/tmp/apkpm.$variant.pid");
 214 print $pid "$$\n";
 215 close $pid;
 216
 217 $driver->run;
 218