board/mpl/pip405/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   /* Read-only sections, merged into text segment: */
  36   . = + SIZEOF_HEADERS;
  37   .interp : { *(.interp) }
  38   .hash          : { *(.hash)           }
  39   .dynsym        : { *(.dynsym)         }
  40   .dynstr        : { *(.dynstr)         }
  41   .rel.text      : { *(.rel.text)               }
  42   .rela.text     : { *(.rela.text)      }
  43   .rel.data      : { *(.rel.data)               }
  44   .rela.data     : { *(.rela.data)      }
  45   .rel.rodata    : { *(.rel.rodata)     }
  46   .rela.rodata   : { *(.rela.rodata)    }
  47   .rel.got       : { *(.rel.got)                }
  48   .rela.got      : { *(.rela.got)               }
  49   .rel.ctors     : { *(.rel.ctors)      }
  50   .rela.ctors    : { *(.rela.ctors)     }
  51   .rel.dtors     : { *(.rel.dtors)      }
  52   .rela.dtors    : { *(.rela.dtors)     }
  53   .rel.bss       : { *(.rel.bss)                }
  54   .rela.bss      : { *(.rela.bss)               }
  55   .rel.plt       : { *(.rel.plt)                }
  56   .rela.plt      : { *(.rela.plt)               }
  57   .init          : { *(.init)   }
  58   .plt : { *(.plt) }
  59   .text      :
  60   {
  61     /* WARNING - the following is hand-optimized to fit within  */
  62     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  63
  64     cpu/ppc4xx/start.o  (.text)
  65     board/mpl/pip405/init.o     (.text)
  66     cpu/ppc4xx/kgdb.o   (.text)
  67     cpu/ppc4xx/traps.o  (.text)
  68     cpu/ppc4xx/interrupts.o     (.text)
  69     cpu/ppc4xx/serial.o (.text)
  70     cpu/ppc4xx/cpu_init.o       (.text)
  71     cpu/ppc4xx/speed.o  (.text)
  72     common/dlmalloc.o   (.text)
  73     lib_generic/crc32.o         (.text)
  74     lib_ppc/extable.o   (.text)
  75     lib_generic/zlib.o          (.text)
  76
  77 /*    . = env_offset;*/
  78 /*    common/environment.o(.text)*/
  79
  80     *(.text)
  81     *(.fixup)
  82     *(.got1)
  83   }
  84   _etext = .;
  85   PROVIDE (etext = .);
  86   .rodata    :
  87   {
  88     *(.rodata)
  89     *(.rodata1)
  90     *(.rodata.str1.4)
  91     *(.eh_frame)
  92   }
  93   .fini      : { *(.fini)    } =0
  94   .ctors     : { *(.ctors)   }
  95   .dtors     : { *(.dtors)   }
  96
  97   /* Read-write section, merged into data segment: */
  98   . = (. + 0x00FF) & 0xFFFFFF00;
  99   _erotext = .;
 100   PROVIDE (erotext = .);
 101   .reloc   :
 102   {
 103     *(.got)
 104     _GOT2_TABLE_ = .;
 105     *(.got2)
 106     _FIXUP_TABLE_ = .;
 107     *(.fixup)
 108   }
 109   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 110   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 111
 112   .data    :
 113   {
 114     *(.data)
 115     *(.data1)
 116     *(.sdata)
 117     *(.sdata2)
 118     *(.dynamic)
 119     CONSTRUCTORS
 120   }
 121   _edata  =  .;
 122   PROVIDE (edata = .);
 123
 124   . = .;
 125   __u_boot_cmd_start = .;
 126   .u_boot_cmd : { *(.u_boot_cmd) }
 127   __u_boot_cmd_end = .;
 128
 129
 130   . = .;
 131   __start___ex_table = .;
 132   __ex_table : { *(__ex_table) }
 133   __stop___ex_table = .;
 134
 135   . = ALIGN(256);
 136   __init_begin = .;
 137   .text.init : { *(.text.init) }
 138   .data.init : { *(.data.init) }
 139   . = ALIGN(256);
 140   __init_end = .;
 141
 142   __bss_start = .;
 143   .bss       :
 144   {
 145    *(.sbss) *(.scommon)
 146    *(.dynbss)
 147    *(.bss)
 148    *(COMMON)
 149   }
 150   _end = . ;
 151   PROVIDE (end = .);
 152 }