git.rot13.org Git - webpac2/blob - lib/WebPAC/Input.pm

   1 package WebPAC::Input;
   2
   3 use warnings;
   4 use strict;
   5
   6 use blib;
   7
   8 use WebPAC::Common;
   9 use base qw/WebPAC::Common/;
  10 use Data::Dump qw/dump/;
  11 use Encode qw/from_to/;
  12
  13 =head1 NAME
  14
  15 WebPAC::Input - read different file formats into WebPAC
  16
  17 =head1 VERSION
  18
  19 Version 0.16
  20
  21 =cut
  22
  23 our $VERSION = '0.16';
  24
  25 =head1 SYNOPSIS
  26
  27 This module implements input as database which have fixed and known
  28 I<size> while indexing and single unique numeric identifier for database
  29 position ranging from 1 to I<size>.
  30
  31 Simply, something that is indexed by unmber from 1 .. I<size>.
  32
  33 Examples of such databases are CDS/ISIS files, MARC files, lines in
  34 text file, and so on.
  35
  36 Specific file formats are implemented using low-level interface modules,
  37 located in C<WebPAC::Input::*> namespace which export C<open_db>,
  38 C<fetch_rec> and optional C<init> functions.
  39
  40 Perhaps a little code snippet.
  41
  42         use WebPAC::Input;
  43
  44         my $db = WebPAC::Input->new(
  45                 module => 'WebPAC::Input::ISIS',
  46         );
  47
  48         $db->open( path => '/path/to/database' );
  49         print "database size: ",$db->size,"\n";
  50         while (my $rec = $db->fetch) {
  51                 # do something with $rec
  52         }
  53
  54
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 new
  59
  60 Create new input database object.
  61
  62   my $db = new WebPAC::Input(
  63         module => 'WebPAC::Input::MARC',
  64         encoding => 'ISO-8859-2',
  65         recode => 'char pairs',
  66         no_progress_bar => 1,
  67   );
  68
  69 C<module> is low-level file format module. See L<WebPAC::Input::ISIS> and
  70 L<WebPAC::Input::MARC>.
  71
  72 Optional parametar C<encoding> specify application code page (which will be
  73 used internally). This should probably be your terminal encoding, and by
  74 default, it C<ISO-8859-2>.
  75
  76 C<recode> is optional string constisting of character or words pairs that
  77 should be replaced in input stream.
  78
  79 C<no_progress_bar> disables progress bar output on C<STDOUT>
  80
  81 This function will also call low-level C<init> if it exists with same
  82 parametars.
  83
  84 =cut
  85
  86 sub new {
  87         my $class = shift;
  88         my $self = {@_};
  89         bless($self, $class);
  90
  91         my $log = $self->_get_logger;
  92
  93         $log->logconfess("code_page argument is not suppored any more. change it to encoding") if ($self->{lookup});
  94         $log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_ref") if ($self->{lookup});
  95         $log->logconfess("low_mem argument is not suppored any more. rewrite it to load_row and save_row") if ($self->{low_mem});
  96
  97         $log->logconfess("specify low-level file format module") unless ($self->{module});
  98         my $module_path = $self->{module};
  99         $module_path =~ s#::#/#g;
 100         $module_path .= '.pm';
 101         $log->debug("require low-level module $self->{module} from $module_path");
 102
 103         require $module_path;
 104
 105         $self->{'encoding'} ||= 'ISO-8859-2';
 106
 107         $self ? return $self : return undef;
 108 }
 109
 110 =head2 open
 111
 112 This function will read whole database in memory and produce lookups.
 113
 114  my $store;     # simple in-memory hash
 115
 116  $input->open(
 117         path => '/path/to/database/file',
 118         code_page => 'cp852',
 119         limit => 500,
 120         offset => 6000,
 121         stats => 1,
 122         lookup_coderef => sub {
 123                 my $rec = shift;
 124                 # store lookups
 125         },
 126         modify_records => {
 127                 900 => { '^a' => { ' : ' => '^b' } },
 128                 901 => { '*' => { '^b' => ' ; ' } },
 129         },
 130         modify_file => 'conf/modify/mapping.map',
 131         save_row => sub {
 132                 my $a = shift;
 133                 $store->{ $a->{id} } = $a->{row};
 134         },
 135         load_row => sub {
 136                 my $a = shift;
 137                 return defined($store->{ $a->{id} }) &&
 138                         $store->{ $a->{id} };
 139         },
 140
 141  );
 142
 143 By default, C<code_page> is assumed to be C<cp852>.
 144
 145 C<offset> is optional parametar to position at some offset before reading from database.
 146
 147 C<limit> is optional parametar to read just C<limit> records from database
 148
 149 C<stats> create optional report about usage of fields and subfields
 150
 151 C<lookup_coderef> is closure to called to save data into lookups
 152
 153 C<modify_records> specify mapping from subfields to delimiters or from
 154 delimiters to subfields, as well as oprations on fields (if subfield is
 155 defined as C<*>.
 156
 157 C<modify_file> is alternative for C<modify_records> above which preserves order and offers
 158 (hopefully) simplier sintax than YAML or perl (see L</modify_file_regex>). This option
 159 overrides C<modify_records> if both exists for same input.
 160
 161 C<save_row> and C<load_row> are low-level implementation of store engine. Calling convention
 162 is documented in example above.
 163
 164 Returns size of database, regardless of C<offset> and C<limit>
 165 parametars, see also C<size>.
 166
 167 =cut
 168
 169 sub open {
 170         my $self = shift;
 171         my $arg = {@_};
 172
 173         my $log = $self->_get_logger();
 174
 175         $log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_coderef") if ($arg->{lookup});
 176         $log->logconfess("lookup_coderef must be CODE, not ",ref($arg->{lookup_coderef}))
 177                 if ($arg->{lookup_coderef} && ref($arg->{lookup_coderef}) ne 'CODE');
 178
 179         $log->debug( $arg->{lookup_coderef} ? '' : 'not ', "using lookup_coderef");
 180
 181         $log->logcroak("need path") if (! $arg->{'path'});
 182         my $code_page = $arg->{'code_page'} || 'cp852';
 183
 184         # store data in object
 185         $self->{'input_code_page'} = $code_page;
 186         foreach my $v (qw/path offset limit/) {
 187                 $self->{$v} = $arg->{$v} if ($arg->{$v});
 188         }
 189
 190         if ($arg->{load_row} || $arg->{save_row}) {
 191                 $log->logconfess("save_row and load_row must be defined in pair and be CODE") unless (
 192                         ref($arg->{load_row}) eq 'CODE' &&
 193                         ref($arg->{save_row}) eq 'CODE'
 194                 );
 195                 $self->{load_row} = $arg->{load_row};
 196                 $self->{save_row} = $arg->{save_row};
 197                 $log->debug("using load_row and save_row instead of in-memory hash");
 198         }
 199
 200         my $filter_ref;
 201         my $recode_regex;
 202         my $recode_map;
 203
 204         if ($self->{recode}) {
 205                 my @r = split(/\s/, $self->{recode});
 206                 if ($#r % 2 != 1) {
 207                         $log->logwarn("recode needs even number of elements (some number of valid pairs)");
 208                 } else {
 209                         while (@r) {
 210                                 my $from = shift @r;
 211                                 my $to = shift @r;
 212                                 $recode_map->{$from} = $to;
 213                         }
 214
 215                         $recode_regex = join '|' => keys %{ $recode_map };
 216
 217                         $log->debug("using recode regex: $recode_regex");
 218                 }
 219
 220         }
 221
 222         my $rec_regex;
 223         if (my $p = $arg->{modify_file}) {
 224                 $log->debug("using modify_file $p");
 225                 $rec_regex = $self->modify_file_regexps( $p );
 226         } elsif (my $h = $arg->{modify_records}) {
 227                 $log->debug("using modify_records ", sub { dump( $h ) });
 228                 $rec_regex = $self->modify_record_regexps(%{ $h });
 229         }
 230         $log->debug("rec_regex: ", sub { dump($rec_regex) }) if ($rec_regex);
 231
 232         my $class = $self->{module} || $log->logconfess("can't get low-level module name!");
 233
 234         my $ll_db = $class->new(
 235                 path => $arg->{path},
 236 #               filter => sub {
 237 #                       my ($l,$f_nr) = @_;
 238 #                       return unless defined($l);
 239 #                       from_to($l, $code_page, $self->{'encoding'});
 240 #                       $l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map);
 241 #                       return $l;
 242 #               },
 243                 %{ $arg },
 244         );
 245
 246         unless (defined($ll_db)) {
 247                 $log->logwarn("can't open database $arg->{path}, skipping...");
 248                 return;
 249         }
 250
 251         my $size = $ll_db->size;
 252
 253         unless ($size) {
 254                 $log->logwarn("no records in database $arg->{path}, skipping...");
 255                 return;
 256         }
 257
 258         my $from_rec = 1;
 259         my $to_rec = $size;
 260
 261         if (my $s = $self->{offset}) {
 262                 $log->debug("skipping to MFN $s");
 263                 $from_rec = $s;
 264         } else {
 265                 $self->{offset} = $from_rec;
 266         }
 267
 268         if ($self->{limit}) {
 269                 $log->debug("limiting to ",$self->{limit}," records");
 270                 $to_rec = $from_rec + $self->{limit} - 1;
 271                 $to_rec = $size if ($to_rec > $size);
 272         }
 273
 274         # store size for later
 275         $self->{size} = ($to_rec - $from_rec) ? ($to_rec - $from_rec + 1) : 0;
 276
 277         $log->info("processing $self->{size}/$size records [$from_rec-$to_rec] convert $code_page -> $self->{encoding}", $self->{stats} ? ' [stats]' : '');
 278
 279         # read database
 280         for (my $pos = $from_rec; $pos <= $to_rec; $pos++) {
 281
 282                 $log->debug("position: $pos\n");
 283
 284                 my $rec = $ll_db->fetch_rec($pos, sub {
 285                                 my ($l,$f_nr) = @_;
 286 #                               return unless defined($l);
 287 #                               return $l unless ($rec_regex && $f_nr);
 288
 289                                 $log->debug("-=> $f_nr ## $l");
 290
 291                                 # codepage conversion and recode_regex
 292                                 from_to($l, $code_page, $self->{'encoding'});
 293                                 $l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map);
 294
 295                                 # apply regexps
 296                                 if ($rec_regex && defined($rec_regex->{$f_nr})) {
 297                                         $log->logconfess("regexps->{$f_nr} must be ARRAY") if (ref($rec_regex->{$f_nr}) ne 'ARRAY');
 298                                         my $c = 0;
 299                                         foreach my $r (@{ $rec_regex->{$f_nr} }) {
 300                                                 my $old_l = $l;
 301                                                 eval '$l =~ ' . $r;
 302                                                 if ($old_l ne $l) {
 303                                                         $log->debug("REGEX on $f_nr eval \$l =~ $r\n## old l: [$old_l]\n## new l: [$l]");
 304                                                 }
 305                                                 $log->error("error applying regex: $r") if ($@);
 306                                         }
 307                                 }
 308
 309                                 $log->debug("<=- $f_nr ## $l");
 310                                 return $l;
 311                 });
 312
 313                 $log->debug(sub { dump($rec) });
 314
 315                 if (! $rec) {
 316                         $log->warn("record $pos empty? skipping...");
 317                         next;
 318                 }
 319
 320                 # store
 321                 if ($self->{save_row}) {
 322                         $self->{save_row}->({
 323                                 id => $pos,
 324                                 row => $rec,
 325                         });
 326                 } else {
 327                         $self->{data}->{$pos} = $rec;
 328                 }
 329
 330                 # create lookup
 331                 $arg->{'lookup_coderef'}->( $rec ) if ($rec && $arg->{'lookup_coderef'});
 332
 333                 # update counters for statistics
 334                 if ($self->{stats}) {
 335
 336                         # fetch clean record with regexpes applied for statistics
 337                         my $rec = $ll_db->fetch_rec($pos);
 338
 339                         foreach my $fld (keys %{ $rec }) {
 340                                 $self->{_stats}->{fld}->{ $fld }++;
 341
 342                                 $log->logdie("invalid record fild $fld, not ARRAY")
 343                                         unless (ref($rec->{ $fld }) eq 'ARRAY');
 344
 345                                 foreach my $row (@{ $rec->{$fld} }) {
 346
 347                                         if (ref($row) eq 'HASH') {
 348
 349                                                 foreach my $sf (keys %{ $row }) {
 350                                                         next if ($sf eq 'subfields');
 351                                                         $self->{_stats}->{sf}->{ $fld }->{ $sf }->{count}++;
 352                                                         $self->{_stats}->{sf}->{ $fld }->{ $sf }->{repeatable}++
 353                                                                         if (ref($row->{$sf}) eq 'ARRAY');
 354                                                 }
 355
 356                                         } else {
 357                                                 $self->{_stats}->{repeatable}->{ $fld }++;
 358                                         }
 359                                 }
 360                         }
 361                 }
 362
 363                 $self->progress_bar($pos,$to_rec) unless ($self->{no_progress_bar});
 364
 365         }
 366
 367         $self->{pos} = -1;
 368         $self->{last_pcnt} = 0;
 369
 370         # store max mfn and return it.
 371         $self->{max_pos} = $to_rec;
 372         $log->debug("max_pos: $to_rec");
 373
 374         # save for dump
 375         $self->{ll_db} = $ll_db;
 376
 377         return $size;
 378 }
 379
 380 =head2 fetch
 381
 382 Fetch next record from database. It will also displays progress bar.
 383
 384  my $rec = $isis->fetch;
 385
 386 Record from this function should probably go to C<data_structure> for
 387 normalisation.
 388
 389 =cut
 390
 391 sub fetch {
 392         my $self = shift;
 393
 394         my $log = $self->_get_logger();
 395
 396         $log->logconfess("it seems that you didn't load database!") unless ($self->{pos});
 397
 398         if ($self->{pos} == -1) {
 399                 $self->{pos} = $self->{offset};
 400         } else {
 401                 $self->{pos}++;
 402         }
 403
 404         my $mfn = $self->{pos};
 405
 406         if ($mfn > $self->{max_pos}) {
 407                 $self->{pos} = $self->{max_pos};
 408                 $log->debug("at EOF");
 409                 return;
 410         }
 411
 412         $self->progress_bar($mfn,$self->{max_pos}) unless ($self->{no_progress_bar});
 413
 414         my $rec;
 415
 416         if ($self->{load_row}) {
 417                 $rec = $self->{load_row}->({ id => $mfn });
 418         } else {
 419                 $rec = $self->{data}->{$mfn};
 420         }
 421
 422         $rec ||= 0E0;
 423 }
 424
 425 =head2 pos
 426
 427 Returns current record number (MFN).
 428
 429  print $isis->pos;
 430
 431 First record in database has position 1.
 432
 433 =cut
 434
 435 sub pos {
 436         my $self = shift;
 437         return $self->{pos};
 438 }
 439
 440
 441 =head2 size
 442
 443 Returns number of records in database
 444
 445  print $isis->size;
 446
 447 Result from this function can be used to loop through all records
 448
 449  foreach my $mfn ( 1 ... $isis->size ) { ... }
 450
 451 because it takes into account C<offset> and C<limit>.
 452
 453 =cut
 454
 455 sub size {
 456         my $self = shift;
 457         return $self->{size};
 458 }
 459
 460 =head2 seek
 461
 462 Seek to specified MFN in file.
 463
 464  $isis->seek(42);
 465
 466 First record in database has position 1.
 467
 468 =cut
 469
 470 sub seek {
 471         my $self = shift;
 472         my $pos = shift || return;
 473
 474         my $log = $self->_get_logger();
 475
 476         if ($pos < 1) {
 477                 $log->warn("seek before first record");
 478                 $pos = 1;
 479         } elsif ($pos > $self->{max_pos}) {
 480                 $log->warn("seek beyond last record");
 481                 $pos = $self->{max_pos};
 482         }
 483
 484         return $self->{pos} = (($pos - 1) || -1);
 485 }
 486
 487 =head2 stats
 488
 489 Dump statistics about field and subfield usage
 490
 491   print $input->stats;
 492
 493 =cut
 494
 495 sub stats {
 496         my $self = shift;
 497
 498         my $log = $self->_get_logger();
 499
 500         my $s = $self->{_stats};
 501         if (! $s) {
 502                 $log->warn("called stats, but there is no statistics collected");
 503                 return;
 504         }
 505
 506         my $max_fld = 0;
 507
 508         my $out = join("\n",
 509                 map {
 510                         my $f = $_ || die "no field";
 511                         my $v = $s->{fld}->{$f} || die "no s->{fld}->{$f}";
 512                         $max_fld = $v if ($v > $max_fld);
 513
 514                         my $o = sprintf("%4s %d ~", $f, $v);
 515
 516                         if (defined($s->{sf}->{$f})) {
 517                                 map {
 518                                         $o .= sprintf(" %s:%d%s", $_,
 519                                                 $s->{sf}->{$f}->{$_}->{count},
 520                                                 $s->{sf}->{$f}->{$_}->{repeatable} ? '*' : '',
 521                                         );
 522                                 } sort keys %{ $s->{sf}->{$f} };
 523                         }
 524
 525                         if (my $v_r = $s->{repeatable}->{$f}) {
 526                                 $o .= " ($v_r)" if ($v_r != $v);
 527                         }
 528
 529                         $o;
 530                 } sort { $a cmp $b } keys %{ $s->{fld} }
 531         );
 532
 533         $log->debug( sub { dump($s) } );
 534
 535         return $out;
 536 }
 537
 538 =head2 dump_ascii
 539
 540 Display humanly readable dump of record
 541
 542 =cut
 543
 544 sub dump_ascii {
 545         my $self = shift;
 546
 547         return unless $self->{ll_db};
 548
 549         if ($self->{ll_db}->can('dump_rec')) {
 550                 return $self->{ll_db}->dump_ascii( $self->{pos} );
 551         } else {
 552                 return dump( $self->{ll_db}->fetch_rec( $self->{pos} ) );
 553         }
 554 }
 555
 556 =head2 modify_record_regexps
 557
 558 Generate hash with regexpes to be applied using l<filter>.
 559
 560   my $regexpes = $input->modify_record_regexps(
 561                 900 => { '^a' => { ' : ' => '^b' } },
 562                 901 => { '*' => { '^b' => ' ; ' } },
 563   );
 564
 565 =cut
 566
 567 sub _get_regex {
 568         my ($sf,$from,$to) = @_;
 569         if ($from =~ m/^regex:(.+)$/) {
 570                 $from = $1;
 571         } else {
 572                 $from = '\Q' . $from . '\E';
 573         }
 574         if ($sf =~ /^\^/) {
 575                 return
 576                         's/\Q'. $sf .'\E([^\^]*?)'. $from .'([^\^]*?)/'. $sf .'$1'. $to .'$2/';
 577         } else {
 578                 return
 579                         's/'. $from .'/'. $to .'/g';
 580         }
 581 }
 582
 583 sub modify_record_regexps {
 584         my $self = shift;
 585         my $modify_record = {@_};
 586
 587         my $regexpes;
 588
 589         my $log = $self->_get_logger();
 590
 591         foreach my $f (keys %$modify_record) {
 592                 $log->debug("field: $f");
 593
 594                 foreach my $sf (keys %{ $modify_record->{$f} }) {
 595                         $log->debug("subfield: $sf");
 596
 597                         foreach my $from (keys %{ $modify_record->{$f}->{$sf} }) {
 598                                 my $to = $modify_record->{$f}->{$sf}->{$from};
 599                                 #die "no field?" unless defined($to);
 600                                 $log->debug("transform: |$from| -> |$to|");
 601
 602                                 my $regex = _get_regex($sf,$from,$to);
 603                                 push @{ $regexpes->{$f} }, $regex;
 604                                 $log->debug("regex: $regex");
 605                         }
 606                 }
 607         }
 608
 609         return $regexpes;
 610 }
 611
 612 =head2 modify_file_regexps
 613
 614 Generate hash with regexpes to be applied using l<filter> from
 615 pseudo hash/yaml format for regex mappings.
 616
 617 It should be obvious:
 618
 619         200
 620           '^a'
 621             ' : ' => '^e'
 622             ' = ' => '^d'
 623
 624 In field I<200> find C<'^a'> and then C<' : '>, and replace it with C<'^e'>.
 625 In field I<200> find C<'^a'> and then C<' = '>, and replace it with C<'^d'>.
 626
 627   my $regexpes = $input->modify_file_regexps( 'conf/modify/common.pl' );
 628
 629 On undef path it will just return.
 630
 631 =cut
 632
 633 sub modify_file_regexps {
 634         my $self = shift;
 635
 636         my $modify_path = shift || return;
 637
 638         my $log = $self->_get_logger();
 639
 640         my $regexpes;
 641
 642         CORE::open(my $fh, $modify_path) || $log->logdie("can't open modify file $modify_path: $!");
 643
 644         my ($f,$sf);
 645
 646         while(<$fh>) {
 647                 chomp;
 648                 next if (/^#/ || /^\s*$/);
 649
 650                 if (/^\s*(\d+)\s*$/) {
 651                         $f = $1;
 652                         $log->debug("field: $f");
 653                         next;
 654                 } elsif (/^\s*'([^']*)'\s*$/) {
 655                         $sf = $1;
 656                         $log->die("can't define subfiled before field in: $_") unless ($f);
 657                         $log->debug("subfield: $sf");
 658                 } elsif (/^\s*'([^']*)'\s*=>\s*'([^']*)'\s*$/) {
 659                         my ($from,$to) = ($1, $2);
 660
 661                         $log->debug("transform: |$from| -> |$to|");
 662
 663                         my $regex = _get_regex($sf,$from,$to);
 664                         push @{ $regexpes->{$f} }, $regex;
 665                         $log->debug("regex: $regex");
 666                 }
 667         }
 668
 669         return $regexpes;
 670 }
 671
 672 =head1 AUTHOR
 673
 674 Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
 675
 676 =head1 COPYRIGHT & LICENSE
 677
 678 Copyright 2005-2006 Dobrica Pavlinusic, All Rights Reserved.
 679
 680 This program is free software; you can redistribute it and/or modify it
 681 under the same terms as Perl itself.
 682
 683 =cut
 684
 685 1; # End of WebPAC::Input