lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 sub index {
  16         my $self = shift;
  17
  18         my $path = $self->app->home->rel_dir('data');
  19         die "no data dir $path" unless -d $path;
  20
  21         my @files;
  22         find( sub {
  23                 my $file = $File::Find::name;
  24                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  25                         $file =~ s/$path\/*//;
  26                         push @files, $file;
  27                 } else {
  28                         warn "IGNORE: $file\n";
  29                 }
  30         }, $path);
  31
  32         $self->render( files => [ @files ] );
  33 }
  34
  35 our $data;
  36 our $stats;
  37
  38 sub load {
  39         my $self = shift;
  40
  41         my $path = $self->app->home->rel_file( 'data/' . $self->param('path') );
  42         die "$path $!" unless -r $path;
  43
  44         $self->session('path' => $self->param('path'));
  45
  46         # we could use Mojo::JSON here, but it's too slow
  47 #       $data = from_json read_file $path;
  48         $data = read_file $path;
  49         Encode::_utf8_on($data);
  50         warn "# data snippet: ", substr($data,0,200);
  51         if ( $path =~ m/\.js/ ) {
  52                 $data = from_json $data;
  53         } elsif ( $path =~ m/\.txt/ ) {
  54                 my @lines = split(/\n/, $data);
  55                 $data = { items => [] };
  56
  57                 my @header = split(/\|/, shift @lines);
  58                 warn "# header ", dump( @header );
  59                 $self->session( 'header' => [ @header ] );
  60                 $self->session( 'columns' => [ @header ] );
  61                 foreach my $line ( @lines ) {
  62                         my @v = split(/\|/, $line);
  63                         my $item;
  64                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  65                         push @{ $data->{items} }, $item;
  66                 }
  67         } else {
  68                 warn "file format unknown $path";
  69         }
  70
  71         $stats = {};
  72
  73         foreach my $e ( @{ $data->{items} } ) {
  74                 foreach my $n ( keys %$e ) {
  75                         $stats->{$n}->{count}++;
  76                         if ( ref $e->{$n} eq 'ARRAY' ) {
  77
  78                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
  79
  80                                 foreach my $x ( @{$e->{$n}} ) {
  81                                         $stats->{$n}->{numeric}++
  82                                                 if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  83                                 }
  84
  85                         } else {
  86                                 $stats->{$n}->{numeric}++
  87                                         if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  88                         }
  89                 }
  90         }
  91
  92         foreach my $n ( keys %$stats ) {
  93                 next unless defined $stats->{$n}->{array};
  94                 delete $stats->{$n}->{array}
  95                         if $stats->{$n}->{array} == $stats->{$n}->{count};
  96         }
  97
  98         $self->session( 'header' => [
  99                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 100                 grep { defined $stats->{$_}->{count} } keys %$stats
 101         ] ) unless $self->session( 'header' );
 102
 103         warn dump($stats);
 104
 105         $self->redirect_to( '/data/columns' );
 106 }
 107
 108
 109 sub columns {
 110     my $self = shift;
 111
 112         $self->redirect_to( '/data/index' ) unless $self->session('header');
 113
 114         my @columns;
 115         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 116
 117         foreach my $c ( @{ $self->session( 'header' ) } ) {
 118                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 119         }
 120
 121     $self->render(
 122                 message => 'Select columns to display',
 123                 stats => $stats,
 124                 columns => \@columns,
 125                 checked => $self->_checked( $self->_perm_array('columns') ),
 126         );
 127 }
 128
 129 sub _perm_array {
 130     my ($self,$name) = @_;
 131
 132         my @array = $self->param($name);
 133
 134         if ( @array ) {
 135                 $self->session($name => [ @array ]);
 136         } elsif ( my $session = $self->session($name) ) {
 137                 if ( ref $session eq 'ARRAY' ) {
 138                         @array = @$session;
 139                 } else {
 140                         die "$name not array ",dump($session);
 141                 }
 142         }
 143         warn "# $name ",dump @array;
 144         return @array;
 145 }
 146
 147 sub _perm_scalar {
 148     my ($self,$name,$default) = @_;
 149
 150         my $scalar = $self->param($name);
 151
 152         if ( defined $scalar ) {
 153                 $self->session($name => $scalar);
 154         } else {
 155                 $scalar = $self->session($name);
 156         }
 157
 158         if ( ! defined $scalar ) {
 159                 $scalar = $default;
 160                 die "no default for $name" unless defined $scalar;
 161                 $self->session($name => $scalar);
 162         }
 163
 164         warn "# $name ",dump $scalar;
 165         return $scalar;
 166 }
 167
 168 sub filter {
 169         my $self = shift;
 170
 171         my $name = $self->param('filter_name') || die "name?";
 172         my @vals = $self->param('filter_vals');
 173
 174         warn "# filter $name vals ",dump(@vals);
 175
 176         my $filters = $self->session('filters');
 177         if ( @vals ) {
 178                 $filters->{$name} = [ @vals ];
 179         } else {
 180                 delete $filters->{$name};
 181         }
 182         $self->session( 'filters' => $filters );
 183
 184         warn "# filters ",dump($self->session('filters'));
 185
 186         $self->session( 'offset' => 0 );
 187
 188         $self->redirect_to('/data/items');
 189 }
 190
 191 sub _filter_item {
 192         my ( $self, $filters, $i ) = @_;
 193         my $pass = 1;
 194         foreach my $n ( keys %$filters ) {
 195                 my @filter_values = @{ $filters->{$n} };
 196                 my $include_missing = grep { /^_missing/ } @filter_values;
 197                 if ( ! exists $i->{$n} ) {
 198                         if ( $include_missing ) {
 199                                 $pass = 1;
 200                                 next;
 201                         } else {
 202                                 $pass = 0;
 203                                 last;
 204                         }
 205                 }
 206                 # and match any of values in element
 207                 my $have_values = 0;
 208                 foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 209                         $have_values ||= 1 if grep { m/^\Q$v\E$/ } @filter_values;
 210                 }
 211                 if ( ! $have_values ) {
 212                         $pass = 0;
 213                         last;
 214                 }
 215         }
 216         return $pass;
 217 }
 218
 219 sub _data_items {
 220         my $self = shift;
 221         my $filters = $self->session('filters');
 222         grep {
 223                 $filters ? $self->_filter_item( $filters, $_ ) : 1;
 224         } @{ $data->{items} };
 225 }
 226
 227 sub items {
 228     my $self = shift;
 229
 230         $self->redirect_to('/data/index') unless $data->{items};
 231
 232         my @columns = $self->_perm_array('columns');
 233         $self->redirect_to('/data/columns') unless @columns;
 234         my $order   = $self->_perm_scalar('order', $columns[0]);
 235         my $sort    = $self->_perm_scalar('sort', 'a');
 236         my $offset  = $self->_perm_scalar('offset', 0);
 237         my $limit   = $self->_perm_scalar('limit', 20);
 238         $self->_perm_scalar('show', 'table');
 239
 240         # fix offset when changing limit
 241         $offset = int( $offset / $limit ) * $limit;
 242
 243         # FIXME - multi-level sort
 244         my $numeric = $self->_is_numeric($order);
 245         my $missing = $numeric ? 0 : '';
 246         no warnings qw(numeric);
 247         my @sorted = sort {
 248                 my $v1 = exists $a->{$order} ? join('', @{$a->{$order}}) : $missing;
 249                 my $v2 = exists $b->{$order} ? join('', @{$b->{$order}}) : $missing;
 250                 ($v1,$v2) = ($v2,$v1) if $sort eq 'd';
 251                 $numeric ? $v1 <=> $v2 : $v1 cmp $v2 ;
 252         } $self->_data_items;
 253
 254 #       warn "# sorted ", dump @sorted;
 255
 256         my $rows = $#sorted + 1;
 257
 258         $self->render(
 259                 order => $order,
 260                 offset => $offset,
 261                 limit => $limit,
 262                 sorted => [ splice @sorted, $offset, $limit ],
 263                 columns => [ @columns ],
 264                 rows => $rows,
 265                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 266         );
 267
 268 }
 269
 270
 271 sub order {
 272         my $self = shift;
 273         $self->session('order', $self->param('order'));
 274         $self->session('sort', $self->param('sort'));
 275         $self->redirect_to('/data/items');
 276 }
 277
 278 sub _is_numeric {
 279         my ( $self, $name ) = @_;
 280
 281         # sort facet numerically if more >50% elements are numeric
 282         defined $stats->{$name}->{numeric} &&
 283                 $stats->{$name}->{numeric} > $stats->{$name}->{count} / 2;
 284 }
 285
 286 sub facet {
 287         my $self = shift;
 288
 289         if ( my $remove = $self->param('remove') ) {
 290                 my $f = $self->session('filters');
 291                 delete $f->{$remove};
 292                 $self->session( 'filters' => $f );
 293                 $self->redirect_to( '/data/items' );
 294         }
 295
 296         my $facet;
 297         my $name = $self->param('name') || die "no name";
 298
 299         foreach my $i ( $self->_data_items ) {
 300                 if ( ! exists $i->{$name} ) {
 301                         $facet->{ _missing }++;
 302                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 303                         $facet->{$_}++ foreach @{ $i->{$name} };
 304                 } else {
 305                         $facet->{ $i->{$name} }++;
 306                 }
 307         }
 308
 309 #       warn "# facet $name ",dump $facet;
 310
 311         my $checked;
 312         if ( my $f = $self->session('filters') ) {
 313                 if ( defined $f->{$name} ) {
 314                         $checked = $self->_checked( @{ $f->{$name} } );
 315                 }
 316         }
 317
 318         my $sort = $self->param('sort') || 'c';
 319
 320         # sort facet numerically if more >50% elements are numeric
 321         my $numeric = $self->_is_numeric($name);
 322
 323         my @facet_names = sort {
 324                 if ( $sort =~ m/a/i ) {
 325                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 326                 } elsif ( $sort =~ m/d/i ) {
 327                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 328                 } elsif ( $sort =~ m/c/i ) {
 329                         $facet->{$b} <=> $facet->{$a};
 330                 } else {
 331                         warn "unknown sort: $sort";
 332                         $a cmp $b;
 333                 }
 334         } keys %$facet;
 335
 336         $self->render( name => $name, facet => $facet, checked => $checked,
 337                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 338         );
 339 }
 340
 341 sub _checked {
 342         my $self = shift;
 343         my $checked;
 344         $checked->{$_}++ foreach @_;
 345         warn "# _checked ",dump($checked);
 346         return $checked;
 347 }
 348
 349 1;