lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 sub index {
  16         my $self = shift;
  17
  18         my $path = $self->app->home->rel_dir('data');
  19         die "no data dir $path" unless -d $path;
  20
  21         my @files;
  22         find( sub {
  23                 my $file = $File::Find::name;
  24                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  25                         $file =~ s/$path\/*//;
  26                         push @files, $file;
  27                 } else {
  28                         warn "IGNORE: $file\n";
  29                 }
  30         }, $path);
  31
  32         $self->render( files => [ @files ] );
  33 }
  34
  35 our $data;
  36 our $stats;
  37
  38 sub load {
  39         my $self = shift;
  40
  41         my $path = $self->app->home->rel_file( 'data/' . $self->param('path') );
  42         die "$path $!" unless -r $path;
  43
  44         $self->session('path' => $self->param('path'));
  45
  46         # we could use Mojo::JSON here, but it's too slow
  47 #       $data = from_json read_file $path;
  48         $data = read_file $path;
  49         Encode::_utf8_on($data);
  50         warn "# data snippet: ", substr($data,0,200);
  51         if ( $path =~ m/\.js/ ) {
  52                 $data = from_json $data;
  53         } elsif ( $path =~ m/\.txt/ ) {
  54                 my @lines = split(/\r?\n/, $data);
  55                 $data = { items => [] };
  56
  57                 my $headers = shift @lines;
  58                 my $multiline = $headers =~ s/\^//g;
  59                 my @header = split(/\|/, $headers );
  60                 warn "# header ", dump( @header );
  61                 $self->session( 'header' => [ @header ] );
  62                 $self->session( 'columns' => [ @header ] );
  63                 while ( my $line = shift @lines ) {
  64                         chomp $line;
  65                         $line =~ s/\^//g;
  66                         my @v = split(/\|/, $line);
  67                         while ( $multiline && $#v < $#header ) {
  68                                 $line = shift @lines;
  69                                 chomp $line;
  70                                 $line =~ s/\^//g;
  71                                 push @v, split(/\|/, $line);
  72                         }
  73                         my $item;
  74                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  75                         push @{ $data->{items} }, $item;
  76                 }
  77         } else {
  78                 warn "file format unknown $path";
  79         }
  80
  81         $stats = {};
  82
  83         foreach my $e ( @{ $data->{items} } ) {
  84                 foreach my $n ( keys %$e ) {
  85                         $stats->{$n}->{count}++;
  86                         if ( ref $e->{$n} eq 'ARRAY' ) {
  87
  88                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
  89
  90                                 foreach my $x ( @{$e->{$n}} ) {
  91                                         $stats->{$n}->{numeric}++
  92                                                 if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  93                                 }
  94
  95                         } else {
  96                                 $stats->{$n}->{numeric}++
  97                                         if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  98                         }
  99                 }
 100         }
 101
 102         foreach my $n ( keys %$stats ) {
 103                 next unless defined $stats->{$n}->{array};
 104                 delete $stats->{$n}->{array}
 105                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 106         }
 107
 108         $self->session( 'header' => [
 109                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 110                 grep { defined $stats->{$_}->{count} } keys %$stats
 111         ] ) unless $self->session( 'header' );
 112
 113         warn dump($stats);
 114
 115         $self->redirect_to( '/data/columns' );
 116 }
 117
 118
 119 sub columns {
 120     my $self = shift;
 121
 122         $self->redirect_to( '/data/index' ) unless $self->session('header');
 123
 124         my @columns;
 125         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 126
 127         foreach my $c ( @{ $self->session( 'header' ) } ) {
 128                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 129         }
 130
 131     $self->render(
 132                 message => 'Select columns to display',
 133                 stats => $stats,
 134                 columns => \@columns,
 135                 checked => $self->_checked( $self->_perm_array('columns') ),
 136         );
 137 }
 138
 139 sub _perm_array {
 140     my ($self,$name) = @_;
 141
 142         my @array = $self->param($name);
 143
 144         if ( @array ) {
 145                 $self->session($name => [ @array ]);
 146         } elsif ( my $session = $self->session($name) ) {
 147                 if ( ref $session eq 'ARRAY' ) {
 148                         @array = @$session;
 149                 } else {
 150                         die "$name not array ",dump($session);
 151                 }
 152         }
 153         warn "# $name ",dump @array;
 154         return @array;
 155 }
 156
 157 sub _perm_scalar {
 158     my ($self,$name,$default) = @_;
 159
 160         my $scalar = $self->param($name);
 161
 162         if ( defined $scalar ) {
 163                 $self->session($name => $scalar);
 164         } else {
 165                 $scalar = $self->session($name);
 166         }
 167
 168         if ( ! defined $scalar ) {
 169                 $scalar = $default;
 170                 die "no default for $name" unless defined $scalar;
 171                 $self->session($name => $scalar);
 172         }
 173
 174         warn "# $name ",dump $scalar;
 175         return $scalar;
 176 }
 177
 178 sub filter {
 179         my $self = shift;
 180
 181         my $name = $self->param('filter_name') || die "name?";
 182         my @vals = $self->param('filter_vals');
 183
 184         warn "# filter $name vals ",dump(@vals);
 185
 186         my $filters = $self->session('filters');
 187         if ( @vals ) {
 188                 $filters->{$name} = [ @vals ];
 189         } else {
 190                 delete $filters->{$name};
 191         }
 192         $self->session( 'filters' => $filters );
 193
 194         warn "# filters ",dump($self->session('filters'));
 195
 196         $self->session( 'offset' => 0 );
 197
 198         $self->redirect_to('/data/items');
 199 }
 200
 201 sub _filter_item {
 202         my ( $self, $filters, $i ) = @_;
 203         my $pass = 1;
 204         foreach my $n ( keys %$filters ) {
 205                 my @filter_values = @{ $filters->{$n} };
 206                 my $include_missing = grep { /^_missing/ } @filter_values;
 207                 if ( ! exists $i->{$n} ) {
 208                         if ( $include_missing ) {
 209                                 $pass = 1;
 210                                 next;
 211                         } else {
 212                                 $pass = 0;
 213                                 last;
 214                         }
 215                 }
 216                 # and match any of values in element
 217                 my $have_values = 0;
 218                 foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 219                         $have_values ||= 1 if grep { m/^\Q$v\E$/ } @filter_values;
 220                 }
 221                 if ( ! $have_values ) {
 222                         $pass = 0;
 223                         last;
 224                 }
 225         }
 226         return $pass;
 227 }
 228
 229 sub _data_items {
 230         my $self = shift;
 231         my $filters = $self->session('filters');
 232         grep {
 233                 $filters ? $self->_filter_item( $filters, $_ ) : 1;
 234         } @{ $data->{items} };
 235 }
 236
 237 sub items {
 238     my $self = shift;
 239
 240         $self->redirect_to('/data/index') unless $data->{items};
 241
 242         my @columns = $self->_perm_array('columns');
 243         $self->redirect_to('/data/columns') unless @columns;
 244         my $order   = $self->_perm_scalar('order', $columns[0]);
 245         my $sort    = $self->_perm_scalar('sort', 'a');
 246         my $offset  = $self->_perm_scalar('offset', 0);
 247         my $limit   = $self->_perm_scalar('limit', 20);
 248         $self->_perm_scalar('show', 'table');
 249
 250         # fix offset when changing limit
 251         $offset = int( $offset / $limit ) * $limit;
 252
 253         # FIXME - multi-level sort
 254         my $numeric = $self->_is_numeric($order);
 255         my $missing = $numeric ? 0 : '';
 256         no warnings qw(numeric);
 257         my @sorted = sort {
 258                 my $v1 = exists $a->{$order} ? join('', @{$a->{$order}}) : $missing;
 259                 my $v2 = exists $b->{$order} ? join('', @{$b->{$order}}) : $missing;
 260                 ($v1,$v2) = ($v2,$v1) if $sort eq 'd';
 261                 $numeric ? $v1 <=> $v2 : $v1 cmp $v2 ;
 262         } $self->_data_items;
 263
 264 #       warn "# sorted ", dump @sorted;
 265
 266         my $rows = $#sorted + 1;
 267
 268         $self->render(
 269                 order => $order,
 270                 offset => $offset,
 271                 limit => $limit,
 272                 sorted => [ splice @sorted, $offset, $limit ],
 273                 columns => [ @columns ],
 274                 rows => $rows,
 275                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 276         );
 277
 278 }
 279
 280
 281 sub order {
 282         my $self = shift;
 283         $self->session('order', $self->param('order'));
 284         $self->session('sort', $self->param('sort'));
 285         $self->redirect_to('/data/items');
 286 }
 287
 288 sub _is_numeric {
 289         my ( $self, $name ) = @_;
 290
 291         # sort facet numerically if more >50% elements are numeric
 292         defined $stats->{$name}->{numeric} &&
 293                 $stats->{$name}->{numeric} > $stats->{$name}->{count} / 2;
 294 }
 295
 296 sub facet {
 297         my $self = shift;
 298
 299         if ( my $remove = $self->param('remove') ) {
 300                 my $f = $self->session('filters');
 301                 delete $f->{$remove};
 302                 $self->session( 'filters' => $f );
 303                 $self->redirect_to( '/data/items' );
 304         }
 305
 306         my $facet;
 307         my $name = $self->param('name') || die "no name";
 308
 309         foreach my $i ( $self->_data_items ) {
 310                 if ( ! exists $i->{$name} ) {
 311                         $facet->{ _missing }++;
 312                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 313                         $facet->{$_}++ foreach @{ $i->{$name} };
 314                 } else {
 315                         $facet->{ $i->{$name} }++;
 316                 }
 317         }
 318
 319 #       warn "# facet $name ",dump $facet;
 320
 321         my $checked;
 322         if ( my $f = $self->session('filters') ) {
 323                 if ( defined $f->{$name} ) {
 324                         $checked = $self->_checked( @{ $f->{$name} } );
 325                 }
 326         }
 327
 328         my $sort = $self->param('sort') || 'c';
 329
 330         # sort facet numerically if more >50% elements are numeric
 331         my $numeric = $self->_is_numeric($name);
 332
 333         my @facet_names = sort {
 334                 if ( $sort =~ m/a/i ) {
 335                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 336                 } elsif ( $sort =~ m/d/i ) {
 337                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 338                 } elsif ( $sort =~ m/c/i ) {
 339                         $facet->{$b} <=> $facet->{$a};
 340                 } else {
 341                         warn "unknown sort: $sort";
 342                         $a cmp $b;
 343                 }
 344         } keys %$facet;
 345
 346         $self->render( name => $name, facet => $facet, checked => $checked,
 347                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 348         );
 349 }
 350
 351 sub _checked {
 352         my $self = shift;
 353         my $checked;
 354         $checked->{$_}++ foreach @_;
 355         warn "# _checked ",dump($checked);
 356         return $checked;
 357 }
 358
 359 1;