kernel/linux/arch/cris/arch-v10/vmlinux.lds.S

   1 /* ld script to make the Linux/CRIS kernel
   2  * Authors: Bjorn Wesen (bjornw@axis.com)
   3  *
   4  * It is VERY DANGEROUS to fiddle around with the symbols in this
   5  * script. It is for example quite vital that all generated sections
   6  * that are used are actually named here, otherwise the linker will
   7  * put them at the end, where the init stuff is which is FREED after
   8  * the kernel has booted.
   9  */
  10
  11 #include <linux/config.h>
  12 #include <asm-generic/vmlinux.lds.h>
  13
  14 jiffies = jiffies_64;
  15 SECTIONS
  16 {
  17         . = DRAM_VIRTUAL_BASE;
  18         dram_start = .;
  19         ibr_start = .;
  20         . = . + 0x4000; /* see head.S and pages reserved at the start */
  21
  22         _text = .;                    /* Text and read-only data */
  23         text_start = .;              /* lots of aliases */
  24         _stext = .;
  25         __stext = .;
  26         .text : {
  27                 *(.text)
  28                 SCHED_TEXT
  29                 *(.fixup)
  30                 *(.text.__*)
  31         }
  32
  33         _etext = . ;                  /* End of text section */
  34         __etext = .;
  35
  36         . = ALIGN(4);                /* Exception table */
  37         __start___ex_table = .;
  38         __ex_table : { *(__ex_table) }
  39         __stop___ex_table = .;
  40
  41         RODATA
  42
  43         . = ALIGN (4);
  44         ___data_start = . ;
  45         __Sdata = . ;
  46         .data : {                     /* Data */
  47                 *(.data)
  48         }
  49         __edata = . ;                 /* End of data section */
  50         _edata = . ;
  51
  52         . = ALIGN(8192);              /* init_task and stack, must be aligned */
  53         .data.init_task : { *(.data.init_task) }
  54
  55         . = ALIGN(8192);              /* Init code and data */
  56         __init_begin = .;
  57         .init.text : {
  58                    _sinittext = .;
  59                    *(.init.text)
  60                    _einittext = .;
  61         }
  62         .init.data : { *(.init.data) }
  63         . = ALIGN(16);
  64         __setup_start = .;
  65         .init.setup : { *(.init.setup) }
  66         __setup_end = .;
  67         __start___param = .;
  68         __param : { *(__param) }
  69         __stop___param = .;
  70         .initcall.init : {
  71                 __initcall_start = .;
  72                 *(.initcall1.init);
  73                 *(.initcall2.init);
  74                 *(.initcall3.init);
  75                 *(.initcall4.init);
  76                 *(.initcall5.init);
  77                 *(.initcall6.init);
  78                 *(.initcall7.init);
  79                 __initcall_end = .;
  80         }
  81
  82         .con_initcall.init : {
  83                 __con_initcall_start = .;
  84                 *(.con_initcall.init)
  85                 __con_initcall_end = .;
  86         }
  87         SECURITY_INIT
  88
  89         .init.ramfs : {
  90                 __initramfs_start = .;
  91                 *(.init.ramfs)
  92                 __initramfs_end = .;
  93                 /* We fill to the next page, so we can discard all init
  94                    pages without needing to consider what payload might be
  95                    appended to the kernel image.  */
  96                 FILL (0);
  97                 . = ALIGN (8192);
  98         }
  99
 100         __vmlinux_end = .;            /* last address of the physical file */
 101         __init_end = .;
 102
 103         __data_end = . ;              /* Move to _edata ? */
 104         __bss_start = .;              /* BSS */
 105         .bss : {
 106                 *(COMMON)
 107                 *(.bss)
 108         }
 109
 110         . =  ALIGN (0x20);
 111         _end = .;
 112         __end = .;
 113
 114         /* Sections to be discarded */
 115         /DISCARD/ : {
 116                 *(.text.exit)
 117                 *(.data.exit)
 118                 *(.exitcall.exit)
 119         }
 120
 121         dram_end = dram_start + CONFIG_ETRAX_DRAM_SIZE*1024*1024;
 122 }