arch/sparc64/vmlinux.lds

   1 /* ld script to make UltraLinux kernel */
   2 OUTPUT_FORMAT("elf64-sparc", "elf64-sparc", "elf64-sparc")
   3 OUTPUT_ARCH(sparc:v9a)
   4 ENTRY(_start)
   5
   6 SECTIONS
   7 {
   8   swapper_pmd_dir = 0x0000000000402000;
   9   empty_pg_dir = 0x0000000000403000;
  10   . = 0x4000;
  11   .text 0x0000000000404000 :
  12   {
  13     *(.text)
  14     *(.gnu.warning)
  15   } =0
  16   _etext = .;
  17   PROVIDE (etext = .);
  18   .rodata    : { *(.rodata) *(.rodata.*) }
  19   .rodata1   : { *(.rodata1) }
  20   .data    :
  21   {
  22     *(.data)
  23     CONSTRUCTORS
  24   }
  25   .data1   : { *(.data1) }
  26   _edata  =  .;
  27   PROVIDE (edata = .);
  28   .fixup   : { *(.fixup) }
  29   . = ALIGN(16);
  30   __start___ex_table = .;
  31   __ex_table : { *(__ex_table) }
  32   __stop___ex_table = .;
  33   __start___ksymtab = .;
  34   __ksymtab  : { *(__ksymtab) }
  35   __stop___ksymtab = .;
  36   __kstrtab  : { *(.kstrtab) }
  37   __start___kallsyms = .;       /* All kernel symbols */
  38   __kallsyms : { *(__kallsyms) }
  39   __stop___kallsyms = .;
  40   . = ALIGN(8192);
  41   __init_begin = .;
  42   .text.init : { *(.text.init) }
  43   .data.init : { *(.data.init) }
  44   . = ALIGN(16);
  45   __setup_start = .;
  46   .setup_init : { *(.setup.init) }
  47   __setup_end = .;
  48   __initcall_start = .;
  49   .initcall.init : { *(.initcall.init) }
  50   __initcall_end = .;
  51   . = ALIGN(8192);
  52   __init_end = .;
  53   . = ALIGN(64);
  54   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  55   __bss_start = .;
  56   .sbss      : { *(.sbss) *(.scommon) }
  57   .bss       :
  58   {
  59    *(.dynbss)
  60    *(.bss)
  61    *(COMMON)
  62   }
  63   _end = . ;
  64   PROVIDE (end = .);
  65   /* Stabs debugging sections.  */
  66   .stab 0 : { *(.stab) }
  67   .stabstr 0 : { *(.stabstr) }
  68   .stab.excl 0 : { *(.stab.excl) }
  69   .stab.exclstr 0 : { *(.stab.exclstr) }
  70   .stab.index 0 : { *(.stab.index) }
  71   .stab.indexstr 0 : { *(.stab.indexstr) }
  72   .comment 0 : { *(.comment) }
  73   .debug          0 : { *(.debug) }
  74   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  75   .debug_aranges  0 : { *(.debug_aranges) }
  76   .debug_pubnames 0 : { *(.debug_pubnames) }
  77   .debug_sfnames  0 : { *(.debug_sfnames) }
  78   .line           0 : { *(.line) }
  79   /DISCARD/ : { *(.text.exit) *(.data.exit) *(.exitcall.exit) }
  80 }