kernel/linux/arch/arm/mm/proc-v6.S

   1 /*
   2  *  linux/arch/arm/mm/proc-v6.S
   3  *
   4  *  Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  This is the "shell" of the ARMv6 processor support.
  11  */
  12 #include <linux/linkage.h>
  13 #include <asm/assembler.h>
  14 #include <asm/constants.h>
  15 #include <asm/procinfo.h>
  16 #include <asm/pgtable.h>
  17
  18 #include "proc-macros.S"
  19
  20 #define D_CACHE_LINE_SIZE       32
  21
  22         .macro  cpsie, flags
  23         .ifc \flags, f
  24         .long   0xf1080040
  25         .exitm
  26         .endif
  27         .ifc \flags, i
  28         .long   0xf1080080
  29         .exitm
  30         .endif
  31         .ifc \flags, if
  32         .long   0xf10800c0
  33         .exitm
  34         .endif
  35         .err
  36         .endm
  37
  38         .macro  cpsid, flags
  39         .ifc \flags, f
  40         .long   0xf10c0040
  41         .exitm
  42         .endif
  43         .ifc \flags, i
  44         .long   0xf10c0080
  45         .exitm
  46         .endif
  47         .ifc \flags, if
  48         .long   0xf10c00c0
  49         .exitm
  50         .endif
  51         .err
  52         .endm
  53
  54 ENTRY(cpu_v6_proc_init)
  55         mov     pc, lr
  56
  57 ENTRY(cpu_v6_proc_fin)
  58         mov     pc, lr
  59
  60 /*
  61  *      cpu_v6_reset(loc)
  62  *
  63  *      Perform a soft reset of the system.  Put the CPU into the
  64  *      same state as it would be if it had been reset, and branch
  65  *      to what would be the reset vector.
  66  *
  67  *      - loc   - location to jump to for soft reset
  68  *
  69  *      It is assumed that:
  70  */
  71         .align  5
  72 ENTRY(cpu_v6_reset)
  73         mov     pc, r0
  74
  75 /*
  76  *      cpu_v6_do_idle()
  77  *
  78  *      Idle the processor (eg, wait for interrupt).
  79  *
  80  *      IRQs are already disabled.
  81  */
  82 ENTRY(cpu_v6_do_idle)
  83         mcr     p15, 0, r1, c7, c0, 4           @ wait for interrupt
  84         mov     pc, lr
  85
  86 ENTRY(cpu_v6_dcache_clean_area)
  87 #ifndef TLB_CAN_READ_FROM_L1_CACHE
  88 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
  89         add     r0, r0, #D_CACHE_LINE_SIZE
  90         subs    r1, r1, #D_CACHE_LINE_SIZE
  91         bhi     1b
  92 #endif
  93         mov     pc, lr
  94
  95 /*
  96  *      cpu_arm926_switch_mm(pgd_phys, tsk)
  97  *
  98  *      Set the translation table base pointer to be pgd_phys
  99  *
 100  *      - pgd_phys - physical address of new TTB
 101  *
 102  *      It is assumed that:
 103  *      - we are not using split page tables
 104  */
 105 ENTRY(cpu_v6_switch_mm)
 106         mov     r2, #0
 107         ldr     r1, [r1, #MM_CONTEXT_ID]        @ get mm->context.id
 108         mcr     p15, 0, r2, c7, c10, 4          @ drain write buffer
 109         mcr     p15, 0, r0, c2, c0, 0           @ set TTB 0
 110         mcr     p15, 0, r1, c13, c0, 1          @ set context ID
 111         mov     pc, lr
 112
 113 #define nG      (1 << 11)
 114 #define APX     (1 << 9)
 115 #define AP1     (1 << 5)
 116 #define AP0     (1 << 4)
 117 #define XN      (1 << 0)
 118
 119 /*
 120  *      cpu_v6_set_pte(ptep, pte)
 121  *
 122  *      Set a level 2 translation table entry.
 123  *
 124  *      - ptep  - pointer to level 2 translation table entry
 125  *                (hardware version is stored at -1024 bytes)
 126  *      - pte   - PTE value to store
 127  *
 128  *      Permissions:
 129  *        YUWD  APX AP1 AP0     SVC     User
 130  *        0xxx   0   0   0      no acc  no acc
 131  *        100x   1   0   1      r/o     no acc
 132  *        10x0   1   0   1      r/o     no acc
 133  *        1011   0   0   1      r/w     no acc
 134  *        110x   1   1   0      r/o     r/o
 135  *        11x0   1   1   0      r/o     r/o
 136  *        1111   0   1   1      r/w     r/w
 137  */
 138 ENTRY(cpu_v6_set_pte)
 139         str     r1, [r0], #-2048                @ linux version
 140
 141         bic     r2, r1, #0x00000ff0
 142         bic     r2, r2, #0x00000003
 143         orr     r2, r2, #AP0 | 2
 144
 145         tst     r1, #L_PTE_WRITE
 146         tstne   r1, #L_PTE_DIRTY
 147         orreq   r2, r2, #APX
 148
 149         tst     r1, #L_PTE_USER
 150         orrne   r2, r2, #AP1 | nG
 151         tstne   r2, #APX
 152         eorne   r2, r2, #AP0
 153
 154         tst     r1, #L_PTE_YOUNG
 155         biceq   r2, r2, #APX | AP1 | AP0
 156
 157 @       tst     r1, #L_PTE_EXEC
 158 @       orreq   r2, r2, #XN
 159
 160         tst     r1, #L_PTE_PRESENT
 161         moveq   r2, #0
 162
 163         str     r2, [r0]
 164         mcr     p15, 0, r0, c7, c10, 1 @ flush_pte
 165         mov     pc, lr
 166
 167
 168
 169
 170 cpu_v6_name:
 171         .asciz  "Some Random V6 Processor"
 172         .align
 173
 174         .section ".text.init", #alloc, #execinstr
 175
 176 /*
 177  *      __v6_setup
 178  *
 179  *      Initialise TLB, Caches, and MMU state ready to switch the MMU
 180  *      on.  Return in r0 the new CP15 C1 control register setting.
 181  *
 182  *      We automatically detect if we have a Harvard cache, and use the
 183  *      Harvard cache control instructions insead of the unified cache
 184  *      control instructions.
 185  *
 186  *      This should be able to cover all ARMv6 cores.
 187  *
 188  *      It is assumed that:
 189  *      - cache type register is implemented
 190  */
 191 __v6_setup:
 192         mrc     p15, 0, r10, c0, c0, 1          @ read cache type register
 193         tst     r10, #1 << 24                   @ Harvard cache?
 194         mov     r10, #0
 195         mcrne   p15, 0, r10, c7, c14, 0         @ clean+invalidate D cache
 196         mcrne   p15, 0, r10, c7, c5, 0          @ invalidate I cache
 197         mcreq   p15, 0, r10, c7, c15, 0         @ clean+invalidate cache
 198         mcr     p15, 0, r10, c7, c10, 4         @ drain write buffer
 199         mcr     p15, 0, r10, c8, c7, 0          @ invalidate I + D TLBs
 200         mcr     p15, 0, r10, c2, c0, 2          @ TTB control register
 201         mcr     p15, 0, r4, c2, c0, 0           @ load TTB0
 202         mcr     p15, 0, r4, c2, c0, 1           @ load TTB1
 203         mov     r10, #0x1f                      @ domains 0, 1 = manager
 204         mcr     p15, 0, r10, c3, c0, 0          @ load domain access register
 205         mrc     p15, 0, r0, c1, c0, 0           @ read control register
 206         ldr     r10, cr1_clear                  @ get mask for bits to clear
 207         bic     r0, r0, r10                     @ clear bits them
 208         ldr     r10, cr1_set                    @ get mask for bits to set
 209         orr     r0, r0, r10                     @ set them
 210         mov     pc, lr                          @ return to head.S:__ret
 211
 212         /*
 213          *         V X F   I D LR
 214          * .... ...E PUI. .T.T 4RVI ZFRS BLDP WCAM
 215          * rrrr rrrx xxx0 0101 xxxx xxxx x111 xxxx < forced
 216          *         0 110       0011 1.00 .111 1101 < we want
 217          */
 218         .type   cr1_clear, #object
 219         .type   cr1_set, #object
 220 cr1_clear:
 221         .word   0x0120c302
 222 cr1_set:
 223         .word   0x00c0387d
 224
 225         .type   v6_processor_functions, #object
 226 ENTRY(v6_processor_functions)
 227         .word   v6_early_abort
 228         .word   cpu_v6_proc_init
 229         .word   cpu_v6_proc_fin
 230         .word   cpu_v6_reset
 231         .word   cpu_v6_do_idle
 232         .word   cpu_v6_dcache_clean_area
 233         .word   cpu_v6_switch_mm
 234         .word   cpu_v6_set_pte
 235         .size   v6_processor_functions, . - v6_processor_functions
 236
 237         .type   cpu_arch_name, #object
 238 cpu_arch_name:
 239         .asciz  "armv6"
 240         .size   cpu_arch_name, . - cpu_arch_name
 241
 242         .type   cpu_elf_name, #object
 243 cpu_elf_name:
 244         .asciz  "v6"
 245         .size   cpu_elf_name, . - cpu_elf_name
 246         .align
 247
 248         .section ".proc.info", #alloc, #execinstr
 249
 250         /*
 251          * Match any ARMv6 processor core.
 252          */
 253         .type   __v6_proc_info, #object
 254 __v6_proc_info:
 255         .long   0x00070000
 256         .long   0x00ff0000
 257         .long   0x00000c0e
 258         b       __v6_setup
 259         .long   cpu_arch_name
 260         .long   cpu_elf_name
 261         .long   HWCAP_SWP | HWCAP_HALF | HWCAP_FAST_MULT | HWCAP_VFP
 262         .long   cpu_v6_name
 263         .long   v6_processor_functions
 264         .long   v6wbi_tlb_fns
 265         .long   v6_user_fns
 266         .long   v6_cache_fns
 267         .size   __v6_proc_info, . - __v6_proc_info