git.rot13.org Git - dell-switch/blob - dell-switch.pl

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4 use autodie;
   5
   6 use Net::OpenSSH;
   7 use Data::Dump qw(dump);
   8 use Time::HiRes qw(sleep);
   9
  10 our $login;
  11 our $passwd;
  12 our $debug = $ENV{DEBUG} || 0;
  13
  14 use lib '.';
  15 require 'config.pl';
  16
  17 #$Net::OpenSSH::debug = ~0;
  18
  19 my $ip = shift @ARGV || die "usage: $0 IP command[ command ...]\n";
  20 my @commands = @ARGV;
  21 @commands = <DATA> unless @commands;
  22
  23 warn "\n## ssh $ip\n";
  24 my $ssh = Net::OpenSSH->new($ip, user => $login, passwd => $passwd);
  25 my ($pty ,$pid) = $ssh->open2pty();
  26 if ( ! $pty ) {
  27         warn "ERROR: can't connect to $ip, skipping";
  28         exit 0;
  29 }
  30
  31 my $buff;
  32
  33 sub send_pty {
  34         my $string = shift;
  35         sleep 0.1; # we really need to wait for slow PowerConnect 5324
  36         foreach (split //, $string) {
  37                 print STDERR "[$_]" if $debug;
  38                 syswrite $pty, $_;
  39                 #$pty->flush;
  40                 sleep 0.05;
  41
  42                 sysread $pty, my $echo, 1;
  43                 print STDERR $echo;
  44                 $buff .= $echo;
  45         }
  46 }
  47
  48 mkdir 'log' unless -d 'log';
  49
  50 chdir 'log';
  51
  52 sub save_log {
  53         my ($ip, $hostname, $command, $buff) = @_;
  54
  55         return unless $command;
  56
  57         my $file = "${ip}_${hostname}_${command}.log";
  58         open my $log, '>', $file;
  59         $buff =~ s/\r//gs; # strip CR, leave LF only
  60         print $log $buff;
  61         if ( -e '.git' ) {
  62                 system 'git', 'add', $file;
  63                 system 'git', 'commit', '-m', "$ip $hostname", $file;
  64         }
  65 }
  66
  67 my $command;
  68 my @commands_while = ( @commands );
  69
  70 while() {
  71         my $data;
  72         my $read = sysread($pty, $data, 1);
  73         print STDERR $data;
  74         $buff .= $data;
  75         if ( $buff =~ m/User Name:/ ) {
  76                 send_pty "$login\n";
  77                 $buff = '';
  78         } elsif ( $buff =~ m/Password:/ ) {
  79                 send_pty "$passwd\n";
  80                 $buff = '';
  81         } elsif ( $buff =~ m/([\w\-]+)#$/ ) {
  82                 my $hostname = $1;
  83                 if ( $buff ) {
  84                         save_log $ip, $hostname, $command, $buff;
  85                         $buff = '';
  86                 }
  87                 if ( $command = shift @commands_while ) {
  88                         $command =~ s/[\n\r]+$//;
  89                         send_pty "$command\n";
  90                         $buff = '';
  91                 } else  {
  92                         send_pty "exit\n";
  93                         close($pty);
  94                         last;
  95                 }
  96         } elsif ( $buff =~ m/% Unrecognized command/ ) {
  97                 exit 1;
  98         } elsif ( $buff =~ s{More: <space>,  Quit: q.*One line: <return>\s*}{} ) {
  99                 send_pty " ";
 100         } elsif ( $buff =~ s{\Q--More-- or (q)uit\E}{} ) {
 101                 send_pty " ";
 102         } elsif ( $buff =~ s{\e\[0m\s*\r\s+\r}{} ) {
 103                 # nop
 104         } elsif ( $buff =~ m/^[\r\n]+[\w\-]+>$/ ) {
 105                 send_pty "enable\n";
 106         }
 107 }
 108
 109 __DATA__
 110 show system
 111 show arp
 112 show vlan
 113 show running-config
 114 show bridge address
 115 show interfaces status
 116