bak-git-server.pl

   1 #!/usr/bin/perl
   2
   3 =head1 bak-git
   4
   5 Simple tracking of remote files in central git repository
   6 with only shell, netcat, rsync and ssh on client
   7
   8 Start server, install on remote-host or upgrade with:
   9
  10   ./bak-git-server.pl /path/to/backup 192.168.42.42
  11         [--install remote-host]
  12         [--upgrade]
  13
  14 C<rsync> traffic is always transfered over ssh, but C<diff> or C<ch> can
  15 still leak sensitive information if C<bak> shell client connects directly
  16 to server host.
  17
  18 Add following line to C<~/.ssh/config> under C<Host> for which you want encrypted
  19 controll channel (or to pass through server ssh hops using C<ProxyCommand>)
  20
  21   RemoteForward 9001 192.168.42.42:9001
  22
  23 bak command overview:
  24
  25   bak add /path
  26   bak commit [/path [message]]
  27   bak diff [host:][/path]
  28   bak status [/path]
  29   bak log [/path]
  30
  31   bak show
  32   bak ch[anges]
  33   bak revert [host:]/path
  34
  35   bak cat [host:]/path
  36   bak grep pattern
  37
  38   bak - push all changed files to server
  39
  40 See L<http://blog.rot13.org/bak-git> for more information
  41
  42 =cut
  43
  44 use warnings;
  45 use strict;
  46 use autodie;
  47 use IO::Socket::INET;
  48 use File::Path;
  49 use Getopt::Long;
  50
  51 my $upgrade = 0;
  52 my $install;
  53
  54 GetOptions(
  55         'upgrade!'  => \$upgrade,
  56         'install=s' => \$install,
  57 ) || die "$!\n";
  58
  59 my ( $dir, $server_ip ) = @ARGV;
  60 die "usage: $0 /backup/directory 127.0.0.1\n" unless $dir;
  61 $server_ip ||= '127.0.0.1';
  62
  63 # parse ssh config
  64 my $ssh_tunnel;
  65 open(my $ssh_fd, '<', "$ENV{HOME}/.ssh/config");
  66 my $host;
  67 while(<$ssh_fd>) {
  68         chomp;
  69         next unless length($_) > 0;
  70         next if m/^\s*#/;
  71
  72         if ( /^Host\s+(.+)/i ) {
  73                 $host = $1;
  74         } elsif ( /^\s+(\S+)\s+(.+)/ ) {
  75                 $ssh_tunnel->{$host}++ if lc($1) eq 'remoteforward' && $2 =~ m/9001/;
  76         } else {
  77                 die "can't parse $_";
  78         }
  79 }
  80
  81 sub shell_client {
  82         my ( $hostname ) = @_;
  83         my $path = '/tmp/bak';
  84         my $server = $server_ip;
  85         $server = '127.0.0.1' if $ssh_tunnel->{$hostname};
  86 warn "# ssh_client $hostname $server";
  87         open(my $fh, '>', $path);
  88         print $fh "#!/bin/sh\n";
  89         print $fh "echo \$USER/\$SUDO_USER $hostname `pwd` \$* | nc $server 9001\n";
  90         close($fh);
  91         chmod 0755, $path;
  92         return $path;
  93 }
  94
  95 sub _kill_ssh {
  96         while ( my($host,$pid) = each %$ssh_tunnel ) {
  97                 warn "$host kill TERM $pid";
  98                 kill 15, $pid; # TERM
  99         }
 100 }
 101
 102 #$SIG{INT};
 103 $SIG{TERM} = &_kill_ssh;
 104
 105 chdir $dir;
 106 system 'git init' unless -e '.git';
 107
 108 if ( $upgrade || $install ) {
 109
 110         my @hosts = grep { -d $_ } glob '*';
 111         @hosts = ( $install ) if $install;
 112
 113         foreach my $hostname ( @hosts ) {
 114                 warn "install on $hostname\n";
 115                 system 'ssh-copy-id', "root\@$hostname" if ! -d $hostname;
 116                 my $path = shell_client( $hostname );
 117                 system "scp $path root\@$hostname:/usr/local/bin/";
 118                 system "ssh root\@$hostname apt-get install -y rsync";
 119         }
 120 } else {
 121         my $ssh = $ENV{SSH} || 'ssh';
 122         warn "# start $ssh tunnels...";
 123         foreach my $host ( keys %$ssh_tunnel ) {
 124                 warn "## $host\n";
 125                 my $pid = fork;
 126                 if ( ! defined $pid ) {
 127                         die "fork: $!";
 128                 } elsif ( $pid ) {
 129 #                       waitpid $pid, 0;
 130                         warn "FIXME: waitpid $pid";
 131                 } else {
 132                         warn "EXEC $ssh $host";
 133                         exec "$ssh -N root\@$host";
 134                 }
 135
 136                 $ssh_tunnel->{$host} = $pid;
 137         }
 138 }
 139
 140 warn "dir: $dir listen: $server_ip:9001\n";
 141
 142 my $server = IO::Socket::INET->new(
 143         Proto     => 'tcp',
 144 #       LocalAddr => $server_ip,
 145         LocalPort => 9001,
 146         Listen    => SOMAXCONN,
 147         Reuse     => 1
 148 ) || die $!;
 149
 150
 151 sub rsync {
 152         warn "# rsync ",join(' ', @_), "\n";
 153         system 'rsync', @_;
 154 }
 155
 156 sub pull_changes {
 157         my $hostname = shift;
 158         system "find $hostname -type f | sed 's,$hostname,,' > /tmp/$hostname.list";
 159         if ( @_ ) {
 160                 open(my $files, '>>', "/tmp/$hostname.list");
 161                 print $files "$_\n" foreach @_;
 162                 close($files);
 163         }
 164         rsync split / /, "-avv --files-from /tmp/$hostname.list root\@$hostname:/ $hostname/";
 165 }
 166
 167 while (my $client = $server->accept()) {
 168         my $line = <$client>;
 169         chomp($line);
 170         warn "<<< $line\n";
 171         my ($user,$hostname,$pwd,$command,$rel_path,$message) = split(/\s+/,$line,6);
 172         $hostname =~ s/\..+$//;
 173
 174         my $on_host = '';
 175         if ( $rel_path =~ s/^([^:]+):(.+)$/$2/ ) {
 176                 if ( -e $1 ) {
 177                         $on_host = $1;
 178                 } else {
 179                         print $client "host $1 doesn't exist in backup\n";
 180                         next;
 181                 }
 182         }
 183         my $path = $rel_path =~ m{^/} ? $rel_path : "$pwd/$rel_path";
 184
 185         warn "$hostname [$command] $on_host:$path | $message\n";
 186
 187         my $args_message = $message;
 188
 189         $message ||= "$path [$command]";
 190         $message = "$hostname: $message";
 191
 192         my $dir = $path;
 193         $dir =~ s{/[^/]+$}{};
 194
 195         my $backup_path = -e "$hostname/$path" ? "$hostname/$path" : $hostname;
 196
 197         sub git {
 198                 my $args = join(' ',@_);
 199                 warn "# git $args\n";
 200                 my $out = `git $args`;
 201                 warn "$out\n# [", length($out), " bytes]\n" if defined $out;
 202                 return $out;
 203         }
 204
 205         if ( ! $command ) {
 206                 pull_changes $hostname;
 207         } elsif ( $command eq 'add' ) {
 208                 mkpath "$hostname/$dir" unless -e "$hostname/$dir";
 209                 while ( $path ) {
 210                         rsync( '-avv', "root\@$hostname:$path", "$hostname/$path" );
 211                         print $client git 'add', "$hostname/$path";
 212
 213                         $args_message =~ s/^(.+)\b// || last;
 214                         $path = $1;
 215                         warn "? $path";
 216                 }
 217         } elsif ( $command eq 'commit' ) {
 218                 pull_changes $hostname;
 219                 $message =~ s/'/\\'/g;
 220                 $user =~ s/\/$//;
 221                 print $client git( "commit -m '$message' --author '$user <$hostname>' $backup_path" );
 222         } elsif ( $command =~ m{(diff|status|log|ch)} ) {
 223                 $command .= ' --stat' if $command eq 'log';
 224                 $command = 'log --patch-with-stat' if $command =~ m/^ch/;
 225                 pull_changes( $hostname ) if $command eq 'diff';
 226                 if ( $on_host ) {
 227                         mkpath $_ foreach grep { ! -e $_ } ( "$hostname/$dir", "$on_host/$dir" );
 228                         rsync( '-avv', "root\@$hostname:$path", "$hostname/$path" );
 229                         rsync( '-avv', "root\@$on_host:$path", "$on_host/$path" );
 230                         open(my $diff, '-|', "diff -Nuw $hostname$path $on_host$path");
 231                         while(<$diff>) {
 232                                 print $client $_;
 233                         }
 234                 } else {
 235                         # commands without path will show host-wide status/changes
 236                         my $backup_path = $path ? "$hostname/$path" : "$hostname/";
 237                         # hostname must end with / to prevent error from git:
 238                         # ambiguous argument 'arh-hw': both revision and filename
 239                         # to support branches named as hosts
 240                         print $client git($command, $backup_path);
 241                 }
 242         } elsif ( $command eq 'revert' ) {
 243                 if ( $on_host ) {
 244                         rsync( '-avv', "$on_host/$path", "root\@$hostname:$path" );
 245                 } else {
 246                         print $client git "checkout -- $hostname/$path";
 247                         rsync( '-avv', "$hostname/$path", "root\@$hostname:$path" );
 248                 }
 249         } elsif ( $command eq 'cat' ) {
 250                 my $file_path = ( $on_host ? $on_host : $hostname ) . "/$path";
 251                 open(my $file, '<', $file_path) || warn "ERROR $file_path: $!";
 252                 while(<$file>) {
 253                         print $client $_;
 254                 }
 255                 close($file);
 256         } elsif ( $command eq 'ls' ) {
 257                 print $client `ls $backup_path`;
 258         } elsif ( $command eq 'show' ) {
 259                 print $client `git show $rel_path`;
 260         } elsif ( $command eq 'grep' ) {
 261                 print $client `git log -g --grep=$rel_path`;
 262         } else {
 263                 print $client "Unknown command: $command\n";
 264         }
 265
 266 }
 267