lib/CloudStore/API.pm

   1 package CloudStore::API;
   2 use warnings;
   3 use strict;
   4 use autodie;
   5
   6 use lib 'lib';
   7 use base qw(CloudStore::Gearman CloudStore::MD5sum);
   8
   9 use File::Path qw(make_path remove_tree);
  10 use File::Find;
  11 use Data::Dump qw(dump);
  12 use Carp qw(confess cluck);
  13
  14 sub new {
  15         my ($class,$slice) = @_;
  16
  17         cluck "DEPRICIATED $slice specified" if $slice;
  18
  19         my $self = {
  20                 passwd => '/var/lib/extrausers/passwd',
  21         };
  22         bless $self, $class;
  23
  24         $self->{md5} = $self->user_info("md5") || die "can't find user md5";
  25 =for removed
  26         $self->{md5}->{dir} = "$dir/md5";
  27         if ( ! -e $self->{md5}->{dir} ) {
  28                 make_path $self->{md5}->{dir}, { uid => $self->{md5}->{uid}, gid => $self->{md5}->{gid} };
  29                 warn "## CREATED md5pool $self->{md5}->{dir}\n";
  30         }
  31 =cut
  32
  33         return $self;
  34 }
  35
  36 sub slice_dir_port {
  37         my ($self,$slice) = @_;
  38         my ( undef, $dir, $port, undef ) = getgrnam($slice);
  39         die "getgrnam $slice: $!" if $!;
  40         warn "# slice_dir_port $slice = $dir $port\n";
  41         return ( $dir, $port );
  42 }
  43
  44 sub dir2gearman {
  45         my $self = shift;
  46         my $dir  = shift;
  47         $dir =~ s/\W+/_/g;
  48         $dir =~ s/^_+//;
  49         $dir =~ s{_\d+$}{};
  50         return join('_', $dir, @_);
  51 }
  52
  53 sub user_info {
  54         my ($self,$login) = @_;
  55
  56         confess "need login" unless $login;
  57
  58         my @n = qw/ login passwd uid gid quota comment gecos dir shell expire /;
  59         my @p = $login =~ m/^\d+$/ ? getpwuid $login : getpwnam $login;
  60         die "user_info $login: $@" if $@;
  61         my $user;
  62         $user->{$_} = shift @p foreach @n;
  63         return $user;
  64 }
  65
  66 sub create_user {
  67         my ( $self, $new_email, $new_passwd, $new_quota ) = @_;
  68
  69         my $max_uid = 0;
  70         my $found = 0;
  71
  72         open(my $fh, '<', $self->{passwd});
  73         while(<$fh>) {
  74                 my ( $login, $passwd, $uid, $gid, $email, $dir, $shell ) = split(/:/,$_);
  75                 $max_uid = $uid if $uid > $max_uid;
  76                 $found = $login if $email eq $new_email;
  77         }
  78         close($fh);
  79
  80         my $slice = $ENV{SLICE} || 's1';
  81         $slice =~ s{/.+/(\w+)$}{$1};
  82         my ( $dir, $port ) = $self->slice_dir_port( $slice );
  83
  84         $dir ||= $ENV{SLICE};
  85         $port ||= 6501;
  86
  87         if ( ! $found ) {
  88                 $max_uid++;
  89                 $dir .= "/$max_uid";
  90                 warn "# create_user $slice $new_email $new_quota = $max_uid $dir";
  91                 open(my $fh, '>>', $self->{passwd});
  92                 print $fh "u$max_uid:$new_passwd:$max_uid:$port:$new_email:$dir:/bin/true\n";
  93                 close($fh);
  94                 $found = "u$max_uid";
  95
  96                 mkdir $dir;
  97                 chown $max_uid, $port, $dir;
  98
  99                 my $path = "$dir/.meta/secrets";
 100                 $self->mkbasepath($path);
 101                 open($fh, '>', $path);
 102                 print $fh "u$max_uid:$new_passwd\n";
 103                 close $fh;
 104         }
 105
 106         # FIXME update quota only on create?
 107         $self->gearman_do( $self->dir2gearman( $dir, 'quota', 'set' ) => "$found $new_quota" );
 108
 109         return $found;
 110 }
 111
 112 sub mkbasepath {
 113         my ($self,$path,$opts) = @_;
 114         $path =~ s{/[^/]+$}{};
 115         make_path $path unless -d $path;
 116 }
 117
 118 sub user_dir {
 119         my ( $self, $user, $dir ) = @_;
 120         $user = $self->user_info($user) unless ref $user eq 'HASH';
 121         my $path;
 122         if ( exists $user->{dir} ) {
 123                 $path = $user->{dir} . '/.meta/' . $dir;
 124         } else {
 125                 die "no dir in ", dump $user;
 126         }
 127         $path =~ s{//+}{/}g;
 128
 129         if ( ! -e $path ) {
 130                 $self->mkbasepath( $path, { uid => $user->{uid} } );
 131                 open(my $fh, '>', $path);
 132                 close $fh;
 133                 chown $user->{uid}, $user->{gid}, $path;
 134                 warn "# user_dir created $path\n";
 135         }
 136
 137         #warn "### user_dir $path";
 138         return $path;
 139 }
 140
 141 sub append {
 142         my $self = shift @_;
 143         $self->append_meta( 'usage', @_ );
 144 }
 145
 146 sub append_meta {
 147         my $self = shift @_;
 148         my $log  = shift @_;
 149         my $user = shift @_;
 150         my $path = $self->user_dir( $user => $log );
 151         my $delimiter = '#';
 152            $delimiter = '  ' if $log =~ m/md5sum$/;
 153         my $line = join($delimiter,@_);
 154         open(my $fh, '>>', $path);
 155         print $fh "$line\n";
 156         close $fh;
 157         warn "## $path $line\n";
 158 }
 159
 160 sub usage {
 161         my ( $self, $user ) = @_;
 162         $user = $self->user_info($user) unless ref $user eq 'HASH';
 163
 164         my $usage_path = $user->{dir} . '/.meta/files.usage';
 165         if ( -e $usage_path ) {
 166                 warn "# usage $usage_path missing";
 167                 $self->list_files($user);
 168         }
 169
 170         open(my $fh, '<', $usage_path);
 171         my $size = <$fh>;
 172         chomp $size;
 173
 174         warn "# usage $user->{login} usage: $size\n";
 175         return $size;
 176
 177 =for slow and broken
 178
 179         my $path = $self->user_dir( $user => 'usage');
 180         my $sum;
 181         open(my $fh, '<', $path);
 182         while(<$fh>) {
 183                 chomp;
 184                 my @v = split(/#/,$_);
 185                 $sum->{ $v[0] } += $v[1];
 186                 $sum->{_usage}  += $v[1];
 187         }
 188         my ( $usage, $quota ) = split(/ /,
 189                 $self->gearman_do( $self->dir2gearman( $user->{dir}, 'quota', 'get' ) => $user->{uid} )
 190         );
 191         $sum->{_usage} += $usage;
 192         $sum->{_quota} = $quota;
 193         warn "## usage ",dump($user, $sum), $/;
 194         return $sum;
 195
 196 =cut
 197
 198 }
 199
 200 sub send_file {
 201         my ( $self, $f_uid,$f_path, $t_uid,$t_path ) = @_;
 202
 203         my $f = $self->user_info($f_uid);
 204         die "FIXME not on current slice" if $f->{dir} !~ m/^$ENV{SLICE}/;
 205         my $t = $self->user_info($t_uid);
 206
 207         my $f_full = "$f->{dir}/$f_path";
 208         my $t_full = "$t->{dir}/$t_path";
 209
 210         $self->mkbasepath( $t_full, { uid => $t->{uid} } );
 211
 212         my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size, $atime,$mtime,$ctime,$blksize,$blocks) = stat $f_full;
 213         if ( $uid == $f->{uid} ) {
 214                 warn "# send_file - move $f_uid $f_path to pool\n";
 215                 chown $self->{md5}->{uid}, $self->{md5}->{gid}, $f_full;
 216                 chmod oct("0444"), $f_full;
 217                 $self->append( $f, 'sent', -s $f_full, $t->{uid}, $f_path );
 218         } elsif ( $uid == $self->{md5}->{uid} ) {
 219                 warn "# send_file - shared $f_full\n";
 220         }
 221
 222         $self->delete( $t, $t_path ) if -e $t_full;
 223
 224         my $size = -s $f_full;
 225         my $md5;
 226
 227         my $ok;
 228         {
 229                 no autodie qw(link);
 230                 $ok = link $f_full, $t_full
 231         };
 232         if ( ! $ok || $! =~ m/cross-link/ ) {
 233                 $ok = symlink $f_full, $t_full;
 234         } else {
 235                 $size = -s $t_full;
 236
 237                 if ( $f->{uid} == $self->{md5}->{uid} ) {
 238                         $md5 = $f_path; # we don't have local md5sum db for md5 user!
 239                 } else {
 240                         $md5 = $self->md5_get($f_full);
 241                 }
 242
 243         }
 244
 245         if ( $ok ) {
 246                 $self->append( $t, 'recv', $size, $f->{uid}, $t_path );
 247                 $self->append_meta('md5sum', $t, $md5 => $t_path ) if $md5; # md5sum for received files! FIXME -- cross-slice md5
 248                 $self->refresh_file_list( $t );
 249         } else {
 250                 warn "ERROR: send_file $f_full -> $t_full: $!";
 251         }
 252
 253         return $size;
 254 }
 255
 256 sub rename_file {
 257         my ( $self, $user, $from, $to ) = @_;
 258         $user = $self->user_info($user) unless ref $user eq 'HASH';
 259
 260         my $f_full = "$user->{dir}/$from";
 261         my $t_full = "$user->{dir}/$to";
 262
 263         $self->mkbasepath( $t_full, { uid => $user->{uid}, gid => $user->{gid} } );
 264         my $ok = rename $f_full, $t_full;
 265
 266         $self->refresh_file_list( $user );
 267
 268         my $md5 = $self->md5_get($t_full);
 269         if ( ! $md5 ) {
 270                 warn "ERROR: no md5sum for $from";
 271                 return $ok; # XXX our internal error
 272         }
 273
 274         $self->append_meta('md5sum', $user, 'rename' => $from );
 275         $self->append_meta('md5sum', $user, $md5 => $from );
 276
 277         return $ok;
 278 }
 279
 280
 281 sub delete {
 282         my ( $self, $user, $path ) = @_;
 283         $user = $self->user_info($user) unless ref $user eq 'HASH';
 284
 285         my $deleted_size = 0;
 286         my $full_path = "$user->{dir}/$path";
 287
 288         if ( -d $full_path ) {
 289
 290                 find({
 291                 no_chdir => 1,
 292                 wanted => sub {
 293                         return if -d $_;
 294                         my ($uid,$size) = (stat($_))[4,7];
 295                         warn "## find $uid $size $_\n";
 296                         if ( $uid == $self->{md5}->{uid} ) {
 297                                 $deleted_size += $size;
 298                         }
 299                 }}, $full_path);
 300
 301                 remove_tree $full_path;
 302         } else {
 303                 $deleted_size += -s $full_path;
 304                 unlink $full_path;
 305         }
 306
 307         warn "delete $deleted_size bytes shared\n";
 308
 309         $self->append( $user, 'delete', -$deleted_size, $user->{uid}, $path );
 310         $self->append_meta('md5sum', $user, 'delete', $path );
 311
 312         $self->refresh_file_list( $user );
 313
 314         return $full_path;
 315 }
 316
 317 sub file_size {
 318         my ( $self, $user, $path ) = @_;
 319         $user = $self->user_info($user) unless ref $user eq 'HASH';
 320
 321         my $full_path = "$user->{dir}/$path";
 322         return -s $full_path;
 323 }
 324
 325 sub list_files {
 326         my ( $self, $user, $path ) = @_;
 327
 328         $user =~ s{/+$}{} && warn "cleanup list_files arg [$user]";
 329
 330         $user = $self->user_info($user) unless ref $user eq 'HASH';
 331
 332         die "no dir for ",dump($user) unless exists $user->{dir};
 333
 334         my $files = $user->{dir} . '/.meta/files';
 335         if ( -e $files && -s $files > 0) {
 336                 local $/ = undef;
 337                 open(my $fh, '<', $files);
 338                 my $list = <$fh>;
 339                 close($fh);
 340                 warn "# list_files $user->{login} cached ", length($list), " bytes";
 341                 return $list;
 342         }
 343
 344         my $dir = $user->{dir};
 345         open(my $pipe, '-|', qq|find -L $dir -printf "%y %s %p\n"|);
 346         open(my $fh, '>', "$files.new");
 347         my $total_usage = 0;
 348         my $list_txt;
 349         while(<$pipe>) {
 350                 chomp;
 351                 my ( $type, $size, $name ) = split(/\s/, $_);
 352                 $name =~ s{$dir}{./};
 353                 $name =~ s{//+}{/}g;
 354                 my $line = "$type $size $name\n";
 355                 print $fh $line;
 356                 $list_txt .= $line;
 357                 $total_usage += $size;
 358         }
 359         close($pipe);
 360         close($fh);
 361         rename "$files.new", $files;
 362
 363         open(my $usage, '>', "$files.usage.new");
 364         print $usage $total_usage;
 365         close($usage);
 366         rename "$files.usage.new", "$files.usage";
 367
 368         warn "# list_files $dir usage: $total_usage\n";
 369
 370         return $list_txt;
 371 }
 372
 373 sub refresh_file_list {
 374         my ( $self, $user ) = @_;
 375         $user = $self->user_info($user) unless ref $user eq 'HASH';
 376         my $full_path = "$user->{dir}/.meta/files";
 377         if ( -e $full_path ) {
 378                 warn "## refresh_file_list $full_path";
 379                 unlink $full_path || warn "unlink $full_path: $!";
 380         } else {
 381                 warn "## refresh_file_list $full_path missing";
 382         }
 383
 384         unlink "$full_path.usage" if -e "$full_path.usage";
 385 }
 386
 387 1;