arch/sh64/vmlinux.lds.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * arch/sh5/vmlinux.lds.S
   7  *
   8  * ld script to make ST50 Linux kernel
   9  *
  10  * Copyright (C) 2000, 2001  Paolo Alberelli
  11  *
  12  * benedict.gaster@superh.com:   2nd May 2002
  13  *    Add definition of empty_zero_page to be the first page of kernel image.
  14  *
  15  * benedict.gaster@superh.com:   3rd May 2002
  16  *    Added support for ramdisk, removing statically linked romfs at the same time.
  17  *
  18  * lethal@linux-sh.org:          9th May 2003
  19  *    Kill off GLOBAL_NAME() usage and other CDC-isms.
  20  *
  21  * lethal@linux-sh.org:         19th May 2003
  22  *    Remove support for ancient toolchains.
  23  */
  24
  25 #include <linux/config.h>
  26 #include <asm/page.h>
  27 #include <asm/cache.h>
  28 #include <asm/processor.h>
  29
  30 #ifdef NOTDEF
  31 #ifdef CONFIG_LITTLE_ENDIAN
  32 OUTPUT_FORMAT("elf32-sh64l-linux", "elf32-sh64l-linux", "elf32-sh64l-linux")
  33 #else
  34 OUTPUT_FORMAT("elf32-sh64", "elf32-sh64", "elf32-sh64")
  35 #endif
  36 #endif
  37
  38 OUTPUT_ARCH(sh:sh5)
  39
  40 #define C_PHYS(x) AT (ADDR(x) - CONFIG_CACHED_MEMORY_OFFSET)
  41
  42 ENTRY(__start)
  43 SECTIONS
  44 {
  45   . = CONFIG_CACHED_MEMORY_OFFSET + CONFIG_MEMORY_START + PAGE_SIZE;
  46   _text = .;                    /* Text and read-only data */
  47   text = .;                     /* Text and read-only data */
  48
  49   .empty_zero_page : C_PHYS(.empty_zero_page) {
  50         *(.empty_zero_page)
  51         } = 0
  52
  53   .text : C_PHYS(.text) {
  54         *(.text)
  55         *(.text64)
  56         *(.text..SHmedia32)
  57         *(.fixup)
  58         *(.gnu.warning)
  59 #ifdef CONFIG_LITTLE_ENDIAN
  60         } = 0x6ff0fff0
  61 #else
  62         } = 0xf0fff06f
  63 #endif
  64   .text.lock : C_PHYS(.text.lock) { *(.text.lock) }     /* out-of-line lock text */
  65   .rodata : C_PHYS(.rodata) { *(.rodata) *(.rodata.str1.8) }
  66   .kstrtab : C_PHYS(.kstrtab) { *(.kstrtab) }
  67
  68   /* We likely want __ex_table to be Cache Line aligned */
  69   . = ALIGN(L1_CACHE_BYTES);            /* Exception table */
  70   __start___ex_table = .;
  71   __ex_table : C_PHYS(__ex_table) { *(__ex_table) }
  72   __stop___ex_table = .;
  73
  74   __start___ksymtab = .;        /* Kernel symbol table */
  75   __ksymtab : C_PHYS(__ksymtab) { *(__ksymtab) }
  76   __stop___ksymtab = .;
  77
  78   _etext = .;                   /* End of text section */
  79
  80   .data : C_PHYS(.data) {                       /* Data */
  81         *(.data)
  82         CONSTRUCTORS
  83         }
  84
  85   _edata = .;                   /* End of data section */
  86
  87   . = ALIGN(INIT_TASK_SIZE);    /* init_task: structure size aligned */
  88   .data.init_task : C_PHYS(.data.init_task) { *(.data.init_task) }
  89
  90   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  91   __init_begin = .;
  92   .text.init : C_PHYS(.text.init) { *(.text.init) }
  93   .data.init : C_PHYS(.data.init) { *(.data.init) }
  94   . = ALIGN(L1_CACHE_BYTES);    /* Better if Cache Line aligned */
  95   __setup_start = .;
  96   .setup.init : C_PHYS(.setup.init) { *(.setup.init) }
  97   __setup_end = .;
  98   __initcall_start = .;
  99   .initcall.init : C_PHYS(.initcall.init) { *(.initcall.init) }
 100   __initcall_end = .;
 101   . = ALIGN(PAGE_SIZE);
 102   __init_end = .;
 103
 104   . = ALIGN(L1_CACHE_BYTES);
 105   .data.cacheline_aligned : C_PHYS(.data.cacheline_aligned) { *(.data.cacheline_aligned) }
 106
 107   /* Align to the biggest single data representation, head and tail */
 108   . = ALIGN(8);
 109   __bss_start = .;              /* BSS */
 110   .bss : C_PHYS(.bss) {
 111         *(.bss)
 112         }
 113   . = ALIGN(8);
 114   _end = . ;
 115
 116   /* Sections to be discarded */
 117   /DISCARD/ : {
 118         *(.text.exit)
 119         *(.data.exit)
 120         *(.exitcall.exit)
 121         }
 122
 123   /* Stabs debugging sections.  */
 124   .stab 0 : C_PHYS(.stab) { *(.stab) }
 125   .stabstr 0 : C_PHYS(.stabstr) { *(.stabstr) }
 126   .stab.excl 0 : C_PHYS(.stab.excl) { *(.stab.excl) }
 127   .stab.exclstr 0 : C_PHYS(.stab.exclstr) { *(.stab.exclstr) }
 128   .stab.index 0 : C_PHYS(.stab.index) { *(.stab.index) }
 129   .stab.indexstr 0 : C_PHYS(.stab.indexstr) { *(.stab.indexstr) }
 130   .comment 0 : C_PHYS(.comment) { *(.comment) }
 131   /* DWARF debug sections.
 132      Symbols in the DWARF debugging section are relative to the beginning
 133      of the section so we begin .debug at 0.  */
 134   /* DWARF 1 */
 135   .debug          0 : C_PHYS(.debug) { *(.debug) }
 136   .line           0 : C_PHYS(.line) { *(.line) }
 137   /* GNU DWARF 1 extensions */
 138   .debug_srcinfo  0 : C_PHYS(.debug_srcinfo) { *(.debug_srcinfo) }
 139   .debug_sfnames  0 : C_PHYS(.debug_sfnames) { *(.debug_sfnames) }
 140   /* DWARF 1.1 and DWARF 2 */
 141   .debug_aranges  0 : C_PHYS(.debug_aranges) { *(.debug_aranges) }
 142   .debug_pubnames 0 : C_PHYS(.debug_pubnames) { *(.debug_pubnames) }
 143   /* DWARF 2 */
 144   .debug_info     0 : C_PHYS(.debug_info) { *(.debug_info) }
 145   .debug_abbrev   0 : C_PHYS(.debug_abbrev) { *(.debug_abbrev) }
 146   .debug_line     0 : C_PHYS(.debug_line) { *(.debug_line) }
 147   .debug_frame    0 : C_PHYS(.debug_frame) { *(.debug_frame) }
 148   .debug_str      0 : C_PHYS(.debug_str) { *(.debug_str) }
 149   .debug_loc      0 : C_PHYS(.debug_loc) { *(.debug_loc) }
 150   .debug_macinfo  0 : C_PHYS(.debug_macinfo) { *(.debug_macinfo) }
 151   /* SGI/MIPS DWARF 2 extensions */
 152   .debug_weaknames 0 : C_PHYS(.debug_weaknames) { *(.debug_weaknames) }
 153   .debug_funcnames 0 : C_PHYS(.debug_funcnames) { *(.debug_funcnames) }
 154   .debug_typenames 0 : C_PHYS(.debug_typenames) { *(.debug_typenames) }
 155   .debug_varnames  0 : C_PHYS(.debug_varnames) { *(.debug_varnames) }
 156   /* These must appear regardless of  .  */
 157 }