lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14 use Storable;
  15
  16 our $loaded;
  17 our $filters;
  18
  19 sub index {
  20         my $self = shift;
  21
  22         my $path = $self->app->home->rel_dir('data');
  23         die "no data dir $path" unless -d $path;
  24
  25         my @files;
  26         find( sub {
  27                 my $file = $File::Find::name;
  28                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  29                         $file =~ s/$path\/*//;
  30                         push @files, $file;
  31                 } else {
  32                         warn "IGNORE: $file\n";
  33                 }
  34         }, $path);
  35
  36         @files = sort { lc $a cmp lc $b } @files;
  37         my $size;
  38         $size->{$_} = -s "$path/$_" foreach @files;
  39
  40         my $dump_path;
  41         $dump_path->{$_} = $self->_dump_path( $_ ) foreach @files;
  42
  43         if ( my $save_path = $self->session('save_path') ) {
  44                 $self->session( 'save_path' => 0 )
  45                 if ! defined $loaded->{$save_path};
  46         }
  47
  48         $self->render(
  49                 files => [ @files ],
  50                 size => $size,
  51                 loaded => $loaded,
  52                 filters => $filters,
  53                 dump_path => $dump_path,
  54         );
  55 }
  56
  57 sub _dump_path {
  58         my ( $self, $name ) = @_;
  59         my $dir = $self->app->home->rel_dir('data');
  60         $name =~ s/^$dir//;
  61         $name =~ s/\/+/_/g;
  62         return '/tmp/mojo_facets.' . $name . '.storable';
  63 }
  64
  65 sub _save {
  66         my ( $self, $path ) = @_;
  67
  68         my $dump_path = $self->_dump_path( $path );
  69         warn "save loaded to $dump_path";
  70         my $info = $loaded->{$path};
  71         store $info, $dump_path;
  72
  73         # sync timestamp
  74         #my $mtime = $loaded->{$path}->{mtime};
  75         #utime $mtime, $mtime, $dump_path;
  76
  77         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  78         return $dump_path;
  79 }
  80
  81 sub _load_path {
  82         my ( $self, $path ) = @_;
  83
  84         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  85         die "$full_path $!" unless -r $full_path;
  86
  87         my $dump_path = $self->_dump_path( $path );
  88
  89         if ( defined $loaded->{$path}->{data} ) {
  90                 my $mtime = (stat($full_path))[9];
  91                 return if $loaded->{$path}->{mtime} == $mtime;
  92                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
  93         } elsif ( -e $dump_path ) {
  94                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
  95                 my $info = retrieve $dump_path;
  96                 $loaded->{ $path } = $info;
  97                 return;
  98         }
  99
 100         # we could use Mojo::JSON here, but it's too slow
 101 #       $data = from_json read_file $path;
 102         my $data = read_file $full_path;
 103         warn "# data snippet: ", substr($data,0,200);
 104         my @header;
 105         if ( $path =~ m/\.js/ ) {
 106                 Encode::_utf8_on($data);
 107                 $data = from_json $data;
 108         } elsif ( $path =~ m/\.txt/ ) {
 109                 my @lines = split(/\r?\n/, $data);
 110                 $data = { items => [] };
 111
 112                 my $header_line = shift @lines;
 113                 my $multiline = $header_line =~ s/\^//g;
 114                 @header = split(/\|/, $header_line );
 115                 warn "# header ", dump( @header );
 116                 while ( my $line = shift @lines ) {
 117                         $line =~ s/\^//g;
 118                         chomp $line;
 119                         my @v = split(/\|/, $line);
 120                         while ( @lines && $#v < $#header ) {
 121                                 $line = $lines[0];
 122                                 $line =~ s/\^//g;
 123                                 chomp $line;
 124                                 my @more_v = split(/\|/, $line);
 125                                 if ( $#v + $#more_v > $#header ) {
 126                                         warn "short line: ",dump( @v );
 127                                         last;
 128                                 }
 129                                 shift @lines;
 130                                 $v[ $#v ] .= shift @more_v if @more_v;
 131                                 push @v, @more_v if @more_v;
 132
 133                                 if ( $#v > $#header ) {
 134                                         die "# splice $#header ", dump( @v );
 135                                         @v = splice @v, 0, $#header;
 136                                 }
 137                         }
 138                         my $item;
 139                         foreach my $i ( 0 .. $#v ) {
 140                                 $item->{ $header[$i] || "f_$i" } = [ $v[$i] ];
 141                         }
 142                         push @{ $data->{items} }, $item;
 143                 }
 144         } else {
 145                 warn "file format unknown $path";
 146         }
 147
 148         my $stats;
 149
 150         foreach my $e ( @{ $data->{items} } ) {
 151                 foreach my $n ( keys %$e ) {
 152                         $stats->{$n}->{count}++;
 153                         my @v;
 154                         if ( ref $e->{$n} eq 'ARRAY' ) {
 155                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 156                                 @v = @{ $e->{$n} };
 157                         } else {
 158                                 @v = ( $e->{$n} );
 159                         }
 160
 161                         foreach my $x ( @v ) {
 162                                 $stats->{$n}->{numeric}++
 163                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 164                                 $stats->{$n}->{empty}++
 165                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 166                         }
 167
 168                 }
 169         }
 170
 171         foreach my $n ( keys %$stats ) {
 172                 next unless defined $stats->{$n}->{array};
 173                 delete $stats->{$n}->{array}
 174                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 175         }
 176
 177         if ( ! @header ) {
 178                 if ( defined $data->{header} ) {
 179                         if ( ref $data->{header} eq 'ARRAY' ) {
 180                                 @header = @{ $data->{header} };
 181                         } else {
 182                                 warn "header not array ", dump( $data->{header} );
 183                         }
 184                 }
 185         }
 186
 187         @header =
 188                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 189                 grep { defined $stats->{$_}->{count} } keys %$stats
 190                 unless @header;
 191
 192         warn dump($stats);
 193
 194         my $info = {
 195                 header => [ @header ],
 196                 stats  => $stats,
 197                 full_path => $full_path,
 198                 size => -s $full_path,
 199                 mtime => (stat($full_path))[9],
 200                 data => $data,
 201         };
 202
 203         $loaded->{ $path } = $info;
 204         $self->_save( $path );
 205
 206 }
 207
 208
 209 sub load {
 210         my $self = shift;
 211
 212         my @paths = $self->param('paths');
 213         warn "# paths ", dump @paths;
 214         $self->_load_path( $_ ) foreach @paths;
 215
 216         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 217         warn "# path $path\n";
 218         $self->session('path' => $path);
 219         $self->_load_path( $path );
 220
 221         $self->session( 'header' => $loaded->{$path}->{header} );
 222         if ( ! defined $loaded->{$path}->{columns} ) {
 223                 $self->session( 'columns' => $loaded->{$path}->{header} );
 224                 $self->session( 'order'   => $loaded->{$path}->{header}->[0] );
 225                 $self->redirect_to( '/data/columns' );
 226         } else {
 227                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 228                 $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 229                 $self->redirect_to( '/data/items' );
 230         }
 231 }
 232
 233
 234 sub _loaded {
 235         my ( $self, $name ) = @_;
 236         my $path = $self->session('path');
 237         $self->redirect_to('/data/index') unless $path;
 238         if ( ! defined $loaded->{$path}->{$name} ) {
 239                 warn "$path $name isn't loaded\n";
 240                 $self->_load_path( $path );
 241                 $self->redirect_to('/data/index')
 242                         unless defined $loaded->{$path}->{$name};
 243         }
 244         return $loaded->{$path}->{$name};
 245 }
 246
 247
 248 sub _checked {
 249         my $self = shift;
 250         my $checked;
 251         $checked->{$_}++ foreach @_;
 252 #       warn "# _checked ",dump($checked);
 253         return $checked;
 254 }
 255
 256
 257 sub columns {
 258     my $self = shift;
 259
 260         if ( $self->param('columns') ) {
 261                 $self->_perm_array('columns');
 262                 $self->redirect_to('/data/items');
 263         }
 264
 265         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 266
 267         my @columns;
 268         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 269
 270         foreach my $c ( @{ $self->session( 'header' ) } ) {
 271                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 272         }
 273
 274     $self->render(
 275                 message => 'Select columns to display',
 276                 stats => $stats,
 277                 columns => \@columns,
 278                 checked => $self->_checked( $self->_perm_array('columns') ),
 279         );
 280 }
 281
 282 sub _perm_array {
 283     my ($self,$name) = @_;
 284
 285         my @array = $self->param($name);
 286         my $path  = $self->session('path');
 287
 288         if ( @array ) {
 289                 $self->session($name => [ @array ]);
 290                 $loaded->{$path}->{$name} = [ @array ];
 291         } elsif ( my $session = $self->session($name) ) {
 292                 if ( ref $session eq 'ARRAY' ) {
 293                         @array = @$session;
 294                 } else {
 295                         die "$name not array ",dump($session);
 296                 }
 297         }
 298         #warn "# $name ",dump @array;
 299         return @array;
 300 }
 301
 302 sub _perm_scalar {
 303     my ($self,$name,$default) = @_;
 304
 305         my $scalar = $self->param($name);
 306
 307         if ( defined $scalar ) {
 308                 $self->session($name => $scalar);
 309         } else {
 310                 $scalar = $self->session($name);
 311         }
 312
 313         if ( ! defined $scalar ) {
 314                 $scalar = $default;
 315                 die "no default for $name" unless defined $scalar;
 316                 $self->session($name => $scalar);
 317         }
 318
 319         warn "# _perm_scalar $name ",dump $scalar;
 320         return $scalar;
 321 }
 322
 323 sub filter {
 324         my $self = shift;
 325
 326         my $name = $self->param('filter_name') || die "name?";
 327         my @vals = $self->param('filter_vals');
 328
 329         $self->_remove_filter( $name );
 330         $self->_filter_on_data( $name, @vals ) if @vals;
 331
 332         $self->session( 'offset' => 0 );
 333
 334         $self->redirect_to('/data/items');
 335 }
 336
 337 sub _filter_on_data {
 338         my ( $self, $name, @vals ) = @_;
 339
 340         my $path = $self->session('path');
 341
 342         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 343                 warn "filter $name not found in data set";
 344                 return;
 345         }
 346
 347         $filters->{$name} = [ @vals ];
 348         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 349
 350         my $filter_hash;
 351         $filter_hash->{$_}++ foreach @vals;
 352
 353         #warn "# filter_hash ",dump( $filter_hash );
 354
 355         my $items = $self->_loaded('data')->{items};
 356
 357         my $include_missing = defined $filter_hash->{_missing};
 358         my $filtered_items;
 359
 360         foreach my $i ( 0 .. $#$items ) {
 361
 362                 if ( defined $items->[$i]->{$name} ) {
 363                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 364                                 if ( defined $filter_hash->{ $v } ) {
 365                                         $filtered_items->{$i}++;
 366                                 }
 367                         }
 368                 } elsif ( $include_missing ) {
 369                         $filtered_items->{$i}++;
 370                 }
 371         }
 372
 373         #warn "# filter $name ",dump($filtered_items);
 374
 375         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 376         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 377 }
 378
 379 sub _data_items {
 380         my ( $self, $all ) = @_;
 381         my $data = $self->_loaded( 'data' );
 382
 383         return @{ $data->{items} } if $all == 1;
 384
 385         my $filters = $self->_current_filters;
 386         my $filter_value;
 387         foreach my $f ( keys %$filters ) {
 388                 foreach my $n ( @{ $filters->{$f} } ) {
 389                         $filter_value->{$f}->{$n} = 1;
 390                 }
 391         }
 392         my @items = @{ $data->{items} };
 393         @items = grep {
 394                 my $i = $_;
 395                 my $pass = 1;
 396                 foreach my $n ( keys %$filter_value ) {
 397                         if ( ! exists $i->{$n} ) {
 398                                 if ( defined $filter_value->{$n}->{_missing} ) {
 399                                         $pass = 1;
 400                                         next;
 401                                 } else {
 402                                         $pass = 0;
 403                                         last;
 404                                 }
 405                         }
 406                         # and match any of values in element
 407                         my $have_values = 0;
 408                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 409                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 410                         }
 411                         if ( ! $have_values ) {
 412                                 $pass = 0;
 413                                 last;
 414                         }
 415                 }
 416                 $pass;
 417         } @items if $filter_value;
 418         return @items;
 419 }
 420
 421
 422 sub _current_filters {
 423         my $self = shift;
 424         my $current_filters;
 425         $current_filters->{ $_ } = $filters->{ $_ }
 426                 foreach (
 427                         grep { defined $filters->{ $_ } }
 428                         @{ $self->_loaded('header') }
 429                 );
 430         #warn "# current_filters ",dump($current_filters);
 431         return $current_filters;
 432 }
 433
 434 sub _data_sorted_by {
 435         my ( $self, $order ) = @_;
 436
 437         my $path = $self->session('path');
 438
 439         warn "_data_sorted_by $order from $path";
 440
 441         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 442                 return $loaded->{$path}->{sorted}->{$order};
 443         }
 444
 445         my $data = $self->_loaded( 'data' );
 446         my $numeric = $self->_is_numeric($order);
 447         my $missing = $numeric ? 0 : '';
 448         no warnings qw(numeric);
 449         my $nr = 0;
 450         my @sorted = map {
 451                 $_->[0]
 452         } sort {
 453                 if ( $numeric ) {
 454                         $a->[1] <=> $b->[1]
 455                 } else {
 456                         $a->[1] cmp $b->[1]
 457                 }
 458         } map {
 459                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 460         } @{ $data->{items} }
 461         ;
 462
 463         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 464         #warn "# sorted ",dump( @sorted );
 465
 466         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 467 }
 468
 469
 470 sub items {
 471         my $self = shift;
 472
 473         my $path = $self->session('path');
 474         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 475
 476         my @columns = $self->_perm_array('columns');
 477         $self->redirect_to('/data/columns') unless @columns;
 478         my $order   = $self->_perm_scalar('order', $columns[0]);
 479         my $sort    = $self->_perm_scalar('sort', 'a');
 480         my $offset  = $self->_perm_scalar('offset', 0);
 481         my $limit   = $self->_perm_scalar('limit', 20);
 482         $self->_perm_scalar('show', 'table');
 483
 484         # fix offset when changing limit
 485         $offset = int( $offset / $limit ) * $limit;
 486
 487         my $sorted = $self->_data_sorted_by( $order );
 488
 489         my @filter_names;
 490         if ( $filters ) {
 491                 foreach my $name ( keys %$filters ) {
 492                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 493                                 warn "skip filter $name not found in $path\n";
 494                                 next;
 495                         }
 496                         push @filter_names, $name;
 497                 }
 498                 warn "filter_names ",dump( @filter_names );
 499                 foreach my $name ( @filter_names ) {
 500                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 501                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 502                 }
 503         }
 504
 505         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 506
 507 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 508
 509         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 510
 511                 my $path_filters = $loaded->{$path}->{filters};
 512
 513                 warn "create combined filter for $all_filters\n";
 514
 515                 my @filtered;
 516                 foreach my $i ( 0 .. $#$sorted ) {
 517                         my $pos = $sorted->[$i];
 518
 519                         if ( $#filter_names == -1 ) {
 520                                 push @filtered, $pos;
 521                                 next;
 522                         }
 523
 524                         my $skip = 0;
 525                         foreach ( @filter_names ) {
 526                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 527                         }
 528                         next if $skip;
 529
 530                         push @filtered, $pos;
 531                 }
 532
 533                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 534         }
 535
 536         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 537                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 538
 539         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 540
 541         my $sorted_items;
 542         my $data = $self->_loaded('data');
 543         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 544         foreach ( 0 .. $limit ) {
 545                 my $i = $_ + $offset;
 546                 last unless defined $filtered->[$i];
 547                 $i = $from_end - $i if $from_end;
 548                 my $id = $filtered->[$i];
 549                 push @$sorted_items,
 550                 my $item = $data->{items}->[ $id ];
 551                 $item->{_row_id} ||= $id;
 552         }
 553
 554         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 555
 556         $self->render(
 557                 order => $order,
 558                 offset => $offset,
 559                 limit => $limit,
 560                 sorted => $sorted_items,
 561                 columns => [ @columns ],
 562                 rows => $#$filtered + 1,
 563                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 564                 filters => $self->_current_filters,
 565         );
 566
 567 }
 568
 569
 570 sub order {
 571         my $self = shift;
 572         $self->session('order', $self->param('order'));
 573         $self->session('sort', $self->param('sort'));
 574         $self->redirect_to('/data/items');
 575 }
 576
 577 sub _is_numeric {
 578         my ( $self, $name ) = @_;
 579
 580         my $stats = $self->_loaded( 'stats' );
 581
 582         # sort facet numerically if more >50% elements are numeric
 583         my $count = $stats->{$name}->{count};
 584         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 585         defined $stats->{$name}->{numeric} &&
 586                 $stats->{$name}->{numeric} > $count / 2;
 587 }
 588
 589 sub _remove_filter {
 590         my ($self,$name) = @_;
 591         warn "_remove_filter $name\n";
 592
 593         my $path = $self->session('path');
 594
 595         delete $filters->{$name};
 596         delete $loaded->{$path}->{filters}->{$name};
 597         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 598
 599         foreach (
 600                         grep { /\b$name\b/ }
 601                         keys %{ $loaded->{$path}->{filtered} }
 602         ) {
 603                 delete $loaded->{$path}->{filtered}->{$_};
 604                 warn "remove filtered cache $_";
 605         }
 606 }
 607
 608 sub facet {
 609         my $self = shift;
 610
 611         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 612
 613         if ( my $name = $self->param('remove') ) {
 614                 $self->_remove_filter( $name );
 615                 $self->redirect_to( '/data/items' );
 616         }
 617
 618         my $facet;
 619         my $name = $self->param('name') || die "no name";
 620
 621         my $all = $self->_perm_scalar('all', 1);
 622         my $data = $self->_loaded('data');
 623
 624         my $filters = $self->_current_filters;
 625         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 626         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 627                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 628
 629         if ( ! $filtered || $all ) {
 630                 $filtered = [ 0 .. $#{ $data->{items} } ];
 631                 warn "filter all values\n";
 632         } else {
 633                 warn "filter using $all_filters\n";
 634         }
 635
 636         foreach my $i ( @$filtered ) {
 637                 my $item = $data->{items}->[$i];
 638                 if ( ! exists $item->{$name} ) {
 639                         $facet->{ _missing }++;
 640                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 641                         $facet->{$_}++ foreach @{ $item->{$name} };
 642                 } else {
 643                         $facet->{ $item->{$name} }++;
 644                 }
 645         }
 646
 647 #       warn "# facet $name ",dump $facet;
 648
 649         my $checked;
 650         my @facet_names =
 651                   $all                      ? keys %$facet
 652                 : defined $filters->{$name} ? @{ $filters->{$name} }
 653                 : keys %$facet;
 654
 655         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 656
 657         my $numeric = $self->_is_numeric($name);
 658
 659         my $sort = $self->param('sort');
 660         # sort numeric facets with more than 5 values ascending
 661         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 662
 663         @facet_names = sort {
 664                 my $result;
 665                 if ( $sort eq 'a' ) {
 666                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 667                 } elsif ( $sort eq 'd' ) {
 668                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 669                 } elsif ( $sort eq 'c' ) {
 670                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 671                 } else {
 672                         warn "unknown sort: $sort";
 673                         $result = $a cmp $b;
 674                 }
 675                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 676                 $result;
 677         } @facet_names;
 678
 679         $self->render( name => $name, facet => $facet, checked => $checked,
 680                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 681         );
 682 }
 683
 684 sub edit {
 685         my $self = shift;
 686         my $content = $self->param('content');
 687
 688         my $i = $self->param('_row_id');
 689         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 690         my $path = $self->param('path') || die "no path";
 691         my $name = $self->param('name') || die "no name";
 692         my $status = 200; # 200 = OK, 201 = Created
 693
 694         my $data = $self->_loaded('data');
 695
 696         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 697                 $content =~ s/^\s+//s;
 698                 $content =~ s/\s+$//s;
 699                 my $v;
 700                 if ( $content =~ /\xB6/ ) {     # para
 701                         $v = [ split(/\s*\xB6\s*/, $content) ];
 702                 } else {
 703                         $v = [ $content ];
 704                 }
 705
 706                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 707                 my $new = dump $v;
 708                 if ( $old ne $new
 709                         && ! ( $old eq 'undef' && length($content) == 0 ) # new value empty, previous undef
 710                 ) {
 711                         warn "# update $path $i $old -> $new\n";
 712                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 713
 714                         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 715                             delete $loaded->{$path}->{sorted}->{$name};
 716                                 warn "# invalidate $path sorted $name\n";
 717                         }
 718
 719                         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 720                             delete $loaded->{$path}->{filtered}->{$_};
 721                                 warn "# invalidate $path filtered $_\n";
 722                         }
 723
 724                         $status = 201; # created
 725                         $self->session('save_path' => $path);
 726
 727                 } else {
 728                         warn "# unchanged $path $i $old\n";
 729                         $status = 304;
 730                 }
 731         } else {
 732                 $content = "$path $i $name doesn't exist\n";
 733                 $status = 404;
 734         }
 735
 736         warn "# edit $status $content";
 737
 738         $self->render(
 739                 status => $status,
 740                 content => $content,
 741         );
 742 }
 743
 744
 745 sub save {
 746         my $self = shift;
 747         my $path = $self->param('path');
 748         $path  ||= $self->session('path');
 749
 750         my $dump_path = $self->_save( $path );
 751         $self->session('save_path' => 0);
 752
 753         $self->redirect_to( '/data/items' );
 754 }
 755
 756 1;