kernel/linux/arch/s390/kernel/vmlinux.lds.S

   1 /* ld script to make s390 Linux kernel
   2  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   3  */
   4
   5 #include <asm-generic/vmlinux.lds.h>
   6 #include <linux/config.h>
   7
   8 #ifndef CONFIG_ARCH_S390X
   9 OUTPUT_FORMAT("elf32-s390", "elf32-s390", "elf32-s390")
  10 OUTPUT_ARCH(s390)
  11 ENTRY(_start)
  12 jiffies = jiffies_64 + 4;
  13 #else
  14 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  15 OUTPUT_ARCH(s390:64-bit)
  16 ENTRY(_start)
  17 jiffies = jiffies_64;
  18 #endif
  19
  20 SECTIONS
  21 {
  22   . = 0x00000000;
  23   _text = .;                    /* Text and read-only data */
  24   .text : {
  25         *(.text)
  26         SCHED_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x0700
  30
  31   _etext = .;                   /* End of text section */
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   RODATA
  39
  40 #ifdef CONFIG_SHARED_KERNEL
  41   . = ALIGN(1048576);           /* VM shared segments are 1MB aligned */
  42
  43   _eshared = .;                 /* End of shareable data */
  44 #endif
  45
  46   .data : {                     /* Data */
  47         *(.data)
  48         CONSTRUCTORS
  49         }
  50
  51   . = ALIGN(4096);
  52   __nosave_begin = .;
  53   .data_nosave : { *(.data.nosave) }
  54   . = ALIGN(4096);
  55   __nosave_end = .;
  56
  57   . = ALIGN(4096);
  58   .data.page_aligned : { *(.data.idt) }
  59
  60   . = ALIGN(32);
  61   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  62
  63   _edata = .;                   /* End of data section */
  64
  65   . = ALIGN(8192);              /* init_task */
  66   .data.init_task : { *(.data.init_task) }
  67
  68   /* will be freed after init */
  69   . = ALIGN(4096);              /* Init code and data */
  70   __init_begin = .;
  71   .init.text : {
  72         _sinittext = .;
  73         *(.init.text)
  74         _einittext = .;
  75   }
  76   .init.data : { *(.init.data) }
  77   . = ALIGN(256);
  78   __setup_start = .;
  79   .init.setup : { *(.init.setup) }
  80   __setup_end = .;
  81   __start___param = .;
  82   __param : { *(__param) }
  83   __stop___param = .;
  84   __initcall_start = .;
  85   .initcall.init : {
  86         *(.initcall1.init)
  87         *(.initcall2.init)
  88         *(.initcall3.init)
  89         *(.initcall4.init)
  90         *(.initcall5.init)
  91         *(.initcall6.init)
  92         *(.initcall7.init)
  93   }
  94   __initcall_end = .;
  95   __con_initcall_start = .;
  96   .con_initcall.init : { *(.con_initcall.init) }
  97   __con_initcall_end = .;
  98   SECURITY_INIT
  99   . = ALIGN(256);
 100   __initramfs_start = .;
 101   .init.ramfs : { *(.init.initramfs) }
 102   . = ALIGN(2);
 103   __initramfs_end = .;
 104   . = ALIGN(256);
 105   __per_cpu_start = .;
 106   .data.percpu  : { *(.data.percpu) }
 107   __per_cpu_end = .;
 108   . = ALIGN(4096);
 109   __init_end = .;
 110   /* freed after init ends here */
 111
 112   __bss_start = .;              /* BSS */
 113   .bss : { *(.bss) }
 114   . = ALIGN(2);
 115   __bss_stop = .;
 116
 117   _end = . ;
 118
 119   /* Sections to be discarded */
 120   /DISCARD/ : {
 121         *(.exitcall.exit)
 122         }
 123
 124   /* Stabs debugging sections.  */
 125   .stab 0 : { *(.stab) }
 126   .stabstr 0 : { *(.stabstr) }
 127   .stab.excl 0 : { *(.stab.excl) }
 128   .stab.exclstr 0 : { *(.stab.exclstr) }
 129   .stab.index 0 : { *(.stab.index) }
 130   .stab.indexstr 0 : { *(.stab.indexstr) }
 131   .comment 0 : { *(.comment) }
 132 }