kernel/linux/arch/mips/kernel/vmlinux.lds.S

   1 #include <linux/config.h>
   2 #include <asm-generic/vmlinux.lds.h>
   3
   4 #undef mips             /* CPP really sucks for this job  */
   5 #define mips mips
   6 OUTPUT_ARCH(mips)
   7 ENTRY(kernel_entry)
   8 jiffies = JIFFIES;
   9 SECTIONS
  10 {
  11 #ifdef CONFIG_BOOT_ELF64
  12   /* Read-only sections, merged into text segment: */
  13   /* . = 0xc000000000000000; */
  14
  15   /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
  16   /* . = 0xc00000000001c000; */
  17
  18   /* Set the vaddr for the text segment to a value
  19         >= 0xa800 0000 0001 9000 if no symmon is going to configured
  20         >= 0xa800 0000 0030 0000 otherwise  */
  21
  22   /* . = 0xa800000000300000; */
  23   /* . = 0xa800000000300000; */
  24   . = 0xffffffff80300000;
  25 #endif
  26   . = LOADADDR;
  27   /* read-only */
  28   _text = .;                    /* Text and read-only data */
  29   .text : {
  30     *(.text)
  31     SCHED_TEXT
  32     *(.fixup)
  33     *(.gnu.warning)
  34   } =0
  35
  36   _etext = .;                   /* End of text section */
  37
  38   . = ALIGN(16);                /* Exception table */
  39   __start___ex_table = .;
  40   __ex_table : { *(__ex_table) }
  41   __stop___ex_table = .;
  42
  43   __start___dbe_table = .;      /* Exception table for data bus errors */
  44   __dbe_table : { *(__dbe_table) }
  45   __stop___dbe_table = .;
  46
  47   RODATA
  48
  49   /* writeable */
  50   .data : {                     /* Data */
  51     . = . + MAPPED_OFFSET;      /* for CONFIG_MAPPED_KERNEL */
  52     *(.data.init_task)
  53
  54     *(.data)
  55
  56    /* Align the initial ramdisk image (INITRD) on page boundaries. */
  57    . = ALIGN(4096);
  58    __rd_start = .;
  59    *(.initrd)
  60    . = ALIGN(4096);
  61    __rd_end = .;
  62
  63     CONSTRUCTORS
  64   }
  65   _gp = . + 0x8000;
  66   .lit8 : { *(.lit8) }
  67   .lit4 : { *(.lit4) }
  68   /* We want the small data sections together, so single-instruction offsets
  69      can access them all, and initialized data all before uninitialized, so
  70      we can shorten the on-disk segment size.  */
  71   .sdata     : { *(.sdata) }
  72
  73   . = ALIGN(4096);
  74   __nosave_begin = .;
  75   .data_nosave : { *(.data.nosave) }
  76   . = ALIGN(4096);
  77   __nosave_end = .;
  78
  79   . = ALIGN(32);
  80   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  81
  82   _edata =  .;                  /* End of data section */
  83
  84   /* will be freed after init */
  85   . = ALIGN(4096);              /* Init code and data */
  86   __init_begin = .;
  87   /* /DISCARD/ doesn't work for .reginfo */
  88   .reginfo : { *(.reginfo) }
  89   .init.text : {
  90         _sinittext = .;
  91         *(.init.text)
  92         _einittext = .;
  93   }
  94   .init.data : { *(.init.data) }
  95   . = ALIGN(16);
  96   __setup_start = .;
  97   .init.setup : { *(.init.setup) }
  98   __setup_end = .;
  99   __start___param = .;
 100   __param : { *(__param) }
 101   __stop___param = .;
 102
 103   .early_initcall.init : {
 104   __earlyinitcall_start = .;
 105         *(.initcall.early1.init)
 106   }
 107   __earlyinitcall_end = .;
 108
 109   __initcall_start = .;
 110   .initcall.init : {
 111         *(.initcall1.init)
 112         *(.initcall2.init)
 113         *(.initcall3.init)
 114         *(.initcall4.init)
 115         *(.initcall5.init)
 116         *(.initcall6.init)
 117         *(.initcall7.init)
 118   }
 119   __initcall_end = .;
 120
 121   __con_initcall_start = .;
 122   .con_initcall.init : { *(.con_initcall.init) }
 123   __con_initcall_end = .;
 124   SECURITY_INIT
 125   . = ALIGN(4096);
 126   __initramfs_start = .;
 127   .init.ramfs : { *(.init.ramfs) }
 128   __initramfs_end = .;
 129   . = ALIGN(32);
 130   __per_cpu_start = .;
 131   .data.percpu  : { *(.data.percpu) }
 132   __per_cpu_end = .;
 133   . = ALIGN(4096);
 134   __init_end = .;
 135   /* freed after init ends here */
 136
 137   __bss_start = .;              /* BSS */
 138   .sbss      : {
 139     *(.sbss)
 140     *(.scommon)
 141   }
 142   .bss : {
 143     *(.bss)
 144     *(COMMON)
 145   }
 146   __bss_stop = .;
 147
 148   _end = . ;
 149
 150   /* Sections to be discarded */
 151   /DISCARD/ : {
 152         *(.exit.text)
 153         *(.exit.data)
 154         *(.exitcall.exit)
 155   }
 156
 157   /* This is the MIPS specific mdebug section.  */
 158   .mdebug : { *(.mdebug) }
 159   /* These are needed for ELF backends which have not yet been
 160      converted to the new style linker.  */
 161   .stab 0 : { *(.stab) }
 162   .stabstr 0 : { *(.stabstr) }
 163   /* DWARF debug sections.
 164      Symbols in the .debug DWARF section are relative to the beginning of the
 165      section so we begin .debug at 0.  It's not clear yet what needs to happen
 166      for the others.   */
 167   .debug          0 : { *(.debug) }
 168   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 169   .debug_aranges  0 : { *(.debug_aranges) }
 170   .debug_pubnames 0 : { *(.debug_pubnames) }
 171   .debug_sfnames  0 : { *(.debug_sfnames) }
 172   .line           0 : { *(.line) }
 173   /* These must appear regardless of  .  */
 174   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
 175   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
 176   .comment : { *(.comment) }
 177   .note : { *(.note) }
 178 }