arch/arm/boot/compressed/head-sa1100.S

   1 /*
   2  * linux/arch/arm/boot/compressed/head-sa1100.S
   3  *
   4  * Copyright (C) 1999 Nicolas Pitre <nico@cam.org>
   5  *
   6  * SA1100 specific tweaks.  This is merged into head.S by the linker.
   7  *
   8  */
   9
  10 #include <linux/config.h>
  11 #include <linux/linkage.h>
  12 #include <asm/mach-types.h>
  13
  14                 .section        ".start", "ax"
  15
  16 __SA1100_start:
  17
  18                 @ Preserve r8/r7 i.e. kernel entry values
  19
  20 #if defined(CONFIG_SA1100_GRAPHICSCLIENT) && !defined(CONFIG_ANGELBOOT)
  21                 mov     r7, #MACH_TYPE_GRAPHICSCLIENT
  22                 mov     r8, #0
  23 #endif
  24 #if defined(CONFIG_SA1100_GRAPHICSMASTER) && !defined(CONFIG_ANGELBOOT)
  25                 mov     r7, #MACH_TYPE_GRAPHICSMASTER
  26                 mov     r8, #0
  27 #endif
  28 #if defined(CONFIG_SA1100_ADSBITSY) && !defined(CONFIG_ANGELBOOT)
  29                 mov     r7, #MACH_TYPE_ADSBITSY
  30                 mov     r8, #0
  31 #endif
  32
  33 #ifdef CONFIG_SA1100_PFS168
  34                 @ REVISIT_PFS168: Temporary until firmware updated to use assigned machine number
  35                 mov     r7, #MACH_TYPE_PFS168
  36 #endif
  37
  38 #ifdef CONFIG_SA1100_VICTOR
  39                 teq     r7, #MACH_TYPE_VICTOR
  40                 bne     10f
  41
  42                 @ Copy cmdline to 0xc0000000
  43                 mov     r1, #0xc0000000
  44                 cmp     r0, #0
  45                 moveq   r2, #0
  46 1:              ldrneb  r2, [r0], #1
  47                 cmpne   r2, #0
  48                 strb    r2, [r1], #1
  49                 bne     1b
  50 10:
  51 #endif
  52
  53                 @ Data cache might be active.
  54                 @ Be sure to flush kernel binary out of the cache,
  55                 @ whatever state it is, before it is turned off.
  56                 @ This is done by fetching through currently executed
  57                 @ memory to be sure we hit the same cache.
  58                 bic     r2, pc, #0x1f
  59                 add     r3, r2, #0x4000         @ 16 kb is quite enough...
  60 1:              ldr     r0, [r2], #32
  61                 teq     r2, r3
  62                 bne     1b
  63                 mcr     p15, 0, r0, c7, c10, 4  @ drain WB
  64                 mcr     p15, 0, r0, c7, c7, 0   @ flush I & D caches
  65
  66                 @ disabling MMU and caches
  67                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
  68                 bic     r0, r0, #0x0d           @ clear WB, DC, MMU
  69                 bic     r0, r0, #0x1000         @ clear Icache
  70                 mcr     p15, 0, r0, c1, c0, 0
  71
  72 /*
  73  * Pause for a short time so that we give enough time
  74  * for the host to start a terminal up.
  75  */
  76                 mov     r0, #0x00200000
  77 1:              subs    r0, r0, #1
  78                 bne     1b
  79