koha-tmpl/opac-tmpl/prog/en/xslt/UNIMARCslim2OPACDetail.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   4
   5 <xsl:stylesheet version="1.0"
   6   xmlns:marc="http://www.loc.gov/MARC21/slim"
   7   xmlns:items="http://www.koha-community.org/items"
   8   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9   exclude-result-prefixes="marc items">
  10
  11 <xsl:import href="UNIMARCslimUtils.xsl"/>
  12 <xsl:output method = "xml" indent="yes" omit-xml-declaration = "yes" />
  13 <xsl:template match="/">
  14   <xsl:apply-templates/>
  15 </xsl:template>
  16
  17 <xsl:template match="marc:record">
  18   <xsl:variable name="leader" select="marc:leader"/>
  19   <xsl:variable name="leader6" select="substring($leader,7,1)"/>
  20   <xsl:variable name="leader7" select="substring($leader,8,1)"/>
  21   <xsl:variable name="biblionumber" select="marc:datafield[@tag=090]/marc:subfield[@code='a']"/>
  22
  23
  24   <xsl:if test="marc:datafield[@tag=200]">
  25     <xsl:for-each select="marc:datafield[@tag=200]">
  26       <h1>
  27         <xsl:call-template name="addClassRtl" />
  28         <xsl:variable name="title" select="marc:subfield[@code='a']"/>
  29         <xsl:variable name="ntitle"
  30          select="translate($title, '&#x0098;&#x009C;','')"/>
  31         <xsl:value-of select="$ntitle" />
  32         <xsl:if test="marc:subfield[@code='e']">
  33           <xsl:text> : </xsl:text>
  34           <xsl:for-each select="marc:subfield[@code='e']">
  35             <xsl:value-of select="."/>
  36           </xsl:for-each>
  37         </xsl:if>
  38         <xsl:if test="marc:subfield[@code='b']">
  39           <xsl:text> [</xsl:text>
  40           <xsl:value-of select="marc:subfield[@code='b']"/>
  41           <xsl:text>]</xsl:text>
  42         </xsl:if>
  43         <xsl:if test="marc:subfield[@code='f']">
  44           <xsl:text> / </xsl:text>
  45           <xsl:value-of select="marc:subfield[@code='f']"/>
  46         </xsl:if>
  47         <xsl:if test="marc:subfield[@code='g']">
  48           <xsl:text> ; </xsl:text>
  49           <xsl:value-of select="marc:subfield[@code='g']"/>
  50         </xsl:if>
  51       </h1>
  52     </xsl:for-each>
  53   </xsl:if>
  54
  55   <xsl:call-template name="tag_4xx" />
  56
  57   <xsl:call-template name="tag_7xx">
  58     <xsl:with-param name="tag">700</xsl:with-param>
  59     <xsl:with-param name="label">Main Author</xsl:with-param>
  60   </xsl:call-template>
  61
  62   <xsl:call-template name="tag_7xx">
  63     <xsl:with-param name="tag">710</xsl:with-param>
  64     <xsl:with-param name="label">Corporate Author (Main)</xsl:with-param>
  65   </xsl:call-template>
  66
  67   <xsl:call-template name="tag_7xx">
  68     <xsl:with-param name="tag">701</xsl:with-param>
  69     <xsl:with-param name="label">Coauthor</xsl:with-param>
  70   </xsl:call-template>
  71
  72   <xsl:call-template name="tag_7xx">
  73     <xsl:with-param name="tag">702</xsl:with-param>
  74     <xsl:with-param name="label">Secondary Author</xsl:with-param>
  75   </xsl:call-template>
  76
  77   <xsl:call-template name="tag_7xx">
  78     <xsl:with-param name="tag">711</xsl:with-param>
  79     <xsl:with-param name="label">Corporate Author (Coauthor)</xsl:with-param>
  80   </xsl:call-template>
  81
  82   <xsl:call-template name="tag_7xx">
  83     <xsl:with-param name="tag">712</xsl:with-param>
  84     <xsl:with-param name="label">Corporate Author (Secondary)</xsl:with-param>
  85   </xsl:call-template>
  86
  87   <xsl:if test="marc:datafield[@tag=101]">
  88           <span class="results_summary">
  89       <span class="label">Language: </span>
  90       <xsl:for-each select="marc:datafield[@tag=101]">
  91         <xsl:for-each select="marc:subfield">
  92           <xsl:choose>
  93             <xsl:when test="@code='b'">of intermediate text, </xsl:when>
  94             <xsl:when test="@code='c'">of original work, </xsl:when>
  95             <xsl:when test="@code='d'">of summary, </xsl:when>
  96             <xsl:when test="@code='e'">of contents page, </xsl:when>
  97             <xsl:when test="@code='f'">of title page, </xsl:when>
  98             <xsl:when test="@code='g'">of title proper, </xsl:when>
  99             <xsl:when test="@code='h'">of libretto, </xsl:when>
 100             <xsl:when test="@code='i'">of accompanying material, </xsl:when>
 101             <xsl:when test="@code='j'">of subtitles, </xsl:when>
 102           </xsl:choose>
 103           <xsl:value-of select="text()"/>
 104           <xsl:choose>
 105             <xsl:when test="position()=last()">
 106               <xsl:text>.</xsl:text>
 107             </xsl:when>
 108             <xsl:otherwise>
 109               <xsl:text> ; </xsl:text>
 110             </xsl:otherwise>
 111           </xsl:choose>
 112         </xsl:for-each>
 113       </xsl:for-each>
 114     </span>
 115   </xsl:if>
 116
 117   <xsl:if test="marc:datafield[@tag=102]">
 118           <span class="results_summary">
 119       <span class="label">Country: </span>
 120       <xsl:for-each select="marc:datafield[@tag=102]">
 121         <xsl:for-each select="marc:subfield">
 122           <xsl:value-of select="text()"/>
 123           <xsl:choose>
 124             <xsl:when test="position()=last()">
 125               <xsl:text>.</xsl:text>
 126             </xsl:when>
 127               <xsl:otherwise><xsl:text>, </xsl:text>
 128             </xsl:otherwise>
 129           </xsl:choose>
 130         </xsl:for-each>
 131       </xsl:for-each>
 132     </span>
 133   </xsl:if>
 134
 135   <xsl:call-template name="tag_210" />
 136
 137   <xsl:call-template name="tag_215" />
 138
 139   <xsl:if test="marc:datafield[@tag=010]/marc:subfield[@code='a']">
 140     <span class="results_summary"><span class="label">ISBN: </span>
 141     <xsl:for-each select="marc:datafield[@tag=010]">
 142       <xsl:variable name="isbn" select="marc:subfield[@code='a']"/>
 143       <xsl:value-of select="marc:subfield[@code='a']"/>
 144       <xsl:choose>
 145         <xsl:when test="position()=last()">
 146           <xsl:text>.</xsl:text>
 147         </xsl:when>
 148         <xsl:otherwise>
 149           <xsl:text> ; </xsl:text>
 150         </xsl:otherwise>
 151       </xsl:choose>
 152     </xsl:for-each>
 153     </span>
 154   </xsl:if>
 155
 156   <xsl:if test="marc:datafield[@tag=011]">
 157     <span class="results_summary">
 158       <span class="label">ISSN: </span>
 159       <xsl:for-each select="marc:datafield[@tag=011]">
 160         <xsl:value-of select="marc:subfield[@code='a']"/>
 161         <xsl:choose>
 162           <xsl:when test="position()=last()">
 163             <xsl:text>.</xsl:text>
 164           </xsl:when>
 165           <xsl:otherwise>
 166             <xsl:text>; </xsl:text>
 167           </xsl:otherwise>
 168         </xsl:choose>
 169       </xsl:for-each>
 170     </span>
 171   </xsl:if>
 172
 173   <xsl:call-template name="tag_title">
 174     <xsl:with-param name="tag">225</xsl:with-param>
 175     <xsl:with-param name="label">Series</xsl:with-param>
 176   </xsl:call-template>
 177
 178   <xsl:if test="marc:datafield[@tag=676]">
 179     <span class="results_summary">
 180     <span class="label">Dewey: </span>
 181       <xsl:for-each select="marc:datafield[@tag=676]">
 182         <xsl:value-of select="marc:subfield[@code='a']"/>
 183         <xsl:if test="marc:subfield[@code='v']">
 184           <xsl:text>, </xsl:text>
 185           <xsl:value-of select="marc:subfield[@code='v']"/>
 186         </xsl:if>
 187         <xsl:if test="marc:subfield[@code='z']">
 188           <xsl:text>, </xsl:text>
 189           <xsl:value-of select="marc:subfield[@code='z']"/>
 190         </xsl:if>
 191         <xsl:if test="not (position()=last())">
 192           <xsl:text> ; </xsl:text>
 193         </xsl:if>
 194       </xsl:for-each>
 195     </span>
 196   </xsl:if>
 197
 198   <xsl:if test="marc:datafield[@tag=686]">
 199     <span class="results_summary">
 200     <span class="label">Classification: </span>
 201       <xsl:for-each select="marc:datafield[@tag=686]">
 202         <xsl:value-of select="marc:subfield[@code='a']"/>
 203         <xsl:if test="marc:subfield[@code='b']">
 204           <xsl:text>, </xsl:text>
 205           <xsl:value-of select="marc:subfield[@code='b']"/>
 206         </xsl:if>
 207         <xsl:if test="marc:subfield[@code='c']">
 208           <xsl:text>, </xsl:text>
 209           <xsl:value-of select="marc:subfield[@code='c']"/>
 210         </xsl:if>
 211         <xsl:if test="not (position()=last())"><xsl:text> ; </xsl:text></xsl:if>
 212       </xsl:for-each>
 213     </span>
 214   </xsl:if>
 215
 216   <xsl:if test="marc:datafield[@tag=327]">
 217     <span class="results_summary">
 218       <span class="label">Contents note: </span>
 219       <xsl:for-each select="marc:datafield[@tag=327]">
 220         <xsl:call-template name="chopPunctuation">
 221           <xsl:with-param name="chopString">
 222             <xsl:call-template name="subfieldSelect">
 223                 <xsl:with-param name="codes">abcdjpvxyz</xsl:with-param>
 224                 <xsl:with-param name="subdivCodes">jpxyz</xsl:with-param>
 225                 <xsl:with-param name="subdivDelimiter">-- </xsl:with-param>
 226             </xsl:call-template>
 227           </xsl:with-param>
 228         </xsl:call-template>
 229       </xsl:for-each>
 230     </span>
 231   </xsl:if>
 232
 233   <xsl:if test="marc:datafield[@tag=330]">
 234     <span class="results_summary">
 235       <span class="label">Abstract: </span>
 236       <xsl:for-each select="marc:datafield[@tag=330]">
 237         <xsl:value-of select="marc:subfield[@code='a']"/>
 238         <xsl:choose>
 239           <xsl:when test="position()=last()">
 240             <xsl:text>.</xsl:text>
 241           </xsl:when>
 242           <xsl:otherwise>
 243             <xsl:text>; </xsl:text>
 244           </xsl:otherwise>
 245         </xsl:choose>
 246       </xsl:for-each>
 247     </span>
 248   </xsl:if>
 249
 250   <xsl:if test="marc:datafield[@tag=317]">
 251     <span class="results_summary">
 252       <span class="label">Provenance note: </span>
 253       <xsl:for-each select="marc:datafield[@tag=317]">
 254           <xsl:value-of select="marc:subfield[@code='a']"/>
 255       </xsl:for-each>
 256     </span>
 257   </xsl:if>
 258
 259   <xsl:if test="marc:datafield[@tag=320]">
 260     <span class="results_summary">
 261       <span class="label">Bibliography: </span>
 262       <xsl:for-each select="marc:datafield[@tag=320]">
 263         <xsl:value-of select="marc:subfield[@code='a']"/>
 264         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 265       </xsl:for-each>
 266     </span>
 267   </xsl:if>
 268
 269   <xsl:if test="marc:datafield[@tag=328]">
 270     <span class="results_summary">
 271       <span class="label">Thesis: </span>
 272       <xsl:for-each select="marc:datafield[@tag=328]">
 273         <xsl:value-of select="marc:subfield[@code='a']"/>
 274         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 275       </xsl:for-each>
 276     </span>
 277   </xsl:if>
 278
 279   <xsl:if test="marc:datafield[@tag=333]">
 280     <span class="results_summary">
 281       <span class="label">Audience: </span>
 282       <xsl:for-each select="marc:datafield[@tag=333]">
 283         <xsl:value-of select="marc:subfield[@code='a']"/>
 284         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 285       </xsl:for-each>
 286     </span>
 287   </xsl:if>
 288
 289   <xsl:if test="marc:datafield[@tag=955]">
 290     <span class="results_summary">
 291       <span class="label">SUDOC serial history: </span>
 292       <xsl:for-each select="marc:datafield[@tag=955]">
 293         <xsl:value-of select="marc:subfield[@code='9']"/>:
 294         <xsl:value-of select="marc:subfield[@code='r']"/>
 295         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 296       </xsl:for-each>
 297     </span>
 298   </xsl:if>
 299
 300   <xsl:call-template name="tag_subject">
 301     <xsl:with-param name="tag">600</xsl:with-param>
 302     <xsl:with-param name="label">Subject - Personal Name</xsl:with-param>
 303   </xsl:call-template>
 304
 305   <xsl:call-template name="tag_subject">
 306     <xsl:with-param name="tag">601</xsl:with-param>
 307     <xsl:with-param name="label">Subject - Corporate Author</xsl:with-param>
 308   </xsl:call-template>
 309
 310   <xsl:call-template name="tag_subject">
 311     <xsl:with-param name="tag">602</xsl:with-param>
 312     <xsl:with-param name="label">Subject - Family</xsl:with-param>
 313   </xsl:call-template>
 314
 315   <xsl:call-template name="tag_subject">
 316     <xsl:with-param name="tag">604</xsl:with-param>
 317     <xsl:with-param name="label">Subject - Author/Title</xsl:with-param>
 318   </xsl:call-template>
 319
 320   <xsl:call-template name="tag_subject">
 321     <xsl:with-param name="tag">606</xsl:with-param>
 322     <xsl:with-param name="label">Subject - Topical Name</xsl:with-param>
 323   </xsl:call-template>
 324
 325   <xsl:call-template name="tag_subject">
 326     <xsl:with-param name="tag">607</xsl:with-param>
 327     <xsl:with-param name="label">Subject - Geographical Name</xsl:with-param>
 328   </xsl:call-template>
 329
 330   <xsl:call-template name="tag_subject">
 331     <xsl:with-param name="tag">608</xsl:with-param>
 332     <xsl:with-param name="label">Subject - Form</xsl:with-param>
 333   </xsl:call-template>
 334
 335   <xsl:call-template name="tag_subject">
 336     <xsl:with-param name="tag">610</xsl:with-param>
 337     <xsl:with-param name="label">Subject</xsl:with-param>
 338   </xsl:call-template>
 339
 340   <xsl:call-template name="tag_subject">
 341     <xsl:with-param name="tag">615</xsl:with-param>
 342     <xsl:with-param name="label">Subject Category</xsl:with-param>
 343   </xsl:call-template>
 344
 345   <xsl:call-template name="tag_subject">
 346     <xsl:with-param name="tag">616</xsl:with-param>
 347     <xsl:with-param name="label">Trademark</xsl:with-param>
 348   </xsl:call-template>
 349
 350   <xsl:if test="marc:datafield[@tag=856]">
 351     <span class="results_summary">
 352       <span class="label">Online Resources: </span>
 353       <xsl:for-each select="marc:datafield[@tag=856]">
 354         <a>
 355           <xsl:attribute name="href">
 356             <xsl:value-of select="marc:subfield[@code='u']"/>
 357           </xsl:attribute>
 358           <xsl:choose>
 359             <xsl:when test="marc:subfield[@code='y' or @code='3' or @code='z']">
 360               <xsl:call-template name="subfieldSelect">
 361                 <xsl:with-param name="codes">y3z</xsl:with-param>
 362               </xsl:call-template>
 363             </xsl:when>
 364             <xsl:when test="not(marc:subfield[@code='y']) and not(marc:subfield[@code='3']) and not(marc:subfield[@code='z'])">
 365               Click here to access online
 366             </xsl:when>
 367           </xsl:choose>
 368         </a>
 369         <xsl:choose>
 370           <xsl:when test="position()=last()"></xsl:when>
 371           <xsl:otherwise> | </xsl:otherwise>
 372         </xsl:choose>
 373       </xsl:for-each>
 374     </span>
 375   </xsl:if>
 376
 377         <!-- 780 -->
 378         <xsl:if test="marc:datafield[@tag=780]">
 379         <xsl:for-each select="marc:datafield[@tag=780]">
 380         <span class="results_summary">
 381         <xsl:choose>
 382         <xsl:when test="@ind2=0">
 383             <span class="label">Continues:</span>
 384         </xsl:when>
 385         <xsl:when test="@ind2=1">
 386             <span class="label">Continues in part:</span>
 387         </xsl:when>
 388         <xsl:when test="@ind2=2">
 389             <span class="label">Supersedes:</span>
 390         </xsl:when>
 391         <xsl:when test="@ind2=3">
 392             <span class="label">Supersedes in part:</span>
 393         </xsl:when>
 394         <xsl:when test="@ind2=4">
 395             <span class="label">Formed by the union: ... and: ...</span>
 396         </xsl:when>
 397         <xsl:when test="@ind2=5">
 398             <span class="label">Absorbed:</span>
 399         </xsl:when>
 400         <xsl:when test="@ind2=6">
 401             <span class="label">Absorbed in part:</span>
 402         </xsl:when>
 403         <xsl:when test="@ind2=7">
 404             <span class="label">Separated from:</span>
 405         </xsl:when>
 406         </xsl:choose>
 407                 <xsl:variable name="f780">
 408                     <xsl:call-template name="subfieldSelect">
 409                         <xsl:with-param name="codes">at</xsl:with-param>
 410                     </xsl:call-template>
 411                 </xsl:variable>
 412              <a><xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of select="translate($f780, '()', '')"/></xsl:attribute>
 413                 <xsl:value-of select="translate($f780, '()', '')"/>
 414             </a>
 415         </span>
 416
 417         <xsl:choose>
 418         <xsl:when test="@ind1=0">
 419             <span class="results_summary"><xsl:value-of select="marc:subfield[@code='n']"/></span>
 420         </xsl:when>
 421         </xsl:choose>
 422
 423         </xsl:for-each>
 424         </xsl:if>
 425
 426         <!-- 785 -->
 427         <xsl:if test="marc:datafield[@tag=785]">
 428         <xsl:for-each select="marc:datafield[@tag=785]">
 429         <span class="results_summary">
 430         <xsl:choose>
 431         <xsl:when test="@ind2=0">
 432             <span class="label">Continued by:</span>
 433         </xsl:when>
 434         <xsl:when test="@ind2=1">
 435             <span class="label">Continued in part by:</span>
 436         </xsl:when>
 437         <xsl:when test="@ind2=2">
 438             <span class="label">Superseded by:</span>
 439         </xsl:when>
 440         <xsl:when test="@ind2=3">
 441             <span class="label">Superseded in part by:</span>
 442         </xsl:when>
 443         <xsl:when test="@ind2=4">
 444             <span class="label">Absorbed by:</span>
 445         </xsl:when>
 446         <xsl:when test="@ind2=5">
 447             <span class="label">Absorbed in part by:</span>
 448         </xsl:when>
 449         <xsl:when test="@ind2=6">
 450             <span class="label">Split into .. and ...:</span>
 451         </xsl:when>
 452         <xsl:when test="@ind2=7">
 453             <span class="label">Merged with ... to form ...</span>
 454         </xsl:when>
 455         <xsl:when test="@ind2=8">
 456             <span class="label">Changed back to:</span>
 457         </xsl:when>
 458
 459         </xsl:choose>
 460                    <xsl:variable name="f785">
 461                     <xsl:call-template name="subfieldSelect">
 462                         <xsl:with-param name="codes">at</xsl:with-param>
 463                     </xsl:call-template>
 464                 </xsl:variable>
 465
 466                 <a><xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of select="translate($f785, '()', '')"/></xsl:attribute>
 467                 <xsl:value-of select="translate($f785, '()', '')"/>
 468             </a>
 469
 470         </span>
 471         </xsl:for-each>
 472         </xsl:if>
 473
 474     </xsl:template>
 475
 476     <xsl:template name="nameABCDQ">
 477             <xsl:call-template name="chopPunctuation">
 478                 <xsl:with-param name="chopString">
 479                     <xsl:call-template name="subfieldSelect">
 480                         <xsl:with-param name="codes">aq</xsl:with-param>
 481                     </xsl:call-template>
 482                 </xsl:with-param>
 483                 <xsl:with-param name="punctuation">
 484                     <xsl:text>:,;/ </xsl:text>
 485                 </xsl:with-param>
 486             </xsl:call-template>
 487         <xsl:call-template name="termsOfAddress"/>
 488     </xsl:template>
 489
 490     <xsl:template name="nameABCDN">
 491         <xsl:for-each select="marc:subfield[@code='a']">
 492                 <xsl:call-template name="chopPunctuation">
 493                     <xsl:with-param name="chopString" select="."/>
 494                 </xsl:call-template>
 495         </xsl:for-each>
 496         <xsl:for-each select="marc:subfield[@code='b']">
 497                 <xsl:value-of select="."/>
 498         </xsl:for-each>
 499         <xsl:if test="marc:subfield[@code='c'] or marc:subfield[@code='d'] or marc:subfield[@code='n']">
 500                 <xsl:call-template name="subfieldSelect">
 501                     <xsl:with-param name="codes">cdn</xsl:with-param>
 502                 </xsl:call-template>
 503         </xsl:if>
 504     </xsl:template>
 505
 506     <xsl:template name="nameACDEQ">
 507             <xsl:call-template name="subfieldSelect">
 508                 <xsl:with-param name="codes">acdeq</xsl:with-param>
 509             </xsl:call-template>
 510     </xsl:template>
 511     <xsl:template name="termsOfAddress">
 512         <xsl:if test="marc:subfield[@code='b' or @code='c']">
 513             <xsl:call-template name="chopPunctuation">
 514                 <xsl:with-param name="chopString">
 515                     <xsl:call-template name="subfieldSelect">
 516                         <xsl:with-param name="codes">bc</xsl:with-param>
 517                     </xsl:call-template>
 518                 </xsl:with-param>
 519             </xsl:call-template>
 520         </xsl:if>
 521     </xsl:template>
 522
 523     <xsl:template name="part">
 524         <xsl:variable name="partNumber">
 525             <xsl:call-template name="specialSubfieldSelect">
 526                 <xsl:with-param name="axis">n</xsl:with-param>
 527                 <xsl:with-param name="anyCodes">n</xsl:with-param>
 528                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 529             </xsl:call-template>
 530         </xsl:variable>
 531         <xsl:variable name="partName">
 532             <xsl:call-template name="specialSubfieldSelect">
 533                 <xsl:with-param name="axis">p</xsl:with-param>
 534                 <xsl:with-param name="anyCodes">p</xsl:with-param>
 535                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 536             </xsl:call-template>
 537         </xsl:variable>
 538         <xsl:if test="string-length(normalize-space($partNumber))">
 539                 <xsl:call-template name="chopPunctuation">
 540                     <xsl:with-param name="chopString" select="$partNumber"/>
 541                 </xsl:call-template>
 542         </xsl:if>
 543         <xsl:if test="string-length(normalize-space($partName))">
 544                 <xsl:call-template name="chopPunctuation">
 545                     <xsl:with-param name="chopString" select="$partName"/>
 546                 </xsl:call-template>
 547         </xsl:if>
 548     </xsl:template>
 549
 550     <xsl:template name="specialSubfieldSelect">
 551         <xsl:param name="anyCodes"/>
 552         <xsl:param name="axis"/>
 553         <xsl:param name="beforeCodes"/>
 554         <xsl:param name="afterCodes"/>
 555         <xsl:variable name="str">
 556             <xsl:for-each select="marc:subfield">
 557                 <xsl:if test="contains($anyCodes, @code)      or (contains($beforeCodes,@code) and following-sibling::marc:subfield[@code=$axis])      or (contains($afterCodes,@code) and preceding-sibling::marc:subfield[@code=$axis])">
 558                     <xsl:value-of select="text()"/>
 559                     <xsl:text> </xsl:text>
 560                 </xsl:if>
 561             </xsl:for-each>
 562         </xsl:variable>
 563         <xsl:value-of select="substring($str,1,string-length($str)-1)"/>
 564     </xsl:template>
 565
 566 </xsl:stylesheet>