git.rot13.org Git - webpac2/blob - lib/WebPAC/Input.pm

   1 package WebPAC::Input;
   2
   3 use warnings;
   4 use strict;
   5
   6 use lib 'lib';
   7
   8 use WebPAC::Common;
   9 use base qw/WebPAC::Common/;
  10 use Data::Dump qw/dump/;
  11 use Encode qw/decode from_to/;
  12 use YAML;
  13
  14 =head1 NAME
  15
  16 WebPAC::Input - read different file formats into WebPAC
  17
  18 =cut
  19
  20 our $VERSION = '0.19';
  21
  22 =head1 SYNOPSIS
  23
  24 This module implements input as database which have fixed and known
  25 I<size> while indexing and single unique numeric identifier for database
  26 position ranging from 1 to I<size>.
  27
  28 Simply, something that is indexed by unmber from 1 .. I<size>.
  29
  30 Examples of such databases are CDS/ISIS files, MARC files, lines in
  31 text file, and so on.
  32
  33 Specific file formats are implemented using low-level interface modules,
  34 located in C<WebPAC::Input::*> namespace which export C<open_db>,
  35 C<fetch_rec> and optional C<init> functions.
  36
  37 Perhaps a little code snippet.
  38
  39         use WebPAC::Input;
  40
  41         my $db = WebPAC::Input->new(
  42                 module => 'WebPAC::Input::ISIS',
  43         );
  44
  45         $db->open( path => '/path/to/database' );
  46         print "database size: ",$db->size,"\n";
  47         while (my $rec = $db->fetch) {
  48                 # do something with $rec
  49         }
  50
  51
  52
  53 =head1 FUNCTIONS
  54
  55 =head2 new
  56
  57 Create new input database object.
  58
  59   my $db = new WebPAC::Input(
  60         module => 'WebPAC::Input::MARC',
  61         recode => 'char pairs',
  62         no_progress_bar => 1,
  63         input_config => {
  64                 mapping => [ 'foo', 'bar', 'baz' ],
  65         },
  66   );
  67
  68 C<module> is low-level file format module. See L<WebPAC::Input::ISIS> and
  69 L<WebPAC::Input::MARC>.
  70
  71 C<recode> is optional string constisting of character or words pairs that
  72 should be replaced in input stream.
  73
  74 C<no_progress_bar> disables progress bar output on C<STDOUT>
  75
  76 This function will also call low-level C<init> if it exists with same
  77 parametars.
  78
  79 =cut
  80
  81 sub new {
  82         my $class = shift;
  83         my $self = {@_};
  84         bless($self, $class);
  85
  86         my $log = $self->_get_logger;
  87
  88         $log->logconfess("code_page argument is not suppored any more.") if $self->{code_page};
  89         $log->logconfess("encoding argument is not suppored any more.") if $self->{encoding};
  90         $log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_ref") if $self->{lookup};
  91         $log->logconfess("low_mem argument is not suppored any more. rewrite it to load_row and save_row") if $self->{low_mem};
  92
  93         $log->logconfess("specify low-level file format module") unless ($self->{module});
  94         my $module_path = $self->{module};
  95         $module_path =~ s#::#/#g;
  96         $module_path .= '.pm';
  97         $log->debug("require low-level module $self->{module} from $module_path");
  98
  99         require $module_path;
 100
 101         $self ? return $self : return undef;
 102 }
 103
 104 =head2 open
 105
 106 This function will read whole database in memory and produce lookups.
 107
 108  my $store;     # simple in-memory hash
 109
 110  $input->open(
 111         path => '/path/to/database/file',
 112         input_encoding => 'cp852',
 113         strict_encoding => 0,
 114         limit => 500,
 115         offset => 6000,
 116         stats => 1,
 117         lookup_coderef => sub {
 118                 my $rec = shift;
 119                 # store lookups
 120         },
 121         modify_records => {
 122                 900 => { '^a' => { ' : ' => '^b' } },
 123                 901 => { '*' => { '^b' => ' ; ' } },
 124         },
 125         modify_file => 'conf/modify/mapping.map',
 126         save_row => sub {
 127                 my $a = shift;
 128                 $store->{ $a->{id} } = $a->{row};
 129         },
 130         load_row => sub {
 131                 my $a = shift;
 132                 return defined($store->{ $a->{id} }) &&
 133                         $store->{ $a->{id} };
 134         },
 135
 136  );
 137
 138 By default, C<input_encoding> is assumed to be C<cp852>.
 139
 140 C<offset> is optional parametar to position at some offset before reading from database.
 141
 142 C<limit> is optional parametar to read just C<limit> records from database
 143
 144 C<stats> create optional report about usage of fields and subfields
 145
 146 C<lookup_coderef> is closure to called to save data into lookups
 147
 148 C<modify_records> specify mapping from subfields to delimiters or from
 149 delimiters to subfields, as well as oprations on fields (if subfield is
 150 defined as C<*>.
 151
 152 C<modify_file> is alternative for C<modify_records> above which preserves order and offers
 153 (hopefully) simplier sintax than YAML or perl (see L</modify_file_regex>). This option
 154 overrides C<modify_records> if both exists for same input.
 155
 156 C<save_row> and C<load_row> are low-level implementation of store engine. Calling convention
 157 is documented in example above.
 158
 159 C<strict_encoding> should really default to 1, but it doesn't for now.
 160
 161 Returns size of database, regardless of C<offset> and C<limit>
 162 parametars, see also C<size>.
 163
 164 =cut
 165
 166 sub open {
 167         my $self = shift;
 168         my $arg = {@_};
 169
 170         my $log = $self->_get_logger();
 171         $log->debug( "arguments: ",dump( $arg ));
 172
 173         $log->logconfess("encoding argument is not suppored any more.") if $self->{encoding};
 174         $log->logconfess("code_page argument is not suppored any more.") if $self->{code_page};
 175         $log->logconfess("lookup argument is not suppored any more. rewrite call to lookup_coderef") if ($arg->{lookup});
 176         $log->logconfess("lookup_coderef must be CODE, not ",ref($arg->{lookup_coderef}))
 177                 if ($arg->{lookup_coderef} && ref($arg->{lookup_coderef}) ne 'CODE');
 178
 179         $log->debug( $arg->{lookup_coderef} ? '' : 'not ', "using lookup_coderef");
 180
 181         $log->logcroak("need path") if (! $arg->{'path'});
 182         my $input_encoding = $arg->{'input_encoding'} || $self->{'input_encoding'} || 'cp852';
 183
 184         # store data in object
 185         foreach my $v (qw/path offset limit/) {
 186                 $self->{$v} = $arg->{$v} if ($arg->{$v});
 187         }
 188
 189         if ($arg->{load_row} || $arg->{save_row}) {
 190                 $log->logconfess("save_row and load_row must be defined in pair and be CODE") unless (
 191                         ref($arg->{load_row}) eq 'CODE' &&
 192                         ref($arg->{save_row}) eq 'CODE'
 193                 );
 194                 $self->{load_row} = $arg->{load_row};
 195                 $self->{save_row} = $arg->{save_row};
 196                 $log->debug("using load_row and save_row instead of in-memory hash");
 197         }
 198
 199         my $filter_ref;
 200         my $recode_regex;
 201         my $recode_map;
 202
 203         if ($self->{recode}) {
 204                 my @r = split(/\s/, $self->{recode});
 205                 if ($#r % 2 != 1) {
 206                         $log->logwarn("recode needs even number of elements (some number of valid pairs)");
 207                 } else {
 208                         while (@r) {
 209                                 my $from = shift @r;
 210                                 my $to = shift @r;
 211                                 $recode_map->{$from} = $to;
 212                         }
 213
 214                         $recode_regex = join '|' => keys %{ $recode_map };
 215
 216                         $log->debug("using recode regex: $recode_regex");
 217                 }
 218
 219         }
 220
 221         my $rec_regex;
 222         if (my $p = $arg->{modify_file}) {
 223                 $log->debug("using modify_file $p");
 224                 $rec_regex = $self->modify_file_regexps( $p );
 225         } elsif (my $h = $arg->{modify_records}) {
 226                 $log->debug("using modify_records ", sub { dump( $h ) });
 227                 $rec_regex = $self->modify_record_regexps(%{ $h });
 228         }
 229         $log->debug("rec_regex: ", sub { dump($rec_regex) }) if ($rec_regex);
 230
 231         my $class = $self->{module} || $log->logconfess("can't get low-level module name!");
 232
 233         my $ll_db = $class->new(
 234                 path => $arg->{path},
 235                 input_config => $arg->{input_config} || $self->{input_config},
 236 #               filter => sub {
 237 #                       my ($l,$f_nr) = @_;
 238 #                       return unless defined($l);
 239 #                       $l = decode($input_encoding, $l);
 240 #                       $l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map);
 241 #                       return $l;
 242 #               },
 243                 %{ $arg },
 244         );
 245
 246         unless (defined($ll_db)) {
 247                 $log->logwarn("can't open database $arg->{path}, skipping...");
 248                 return;
 249         }
 250
 251         my $size = $ll_db->size;
 252
 253         unless ($size) {
 254                 $log->logwarn("no records in database $arg->{path}, skipping...");
 255                 return;
 256         }
 257
 258         my $from_rec = 1;
 259         my $to_rec = $size;
 260
 261         if (my $s = $self->{offset}) {
 262                 $log->debug("skipping to MFN $s");
 263                 $from_rec = $s;
 264         } else {
 265                 $self->{offset} = $from_rec;
 266         }
 267
 268         if ($self->{limit}) {
 269                 $log->debug("limiting to ",$self->{limit}," records");
 270                 $to_rec = $from_rec + $self->{limit} - 1;
 271                 $to_rec = $size if ($to_rec > $size);
 272         }
 273
 274         # store size for later
 275         $self->{size} = ($to_rec - $from_rec) ? ($to_rec - $from_rec + 1) : 0;
 276
 277         my $strict_encoding = $arg->{strict_encoding} || $self->{strict_encoding}; ## FIXME should be 1 really
 278
 279         $log->info("processing $self->{size}/$size records [$from_rec-$to_rec]",
 280                 " encoding $input_encoding ", $strict_encoding ? ' [strict]' : '',
 281                 $self->{stats} ? ' [stats]' : '',
 282         );
 283
 284         # read database
 285         for (my $pos = $from_rec; $pos <= $to_rec; $pos++) {
 286
 287                 $log->debug("position: $pos\n");
 288
 289                 my $rec = $ll_db->fetch_rec($pos, sub {
 290                                 my ($l,$f_nr,$debug) = @_;
 291 #                               return unless defined($l);
 292 #                               return $l unless ($rec_regex && $f_nr);
 293
 294                                 return unless ( defined($l) && defined($f_nr) );
 295
 296                                 warn "-=> $f_nr ## |$l|\n" if ($debug);
 297                                 $log->debug("-=> $f_nr ## $l");
 298
 299                                 # codepage conversion and recode_regex
 300                                 $l = decode($input_encoding, $l, 1);
 301                                 $l =~ s/($recode_regex)/$recode_map->{$1}/g if ($recode_regex && $recode_map);
 302
 303                                 # apply regexps
 304                                 if ($rec_regex && defined($rec_regex->{$f_nr})) {
 305                                         $log->logconfess("regexps->{$f_nr} must be ARRAY") if (ref($rec_regex->{$f_nr}) ne 'ARRAY');
 306                                         my $c = 0;
 307                                         foreach my $r (@{ $rec_regex->{$f_nr} }) {
 308                                                 my $old_l = $l;
 309                                                 $log->logconfess("expected regex in ", dump( $r )) unless defined($r->{regex});
 310                                                 eval '$l =~ ' . $r->{regex};
 311                                                 if ($old_l ne $l) {
 312                                                         my $d = "|$old_l| -> |$l| "; # . $r->{regex};
 313                                                         $d .= ' +' . $r->{line} . ' ' . $r->{file} if defined($r->{line});
 314                                                         $d .= ' ' . $r->{debug} if defined($r->{debug});
 315                                                         $log->debug("MODIFY $d");
 316                                                         warn "*** $d\n" if ($debug);
 317
 318                                                 }
 319                                                 $log->error("error applying regex: ",dump($r), $@) if $@;
 320                                         }
 321                                 }
 322
 323                                 $log->debug("<=- $f_nr ## |$l|");
 324                                 warn "<=- $f_nr ## $l\n" if ($debug);
 325                                 return $l;
 326                 });
 327
 328                 $log->debug(sub { dump($rec) });
 329
 330                 if (! $rec) {
 331                         $log->warn("record $pos empty? skipping...");
 332                         next;
 333                 }
 334
 335                 # store
 336                 if ($self->{save_row}) {
 337                         $self->{save_row}->({
 338                                 id => $pos,
 339                                 row => $rec,
 340                         });
 341                 } else {
 342                         $self->{data}->{$pos} = $rec;
 343                 }
 344
 345                 # create lookup
 346                 $arg->{'lookup_coderef'}->( $rec ) if ($rec && $arg->{'lookup_coderef'});
 347
 348                 # update counters for statistics
 349                 if ($self->{stats}) {
 350
 351                         # fetch clean record with regexpes applied for statistics
 352                         my $rec = $ll_db->fetch_rec($pos);
 353
 354                         foreach my $fld (keys %{ $rec }) {
 355                                 $self->{_stats}->{fld}->{ $fld }++;
 356
 357                                 #$log->logdie("invalid record fild $fld, not ARRAY")
 358                                 next unless (ref($rec->{ $fld }) eq 'ARRAY');
 359
 360                                 foreach my $row (@{ $rec->{$fld} }) {
 361
 362                                         if (ref($row) eq 'HASH') {
 363
 364                                                 foreach my $sf (keys %{ $row }) {
 365                                                         next if ($sf eq 'subfields');
 366                                                         $self->{_stats}->{sf}->{ $fld }->{ $sf }->{count}++;
 367                                                         $self->{_stats}->{sf}->{ $fld }->{ $sf }->{repeatable}++
 368                                                                         if (ref($row->{$sf}) eq 'ARRAY');
 369                                                 }
 370
 371                                         } else {
 372                                                 $self->{_stats}->{repeatable}->{ $fld }++;
 373                                         }
 374                                 }
 375                         }
 376                 }
 377
 378                 $self->progress_bar($pos,$to_rec) unless ($self->{no_progress_bar});
 379
 380         }
 381
 382         $self->{pos} = -1;
 383         $self->{last_pcnt} = 0;
 384
 385         # store max mfn and return it.
 386         $self->{max_pos} = $to_rec;
 387         $log->debug("max_pos: $to_rec");
 388
 389         # save for dump
 390         $self->{ll_db} = $ll_db;
 391
 392         return $size;
 393 }
 394
 395 sub input_module { $_[0]->{ll_db} }
 396
 397 =head2 fetch
 398
 399 Fetch next record from database. It will also displays progress bar.
 400
 401  my $rec = $isis->fetch;
 402
 403 Record from this function should probably go to C<data_structure> for
 404 normalisation.
 405
 406 =cut
 407
 408 sub fetch {
 409         my $self = shift;
 410
 411         my $log = $self->_get_logger();
 412
 413         $log->logconfess("it seems that you didn't load database!") unless ($self->{pos});
 414
 415         if ($self->{pos} == -1) {
 416                 $self->{pos} = $self->{offset};
 417         } else {
 418                 $self->{pos}++;
 419         }
 420
 421         my $mfn = $self->{pos};
 422
 423         if ($mfn > $self->{max_pos}) {
 424                 $self->{pos} = $self->{max_pos};
 425                 $log->debug("at EOF");
 426                 return;
 427         }
 428
 429         $self->progress_bar($mfn,$self->{max_pos}) unless ($self->{no_progress_bar});
 430
 431         my $rec;
 432
 433         if ($self->{load_row}) {
 434                 $rec = $self->{load_row}->({ id => $mfn });
 435         } else {
 436                 $rec = $self->{data}->{$mfn};
 437         }
 438
 439         $rec ||= 0E0;
 440 }
 441
 442 =head2 pos
 443
 444 Returns current record number (MFN).
 445
 446  print $isis->pos;
 447
 448 First record in database has position 1.
 449
 450 =cut
 451
 452 sub pos {
 453         my $self = shift;
 454         return $self->{pos};
 455 }
 456
 457
 458 =head2 size
 459
 460 Returns number of records in database
 461
 462  print $isis->size;
 463
 464 Result from this function can be used to loop through all records
 465
 466  foreach my $mfn ( 1 ... $isis->size ) { ... }
 467
 468 because it takes into account C<offset> and C<limit>.
 469
 470 =cut
 471
 472 sub size {
 473         my $self = shift;
 474         return $self->{size};
 475 }
 476
 477 =head2 seek
 478
 479 Seek to specified MFN in file.
 480
 481  $isis->seek(42);
 482
 483 First record in database has position 1.
 484
 485 =cut
 486
 487 sub seek {
 488         my $self = shift;
 489         my $pos = shift;
 490
 491         my $log = $self->_get_logger();
 492
 493         $log->logconfess("called without pos") unless defined($pos);
 494
 495         if ($pos < 1) {
 496                 $log->warn("seek before first record");
 497                 $pos = 1;
 498         } elsif ($pos > $self->{max_pos}) {
 499                 $log->warn("seek beyond last record");
 500                 $pos = $self->{max_pos};
 501         }
 502
 503         return $self->{pos} = (($pos - 1) || -1);
 504 }
 505
 506 =head2 stats
 507
 508 Dump statistics about field and subfield usage
 509
 510   print $input->stats;
 511
 512 =cut
 513
 514 sub stats {
 515         my $self = shift;
 516
 517         my $log = $self->_get_logger();
 518
 519         my $s = $self->{_stats};
 520         if (! $s) {
 521                 $log->warn("called stats, but there is no statistics collected");
 522                 return;
 523         }
 524
 525         my $max_fld = 0;
 526
 527         my $out = join("\n",
 528                 map {
 529                         my $f = $_;
 530                         die "no field in ", dump( $s->{fld} ) unless defined( $f );
 531                         my $v = $s->{fld}->{$f} || die "no s->{fld}->{$f}";
 532                         $max_fld = $v if ($v > $max_fld);
 533
 534                         my $o = sprintf("%4s %d ~", $f, $v);
 535
 536                         if (defined($s->{sf}->{$f})) {
 537                                 my @subfields = keys %{ $s->{sf}->{$f} };
 538                                 map {
 539                                         $o .= sprintf(" %s:%d%s", $_,
 540                                                 $s->{sf}->{$f}->{$_}->{count},
 541                                                 $s->{sf}->{$f}->{$_}->{repeatable} ? '*' : '',
 542                                         );
 543                                 } (
 544                                         # first indicators and other special subfields
 545                                         sort( grep { length($_)  > 1 } @subfields ),
 546                                         # then subfileds (single char)
 547                                         sort( grep { length($_) == 1 } @subfields ),
 548                                 );
 549                         }
 550
 551                         if (my $v_r = $s->{repeatable}->{$f}) {
 552                                 $o .= " ($v_r)" if ($v_r != $v);
 553                         }
 554
 555                         $o;
 556                 } sort {
 557                         if ( $a =~ m/^\d+$/ && $b =~ m/^\d+$/ ) {
 558                                 $a <=> $b
 559                         } else {
 560                                 $a cmp $b
 561                         }
 562                 } keys %{ $s->{fld} }
 563         );
 564
 565         $log->debug( sub { dump($s) } );
 566
 567         my $path = 'var/stats.yml';
 568         YAML::DumpFile( $path, $s );
 569         $log->info( 'created ', $path, ' with ', -s $path, ' bytes' );
 570
 571         return $out;
 572 }
 573
 574 =head2 dump_ascii
 575
 576 Display humanly readable dump of record
 577
 578 =cut
 579
 580 sub dump_ascii {
 581         my $self = shift;
 582
 583         return unless $self->{ll_db};
 584
 585         if ($self->{ll_db}->can('dump_ascii')) {
 586                 return $self->{ll_db}->dump_ascii( $self->{pos} );
 587         } else {
 588                 return dump( $self->{ll_db}->fetch_rec( $self->{pos} ) );
 589         }
 590 }
 591
 592 =head2 _get_regex
 593
 594 Helper function called which create regexps to be execute on code.
 595
 596   _get_regex( 900, 'regex:[0-9]+' ,'numbers' );
 597   _get_regex( 900, '^b', ' : ^b' );
 598
 599 It supports perl regexps with C<regex:> prefix to from value and has
 600 additional logic to skip empty subfields.
 601
 602 =cut
 603
 604 sub _get_regex {
 605         my ($sf,$from,$to) = @_;
 606
 607         # protect /
 608         $from =~ s!/!\\/!gs;
 609         $to =~ s!/!\\/!gs;
 610
 611         if ($from =~ m/^regex:(.+)$/) {
 612                 $from = $1;
 613         } else {
 614                 $from = '\Q' . $from . '\E';
 615         }
 616         if ($sf =~ /^\^/) {
 617                 my $need_subfield_data = '*';   # no
 618                 # if from is also subfield, require some data in between
 619                 # to correctly skip empty subfields
 620                 $need_subfield_data = '+' if ($from =~ m/^\\Q\^/);
 621                 return
 622                         's/\Q'. $sf .'\E([^\^]' . $need_subfield_data . '?)'. $from .'([^\^]*?)/'. $sf .'$1'. $to .'$2/';
 623         } else {
 624                 return
 625                         's/'. $from .'/'. $to .'/g';
 626         }
 627 }
 628
 629
 630 =head2 modify_record_regexps
 631
 632 Generate hash with regexpes to be applied using L<filter>.
 633
 634   my $regexpes = $input->modify_record_regexps(
 635                 900 => { '^a' => { ' : ' => '^b' } },
 636                 901 => { '*' => { '^b' => ' ; ' } },
 637   );
 638
 639 =cut
 640
 641 sub modify_record_regexps {
 642         my $self = shift;
 643         my $modify_record = {@_};
 644
 645         my $regexpes;
 646
 647         my $log = $self->_get_logger();
 648
 649         foreach my $f (keys %$modify_record) {
 650                 $log->debug("field: $f");
 651
 652                 foreach my $sf (keys %{ $modify_record->{$f} }) {
 653                         $log->debug("subfield: $sf");
 654
 655                         foreach my $from (keys %{ $modify_record->{$f}->{$sf} }) {
 656                                 my $to = $modify_record->{$f}->{$sf}->{$from};
 657                                 #die "no field?" unless defined($to);
 658                                 my $d = "|$from| -> |$to|";
 659                                 $log->debug("transform: $d");
 660
 661                                 my $regex = _get_regex($sf,$from,$to);
 662                                 push @{ $regexpes->{$f} }, { regex => $regex, debug => $d };
 663                                 $log->debug("regex: $regex");
 664                         }
 665                 }
 666         }
 667
 668         return $regexpes;
 669 }
 670
 671 =head2 modify_file_regexps
 672
 673 Generate hash with regexpes to be applied using L<filter> from
 674 pseudo hash/yaml format for regex mappings.
 675
 676 It should be obvious:
 677
 678         200
 679           '^a'
 680             ' : ' => '^e'
 681             ' = ' => '^d'
 682
 683 In field I<200> find C<'^a'> and then C<' : '>, and replace it with C<'^e'>.
 684 In field I<200> find C<'^a'> and then C<' = '>, and replace it with C<'^d'>.
 685
 686   my $regexpes = $input->modify_file_regexps( 'conf/modify/common.pl' );
 687
 688 On undef path it will just return.
 689
 690 =cut
 691
 692 sub modify_file_regexps {
 693         my $self = shift;
 694
 695         my $modify_path = shift || return;
 696
 697         my $log = $self->_get_logger();
 698
 699         my $regexpes;
 700
 701         CORE::open(my $fh, $modify_path) || $log->logdie("can't open modify file $modify_path: $!");
 702
 703         my ($f,$sf);
 704
 705         while(<$fh>) {
 706                 chomp;
 707                 next if (/^#/ || /^\s*$/);
 708
 709                 if (/^\s*(\d+)\s*$/) {
 710                         $f = $1;
 711                         $log->debug("field: $f");
 712                         next;
 713                 } elsif (/^\s*'([^']*)'\s*$/) {
 714                         $sf = $1;
 715                         $log->die("can't define subfiled before field in: $_") unless ($f);
 716                         $log->debug("subfield: $sf");
 717                 } elsif (/^\s*'([^']*)'\s*=>\s*'([^']*)'\s*$/) {
 718                         my ($from,$to) = ($1, $2);
 719
 720                         $log->debug("transform: |$from| -> |$to|");
 721
 722                         my $regex = _get_regex($sf,$from,$to);
 723                         push @{ $regexpes->{$f} }, {
 724                                 regex => $regex,
 725                                 file => $modify_path,
 726                                 line => $.,
 727                         };
 728                         $log->debug("regex: $regex");
 729                 } else {
 730                         die "can't parse: $_";
 731                 }
 732         }
 733
 734         return $regexpes;
 735 }
 736
 737 =head1 AUTHOR
 738
 739 Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
 740
 741 =head1 COPYRIGHT & LICENSE
 742
 743 Copyright 2005-2006 Dobrica Pavlinusic, All Rights Reserved.
 744
 745 This program is free software; you can redistribute it and/or modify it
 746 under the same terms as Perl itself.
 747
 748 =cut
 749
 750 1; # End of WebPAC::Input