kernel/linux/arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <linux/config.h>
   6 #include <asm-generic/vmlinux.lds.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14 ENTRY(_start)
  15 SECTIONS
  16 {
  17   . = 0x80000000 + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  18   _text = .;                    /* Text and read-only data */
  19   text = .;                     /* Text and read-only data */
  20   .empty_zero_page : {
  21         *(.empty_zero_page)
  22         } = 0
  23   .text : {
  24         *(.text)
  25         SCHED_TEXT
  26         *(.fixup)
  27         *(.gnu.warning)
  28         } = 0x0009
  29
  30   . = ALIGN(16);                /* Exception table */
  31   __start___ex_table = .;
  32   __ex_table : { *(__ex_table) }
  33   __stop___ex_table = .;
  34
  35   RODATA
  36
  37   _etext = .;                   /* End of text section */
  38
  39   .data : {                     /* Data */
  40         *(.data)
  41
  42          /* Align the initial ramdisk image (INITRD) on page boundaries. */
  43          . = ALIGN(4096);
  44          __rd_start = .;
  45          *(.initrd)
  46          . = ALIGN(4096);
  47          __rd_end = .;
  48
  49         CONSTRUCTORS
  50         }
  51
  52   . = ALIGN(4096);
  53   .data.page_aligned : { *(.data.idt) }
  54
  55   . = ALIGN(32);
  56   __per_cpu_start = .;
  57   .data.percpu : { *(.data.percpu) }
  58   __per_cpu_end = .;
  59   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  60
  61   _edata = .;                   /* End of data section */
  62
  63   . = ALIGN(8192);              /* init_task */
  64   .data.init_task : { *(.data.init_task) }
  65   /* stack */
  66   .stack : { stack = .;  _stack = .; }
  67
  68   . = ALIGN(4096);              /* Init code and data */
  69   __init_begin = .;
  70   _sinittext = .;
  71   .init.text : { *(.init.text) }
  72   _einittext = .;
  73   .init.data : { *(.init.data) }
  74   . = ALIGN(16);
  75   __setup_start = .;
  76   .init.setup : { *(.init.setup) }
  77   __setup_end = .;
  78   __start___param = .;
  79   __param : { *(__param) }
  80   __stop___param = .;
  81   __initcall_start = .;
  82   .initcall.init : {
  83         *(.initcall1.init)
  84         *(.initcall2.init)
  85         *(.initcall3.init)
  86         *(.initcall4.init)
  87         *(.initcall5.init)
  88         *(.initcall6.init)
  89         *(.initcall7.init)
  90   }
  91   __initcall_end = .;
  92   __con_initcall_start = .;
  93   .con_initcall.init : { *(.con_initcall.init) }
  94   __con_initcall_end = .;
  95   SECURITY_INIT
  96   __initramfs_start = .;
  97   .init.ramfs : { *(.init.ramfs) }
  98   __initramfs_end = .;
  99   __machvec_start = .;
 100   .init.machvec : { *(.init.machvec) }
 101   __machvec_end = .;
 102   . = ALIGN(4096);
 103   __init_end = .;
 104
 105   . = ALIGN(4);
 106   __bss_start = .;              /* BSS */
 107   .bss : { *(.bss) }
 108
 109   . = ALIGN(4);
 110   _end = . ;
 111
 112   /* When something in the kernel is NOT compiled as a module, the
 113    * module cleanup code and data are put into these segments.  Both
 114    * can then be thrown away, as cleanup code is never called unless
 115    * it's a module.
 116    */
 117   /DISCARD/ : {
 118         *(.exit.text)
 119         *(.exit.data)
 120         *(.exitcall.exit)
 121         }
 122
 123   /* Stabs debugging sections.  */
 124   .stab 0 : { *(.stab) }
 125   .stabstr 0 : { *(.stabstr) }
 126   .stab.excl 0 : { *(.stab.excl) }
 127   .stab.exclstr 0 : { *(.stab.exclstr) }
 128   .stab.index 0 : { *(.stab.index) }
 129   .stab.indexstr 0 : { *(.stab.indexstr) }
 130   .comment 0 : { *(.comment) }
 131   /* DWARF debug sections.
 132      Symbols in the DWARF debugging section are relative to the beginning
 133      of the section so we begin .debug at 0.  */
 134   /* DWARF 1 */
 135   .debug          0 : { *(.debug) }
 136   .line           0 : { *(.line) }
 137   /* GNU DWARF 1 extensions */
 138   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 139   .debug_sfnames  0 : { *(.debug_sfnames) }
 140   /* DWARF 1.1 and DWARF 2 */
 141   .debug_aranges  0 : { *(.debug_aranges) }
 142   .debug_pubnames 0 : { *(.debug_pubnames) }
 143   /* DWARF 2 */
 144   .debug_info     0 : { *(.debug_info) }
 145   .debug_abbrev   0 : { *(.debug_abbrev) }
 146   .debug_line     0 : { *(.debug_line) }
 147   .debug_frame    0 : { *(.debug_frame) }
 148   .debug_str      0 : { *(.debug_str) }
 149   .debug_loc      0 : { *(.debug_loc) }
 150   .debug_macinfo  0 : { *(.debug_macinfo) }
 151   /* SGI/MIPS DWARF 2 extensions */
 152   .debug_weaknames 0 : { *(.debug_weaknames) }
 153   .debug_funcnames 0 : { *(.debug_funcnames) }
 154   .debug_typenames 0 : { *(.debug_typenames) }
 155   .debug_varnames  0 : { *(.debug_varnames) }
 156   /* These must appear regardless of  .  */
 157 }